From: Adhemerval Zanella via Libc-alpha <libc-alpha@sourceware.org>
To: libc-alpha@sourceware.org, Szabolcs Nagy <szabolcs.nagy@arm.com>,
"H . J . Lu" <hjl.tools@gmail.com>
Cc: Christian Brauner <brauner@kernel.org>
Subject: [PATCH v2 10/11] mips: Add the clone3 wrapper
Date: Fri, 4 Nov 2022 16:01:11 -0300 [thread overview]
Message-ID: <20221104190112.2566409-11-adhemerval.zanella@linaro.org> (raw)
In-Reply-To: <20221104190112.2566409-1-adhemerval.zanella@linaro.org>
It follows the internal signature:
extern int clone3 (struct clone_args *__cl_args, size_t __size,
int (*__func) (void *__arg), void *__arg);
Checked on mips64el-linux-gnueabihf and mipsel-linux-gnu.
---
sysdeps/unix/sysv/linux/mips/clone3.S | 139 ++++++++++++++++++++++++++
sysdeps/unix/sysv/linux/mips/sysdep.h | 2 +
2 files changed, 141 insertions(+)
create mode 100644 sysdeps/unix/sysv/linux/mips/clone3.S
diff --git a/sysdeps/unix/sysv/linux/mips/clone3.S b/sysdeps/unix/sysv/linux/mips/clone3.S
new file mode 100644
index 0000000000..7810994264
--- /dev/null
+++ b/sysdeps/unix/sysv/linux/mips/clone3.S
@@ -0,0 +1,139 @@
+/* The clone3 syscall wrapper. Linux/mips version.
+ Copyright (C) 2022 Free Software Foundation, Inc.
+
+ This file is part of the GNU C Library.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, see
+ <https://www.gnu.org/licenses/>. */
+
+#include <sys/asm.h>
+#include <sysdep.h>
+#define _ERRNO_H 1
+#include <bits/errno.h>
+
+/* The userland implementation is:
+ int clone3 (struct clone_args *cl_args, size_t size,
+ int (*func)(void *arg), void *arg);
+
+ the kernel entry is:
+ int clone3 (struct clone_args *cl_args, size_t size);
+
+ The parameters are passed in registers from userland:
+ a0/$4: cl_args
+ a1/$5: size
+ a2/$6: func
+ a3/$7: arg */
+
+ .text
+ .set nomips16
+#if _MIPS_SIM == _ABIO32
+# define EXTRA_LOCALS 1
+#else
+# define EXTRA_LOCALS 0
+#endif
+#define FRAMESZ ((NARGSAVE*SZREG)+ALSZ)&ALMASK
+GPOFF= FRAMESZ-(1*SZREG)
+NESTED(__clone3, SZREG, sp)
+#ifdef __PIC__
+ SETUP_GP
+#endif
+#if FRAMESZ
+ PTR_SUBU sp, FRAMESZ
+ cfi_adjust_cfa_offset (FRAMESZ)
+#endif
+ SETUP_GP64_STACK (GPOFF, __clone)
+#ifdef __PIC__
+ SAVE_GP (GPOFF)
+#endif
+#ifdef PROF
+ .set noat
+ move $1,ra
+ jal _mcount
+ .set at
+#endif
+
+ /* Sanity check args. */
+ li v0, EINVAL
+ beqz a0, L(error) /* No NULL cl_args pointer. */
+ beqz a2, L(error) /* No NULL function pointer. */
+
+ move $8, a3 /* a3 is set to 0/1 for syscall success/error
+ while a4/$8 is returned unmodified. */
+
+ /* Do the system call, the kernel expects:
+ v0: system call number
+ a0: cl_args
+ a1: size */
+ li v0, __NR_clone3
+ cfi_endproc
+ syscall
+
+ bnez a3, L(error)
+ beqz v0, L(thread_start_clone3)
+
+ /* Successful return from the parent */
+ cfi_startproc
+#if FRAMESZ
+ cfi_adjust_cfa_offset (FRAMESZ)
+#endif
+ SETUP_GP64_STACK_CFI (GPOFF)
+ cfi_remember_state
+ RESTORE_GP64_STACK
+#if FRAMESZ
+ PTR_ADDU sp, FRAMESZ
+ cfi_adjust_cfa_offset (-FRAMESZ)
+#endif
+ ret
+
+L(error):
+ cfi_restore_state
+#ifdef __PIC__
+ PTR_LA t9,__syscall_error
+ RESTORE_GP64_STACK
+ PTR_ADDU sp, FRAMESZ
+ cfi_adjust_cfa_offset (-FRAMESZ)
+ jr t9
+#else
+ RESTORE_GP64_STACK
+ PTR_ADDU sp, FRAMESZ
+ cfi_adjust_cfa_offset (-FRAMESZ)
+ j __syscall_error
+#endif
+END (__clone3)
+
+/* Load up the arguments to the function. Put this block of code in
+ its own function so that we can terminate the stack trace with our
+ debug info. */
+
+ENTRY(__thread_start_clone3)
+L(thread_start_clone3):
+ cfi_undefined ($31)
+ /* cp is already loaded. */
+ SAVE_GP (GPOFF)
+ /* The stackframe has been created on entry of clone3. */
+
+ /* Restore the arg for user's function. */
+ move t9, a2 /* Function pointer. */
+ move a0, $8 /* Argument pointer. */
+
+ /* Call the user's function. */
+ jal t9
+
+ move a0, v0
+ li v0, __NR_exit
+ syscall
+END(__thread_start_clone3)
+
+libc_hidden_def (__clone3)
+weak_alias (__clone3, clone3)
diff --git a/sysdeps/unix/sysv/linux/mips/sysdep.h b/sysdeps/unix/sysv/linux/mips/sysdep.h
index 2515dadc26..3f464925e7 100644
--- a/sysdeps/unix/sysv/linux/mips/sysdep.h
+++ b/sysdeps/unix/sysv/linux/mips/sysdep.h
@@ -28,3 +28,5 @@
#endif
#define HAVE_GETTIMEOFDAY_VSYSCALL "__vdso_gettimeofday"
#define HAVE_CLOCK_GETRES_VSYSCALL "__vdso_clock_getres"
+
+#define HAVE_CLONE3_WRAPPER 1
--
2.34.1
next prev parent reply other threads:[~2022-11-04 19:03 UTC|newest]
Thread overview: 22+ messages / expand[flat|nested] mbox.gz Atom feed top
2022-11-04 19:01 [PATCH v2 00/11] Optimize posix_spawn signal setup with clone3 Adhemerval Zanella via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 01/11] linux: Do not reset signal handler in posix_spawn if it is already SIG_DFL Adhemerval Zanella via Libc-alpha
2023-01-11 21:27 ` Carlos O'Donell via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 02/11] linux: Extend internal clone3 documentation Adhemerval Zanella via Libc-alpha
2022-11-07 16:40 ` Szabolcs Nagy via Libc-alpha
2023-01-11 21:35 ` Carlos O'Donell via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 03/11] Linux: Do not align the stack for __clone3 Adhemerval Zanella via Libc-alpha
2023-01-11 21:43 ` Carlos O'Donell via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 04/11] linux: Add clone3 CLONE_CLEAR_SIGHAND optimization to posix_spawn Adhemerval Zanella via Libc-alpha
2023-01-11 21:44 ` Carlos O'Donell via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 05/11] powerpc64: Add the clone3 wrapper Adhemerval Zanella via Libc-alpha
2022-11-28 16:38 ` Paul E Murphy via Libc-alpha
2022-11-29 20:43 ` Adhemerval Zanella Netto via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 06/11] aarch64: " Adhemerval Zanella via Libc-alpha
2022-11-07 16:14 ` Szabolcs Nagy via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 07/11] s390x: " Adhemerval Zanella via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 08/11] riscv: " Adhemerval Zanella via Libc-alpha
2022-11-04 19:01 ` [PATCH v2 09/11] arm: " Adhemerval Zanella via Libc-alpha
2022-11-04 19:01 ` Adhemerval Zanella via Libc-alpha [this message]
2022-11-04 19:01 ` [PATCH v2 11/11] Linux: optimize clone3 internal usage Adhemerval Zanella via Libc-alpha
2023-01-11 21:45 ` Carlos O'Donell via Libc-alpha
2023-01-11 21:24 ` [PATCH v2 00/11] Optimize posix_spawn signal setup with clone3 Carlos O'Donell via Libc-alpha
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://www.gnu.org/software/libc/involved.html
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20221104190112.2566409-11-adhemerval.zanella@linaro.org \
--to=libc-alpha@sourceware.org \
--cc=adhemerval.zanella@linaro.org \
--cc=brauner@kernel.org \
--cc=hjl.tools@gmail.com \
--cc=szabolcs.nagy@arm.com \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).