public-inbox.git  about / heads / tags
an "archives first" approach to mailing lists
blob 372d003b297c4e67add17d73b8d69f3e33400046 2174 bytes (raw)
$ git show HEAD:xt/solver.t	# shows this blob on the CLI

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
 
#!perl -w
# Copyright (C) all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
use v5.12;
use PublicInbox::TestCommon;
use PublicInbox::Config; # this relies on PI_CONFIG // ~/.public-inbox/config
my @psgi = qw(HTTP::Request::Common Plack::Test URI::Escape Plack::Builder);
require_mods(qw(DBD::SQLite Xapian), @psgi);
use_ok($_) for @psgi;
use_ok 'PublicInbox::WWW';
my $cfg = PublicInbox::Config->new;
my $www = PublicInbox::WWW->new($cfg);
$www->preload;
my $app = sub {
	my $env = shift;
	$env->{'psgi.errors'} = \*STDERR;
	$www->call($env);
};

# TODO: convert these to self-contained test cases
my $todo = {
	'git' => [
		'9e9048b02bd04d287461543d85db0bb715b89f8c'
			.'/s/?b=t%2Ft3420%2Fremove-ids.sed',
		'eebf7a8/s/?b=t%2Ftest-lib.sh',
		'eb580ca513/s/?b=remote-odb.c',
		'776fa90f7f/s/?b=contrib/git-jump/git-jump',
		'5cd8845/s/?b=submodule.c',
		'81c1164ae5/s/?b=builtin/log.c',
		'6aa8857a11/s/?b=protocol.c',
		'96f1c7f/s/', # TODO: b=contrib/completion/git-completion.bash
		'b76f2c0/s/?b=po/zh_CN.po',
		'c2f3bf071ee90b01f2d629921bb04c4f798f02fa/s/', # tag
		'7eb93c89651c47c8095d476251f2e4314656b292/s/', # non-UTF-8
	],
	'sox-devel' => [
		'c38987e8d20505621b8d872863afa7d233ed1096/s/', # non-UTF-8
	]
};

my @gone;
my $client = sub {
	my ($cb) = @_;
	for my $ibx_name (sort keys %$todo) {
		diag "testing $ibx_name";
		my $urls = $todo->{$ibx_name};
		for my $u (@$urls) {
			my $url = "/$ibx_name/$u";
			my $res = $cb->(GET($url));
			is($res->code, 200, $url);
			next if $res->code == 200;
			diag "$url failed";
			diag $res->content;
		}
	}
};

my $nr = 0;
while (my ($ibx_name, $urls) = each %$todo) {
	SKIP: {
		my $ibx = $cfg->lookup_name($ibx_name);
		if (!$ibx) {
			push @gone, $ibx_name;
			skip(qq{[publicinbox "$ibx_name"] not configured},
				scalar(@$urls));
		}
		if (!defined($ibx->{-repo_objs})) {
			push @gone, $ibx_name;
			skip(qq{publicinbox.$ibx_name.coderepo not configured},
				scalar(@$urls));
		}
		$nr++;
	}
}

delete @$todo{@gone};
test_psgi($app, $client);
my $env = { PI_CONFIG => PublicInbox::Config->default_file };
test_httpd($env, $client, $nr);

done_testing();

git clone https://public-inbox.org/public-inbox.git
git clone http://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/public-inbox.git