From: Adhemerval Zanella via Libc-alpha <libc-alpha@sourceware.org>
To: libc-alpha@sourceware.org, Szabolcs Nagy <szabolcs.nagy@arm.com>,
"H . J . Lu" <hjl.tools@gmail.com>
Cc: Christian Brauner <brauner@kernel.org>
Subject: [PATCH v2 05/11] powerpc64: Add the clone3 wrapper
Date: Fri, 4 Nov 2022 16:01:06 -0300 [thread overview]
Message-ID: <20221104190112.2566409-6-adhemerval.zanella@linaro.org> (raw)
In-Reply-To: <20221104190112.2566409-1-adhemerval.zanella@linaro.org>
It follows the internal signature:
extern int clone3 (struct clone_args *__cl_args, size_t __size,
int (*__func) (void *__arg), void *__arg);
The powerpc64 ABI requires an initial stackframe so the child can
store/restore the TOC. Iit is create prior calling clone3 by
adjusting the stack size (since kernel will compute the stack as
stack plus size).
Checked on powerpc64-linux-gnu (power8, kernel 6.0) and
powerpc64le-linux-gnu (power9, kernel 4.18).
---
.../sysv/linux/powerpc/powerpc64/clone3.S | 152 ++++++++++++++++++
sysdeps/unix/sysv/linux/powerpc/sysdep.h | 1 +
2 files changed, 153 insertions(+)
create mode 100644 sysdeps/unix/sysv/linux/powerpc/powerpc64/clone3.S
diff --git a/sysdeps/unix/sysv/linux/powerpc/powerpc64/clone3.S b/sysdeps/unix/sysv/linux/powerpc/powerpc64/clone3.S
new file mode 100644
index 0000000000..0fe2fe91db
--- /dev/null
+++ b/sysdeps/unix/sysv/linux/powerpc/powerpc64/clone3.S
@@ -0,0 +1,152 @@
+/* The clone3 syscall wrapper. Linux/powerpc64 version.
+ Copyright (C) 2022 Free Software Foundation, Inc.
+
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <https://www.gnu.org/licenses/>. */
+
+#include <sysdep.h>
+#define _ERRNO_H 1
+#include <bits/errno.h>
+
+/* The userland implementation is:
+ int clone3 (struct clone_args *cl_args, size_t size,
+ int (*func)(void *arg), void *arg);
+
+ the kernel entry is:
+ int clone3 (struct clone_args *cl_args, size_t size);
+
+ The parameters are passed in registers from userland:
+ r3: cl_args
+ r4: size
+ r5: func
+ r6: arg */
+
+ .text
+ENTRY(__clone3)
+ CALL_MCOUNT 4
+
+ /* Sanity checks args. */
+ cmpdi cr0, r3, 0
+ cmpdi cr1, r5, 0
+ cror cr0*4+eq, cr1*4+eq, cr0*4+eq
+ beq cr0,L(badargs)
+
+ /* Save some regs in the "red zone". */
+#ifdef USE_PPC_SCV
+ std r28, -24(r1)
+ cfi_offset (r28, -24)
+#endif
+ std r29, -16(r1)
+ std r30, -8(r1)
+ cfi_offset (r29, -16)
+ cfi_offset (r30, -8)
+
+ /* Save fn and args across syscall. */
+ mr r30, r5 /* Function in r30. */
+ mr r29, r6 /* Argument in r29. */
+
+ /* End FDE now, because in the child the unwind info will be
+ wrong. */
+ cfi_endproc
+
+ /* Setup a minimum stack fram for child. It needs to first calculate
+ the effective stack address, write the start NULL frame-pointer,
+ and update the frame size in the input cl_args. */
+ ld r7, 40(r3) /* Load stack value. */
+ ld r8, 48(r3) /* Load stack_size value. */
+ li r10, 0
+ add r7, r7, r8 /* Calculate effective stack address. */
+ std r10, -FRAME_MIN_SIZE_PARM(r7)
+ addi r8, r8, -FRAME_MIN_SIZE_PARM
+ std r8, 48(r3)
+
+ /* Do the system call, the kernel expects:
+ r0: system call numer
+ r3: cl_args
+ r4: size */
+ li r0, SYS_ify(clone3)
+#ifdef USE_PPC_SCV
+ CHECK_SCV_SUPPORT r28 0f
+ /* This is equivalent to DO_CALL_SCV, but we cannot use the macro here
+ because it uses CFI directives and we just called cfi_endproc. */
+ mflr r9
+ std r9, FRAME_LR_SAVE(r1)
+ .machine "push"
+ .machine "power9"
+ scv 0
+ .machine "pop"
+ ld r9, FRAME_LR_SAVE(r1)
+ mtlr r9
+
+ /* When using scv, error is indicated by negative r3. */
+ cmpdi cr1, r3, 0
+ b 1f
+#endif
+0: DO_CALL_SC
+
+ /* With sc, error is indicated by cr0.SO. */
+ cmpdi cr1, r3, 0
+ crandc cr1*4+eq, cr1*4+eq, cr0*4+so
+
+1: bne- cr1,L(parent)
+
+ /* Child, load the function and arguments. */
+ std r2, FRAME_TOC_SAVE(r1)
+ PPC64_LOAD_FUNCPTR r30
+ mr r3, r29
+ bctrl
+ ld r2, FRAME_TOC_SAVE(r1)
+
+ li r0, SYS_ify(exit)
+ DO_CALL_SC
+ /* We won't ever get here but provide a nop so that the linker
+ will insert a toc adjusting stub if necessary. */
+ nop
+
+L(badargs):
+ cfi_startproc
+ li r3, EINVAL
+ TAIL_CALL_SYSCALL_ERROR
+
+L(parent):
+ /* Check if svc is available. */
+ cmpdi cr1, r28, 0
+
+ /* Parent. Restore registers & return. */
+#ifdef USE_PPC_SCV
+ cfi_offset (r28, -24)
+ ld r28, -24(r1)
+ cfi_restore (r28)
+#endif
+ cfi_offset (r29,-16)
+ cfi_offset (r30,-8)
+ ld r29, -16(r1)
+ ld r30, -8(r1)
+ cfi_restore (r29)
+ cfi_restore (r30)
+
+#ifdef USE_PPC_SCV
+ beq cr1, 0f
+ RET_SCV
+ b 1f
+#endif
+0: RET_SC
+1: TAIL_CALL_SYSCALL_ERROR
+
+PSEUDO_END (__clone3)
+
+libc_hidden_def (__clone3)
+weak_alias (__clone3, clone3)
diff --git a/sysdeps/unix/sysv/linux/powerpc/sysdep.h b/sysdeps/unix/sysv/linux/powerpc/sysdep.h
index 9e44818978..af63b3974b 100644
--- a/sysdeps/unix/sysv/linux/powerpc/sysdep.h
+++ b/sysdeps/unix/sysv/linux/powerpc/sysdep.h
@@ -214,6 +214,7 @@
#if defined(__PPC64__) || defined(__powerpc64__)
#define HAVE_CLOCK_GETRES64_VSYSCALL "__kernel_clock_getres"
#define HAVE_CLOCK_GETTIME64_VSYSCALL "__kernel_clock_gettime"
+#define HAVE_CLONE3_WRAPPER 1
#else
#define HAVE_CLOCK_GETRES_VSYSCALL "__kernel_clock_getres"
#define HAVE_CLOCK_GETTIME_VSYSCALL "__kernel_clock_gettime"
--
2.34.1
next prev parent reply other threads:[~2022-11-04 19:02 UTC|newest]
Thread overview: 22+ messages / expand[flat|nested] mbox.gz Atom feed top
2022-11-04 19:01 [PATCH v2 00/11] Optimize posix_spawn signal setup with clone3 Adhemerval Zanella via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 01/11] linux: Do not reset signal handler in posix_spawn if it is already SIG_DFL Adhemerval Zanella via Libc-alpha
2023-01-11 21:27 ` Carlos O'Donell via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 02/11] linux: Extend internal clone3 documentation Adhemerval Zanella via Libc-alpha
2022-11-07 16:40 ` Szabolcs Nagy via Libc-alpha
2023-01-11 21:35 ` Carlos O'Donell via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 03/11] Linux: Do not align the stack for __clone3 Adhemerval Zanella via Libc-alpha
2023-01-11 21:43 ` Carlos O'Donell via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 04/11] linux: Add clone3 CLONE_CLEAR_SIGHAND optimization to posix_spawn Adhemerval Zanella via Libc-alpha
2023-01-11 21:44 ` Carlos O'Donell via Libc-alpha
2022-11-04 19:01 ` Adhemerval Zanella via Libc-alpha [this message]
2022-11-28 16:38 ` [PATCH v2 05/11] powerpc64: Add the clone3 wrapper Paul E Murphy via Libc-alpha
2022-11-29 20:43 ` Adhemerval Zanella Netto via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 06/11] aarch64: " Adhemerval Zanella via Libc-alpha
2022-11-07 16:14 ` Szabolcs Nagy via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 07/11] s390x: " Adhemerval Zanella via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 08/11] riscv: " Adhemerval Zanella via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 09/11] arm: " Adhemerval Zanella via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 10/11] mips: " Adhemerval Zanella via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 11/11] Linux: optimize clone3 internal usage Adhemerval Zanella via Libc-alpha
2023-01-11 21:45 ` Carlos O'Donell via Libc-alpha
2023-01-11 21:24 ` [PATCH v2 00/11] Optimize posix_spawn signal setup with clone3 Carlos O'Donell via Libc-alpha
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://www.gnu.org/software/libc/involved.html
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20221104190112.2566409-6-adhemerval.zanella@linaro.org \
--to=libc-alpha@sourceware.org \
--cc=adhemerval.zanella@linaro.org \
--cc=brauner@kernel.org \
--cc=hjl.tools@gmail.com \
--cc=szabolcs.nagy@arm.com \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).