public-inbox.git  about / heads / tags
an "archives first" approach to mailing lists
blob ef261359bbc76e6281da091abf952e2c330918e7 2112 bytes (raw)
$ git show HEAD:xt/perf-msgview.t	# shows this blob on the CLI

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
 
#!perl -w
# Copyright (C) all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
use strict;
use v5.10.1;
use PublicInbox::TestCommon;
use Benchmark qw(:all);
use PublicInbox::Inbox;
use PublicInbox::View;
use PublicInbox::WwwStream;

my $inboxdir = $ENV{GIANT_INBOX_DIR} // $ENV{GIANT_PI_DIR};
my $blob = $ENV{TEST_BLOB};
my $obfuscate = $ENV{PI_OBFUSCATE} ? 1 : 0;
diag "PI_OBFUSCATE=$obfuscate";
plan skip_all => "GIANT_INBOX_DIR not defined for $0" unless $inboxdir;

my @cat = qw(cat-file --buffer --batch-check --batch-all-objects);
if (require_git(2.19, 1)) {
	push @cat, '--unordered';
} else {
	warn
"git <2.19, cat-file lacks --unordered, locality suffers\n";
}
require_mods qw(Plack::Util);
my $ibx = PublicInbox::Inbox->new({ inboxdir => $inboxdir, name => 'name',
				    obfuscate => $obfuscate});
my $git = $ibx->git;
my $fh = $blob ? undef : $git->popen(@cat);
if ($fh) {
	my $vec = '';
	vec($vec, fileno($fh), 1) = 1;
	select($vec, undef, undef, 60) or
		die "timed out waiting for --batch-check";
}

my $ctx = bless {
	env => { HTTP_HOST => 'example.com', 'psgi.url_scheme' => 'https' },
	ibx => $ibx,
	www => Plack::Util::inline_object(style => sub {''}),
	gz => PublicInbox::GzipFilter::gzip_or_die(),
}, 'PublicInbox::WwwStream';
my ($eml, $res, $oid, $type);
my $n = 0;
my $m = 0;
${$ctx->{obuf}} = '';
$ctx->{mhref} = '../';

my $cb = sub {
	$eml = PublicInbox::Eml->new(shift);
	$eml->each_part(\&PublicInbox::View::add_text_body, $ctx, 1);
	$ctx->zflush(grep defined, delete @$ctx{'obuf'}); # compat
	++$m;
	delete $ctx->{zbuf};
	${$ctx->{obuf}} = ''; # compat
	$ctx->{gz} = PublicInbox::GzipFilter::gzip_or_die();
};

my $t = timeit(1, sub {
	if (defined $blob) {
		my $nr = $ENV{NR} // 10000;
		for (1..$nr) {
			++$n;
			$git->cat_async($blob, $cb);
		}
	} else {
		while (<$fh>) {
			($oid, $type) = split / /;
			next if $type ne 'blob';
			++$n;
			$git->cat_async($oid, $cb);
		}
	}
	$git->async_wait_all;
});
diag 'add_text_body took '.timestr($t)." for $n <=> $m messages";
is($m, $n, 'rendered all messages');
done_testing();

git clone https://public-inbox.org/public-inbox.git
git clone http://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/public-inbox.git