public-inbox.git  about / heads / tags
an "archives first" approach to mailing lists
blob 2f810a564f01367a592c0862705074e077a193c9 2509 bytes (raw)
$ git show ci-WIP:script/public-inbox-index	# shows this blob on the CLI

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
 
#!/usr/bin/perl -w
# Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
# Basic tool to create a Xapian search index for a git repository
# configured for public-inbox.
# Usage with libeatmydata <https://www.flamingspork.com/projects/libeatmydata/>
# highly recommended: eatmydata public-inbox-index REPO_DIR

use strict;
use warnings;
use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
my $usage = "public-inbox-index REPO_DIR";
use PublicInbox::Config;
use PublicInbox::Admin qw(resolve_repo_dir);

my $config = eval { PublicInbox::Config->new } || eval {
	warn "public-inbox unconfigured for serving, indexing anyways...\n";
	undef;
};
eval { require PublicInbox::SearchIdx };
if ($@) {
	print STDERR "Search::Xapian required for $0\n";
	exit 1;
}

my $reindex;
my $prune;
my $jobs = undef;
my %opts = (
	'--reindex' => \$reindex,
	'--jobs|j=i' => \$jobs,
	'--prune' => \$prune,
);
GetOptions(%opts) or die "bad command-line args\n$usage";
die "--jobs must be positive\n" if defined $jobs && $jobs < 0;

my @dirs;

if (@ARGV) {
	@dirs = map { resolve_repo_dir($_) } @ARGV;
} else {
	@dirs = (resolve_repo_dir());
}

sub usage { print STDERR "Usage: $usage\n"; exit 1 }
usage() unless @dirs;

defined($config) and $config->each_inbox(sub {
	my ($ibx) = @_;

	for my $i (0..$#dirs) {
		next if $dirs[$i] ne $ibx->{mainrepo};
		$dirs[$i] = $ibx;
	}
});

foreach my $dir (@dirs) {
	if (!ref($dir) && -f "$dir/inbox.lock") { # v2
		my $ibx = { mainrepo => $dir, name => 'unnamed' };
		$dir = PublicInbox::Inbox->new($ibx);
	}
	index_dir($dir);
}

sub index_dir {
	my ($repo) = @_;
	if (!ref $repo && ! -d $repo) {
		die "$repo does not appear to be an inbox repository\n";
	}
	if (ref($repo) && ($repo->{version} || 1) == 2) {
		eval { require PublicInbox::V2Writable };
		die "v2 requirements not met: $@\n" if $@;
		my $v2w = eval {
			$jobs and local $ENV{NPROC} = $jobs;
			PublicInbox::V2Writable->new($repo);
		};
		if (defined $jobs) {
			if ($jobs == 0) {
				$v2w->{parallel} = 0;
			} else {
				my $n = $v2w->{partitions};
				if ($jobs != ($n + 1)) {
					warn
"Unable to respect --jobs=$jobs, inbox was created with $n partitions\n";
				}
			}
		}
		local $SIG{__WARN__} = sub {
			print STDERR $v2w->{current_info}, ': ', @_;
		};
		$v2w->index_sync({ reindex => $reindex, prune => $prune });
	} else {
		my $s = PublicInbox::SearchIdx->new($repo, 1);
		$s->index_sync({ reindex => $reindex });
	}
}

git clone https://public-inbox.org/public-inbox.git
git clone http://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/public-inbox.git