about summary refs log tree commit homepage
path: root/public-inbox-mda
blob: 411ac15f7f396a35b95b23387cd133f0f1e4deed (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
#!/usr/bin/perl -w
# Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
# License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
use strict;
use warnings;
my $usage = 'public-inbox-mda < rfc2822_message';

use Email::Filter;
use Email::Address;
use File::Path::Expand qw/expand_filename/;
use IPC::Run qw(run);
use constant MDA => 'ssoma-mda';
use PublicInbox;
use PublicInbox::Filter;
use PublicInbox::Config;

# n.b: hopefully we can setup the failbox path without bailing due to
# user error, we really want to setup the emergency destination ASAP
# in case there's bugs in our code or user error.
my $failbox = $ENV{PI_FAILBOX} || '~/public-inbox-fail.mbox';
$failbox = expand_filename($failbox);

# this reads the message from stdin
my $filter = Email::Filter->new(emergency => $failbox);
my $config = PublicInbox::Config->new;

my $recipient = $ENV{RECIPIENT};
defined $recipient or die "RECIPIENT not defined in ENV\n";
my $dst = $config->lookup($recipient);
defined $dst or exit(1);
my $main_repo = $dst->{mainrepo} or exit(1);
my $filtered; # string dest

if (PublicInbox->precheck($filter, $recipient) &&
    do_spamc($filter->simple, \$filtered)) {
	# update our message with SA headers (in case our filter rejects it)
	my $simple = Email::Simple->new($filtered);
	$filtered = undef;
	$filter->simple($simple);

	if (PublicInbox::Filter->run($simple)) {
		# run spamc again on the HTML-free message
		if (do_spamc($simple, \$filtered)) {
			$simple = Email::Simple->new($filtered);
			$filter->simple($simple);

			my $from = $filter->from;
			my @from = Email::Address->parse($from);
			my $name = $from[0]->name;
			defined $name or $name = "";
			my $email = $from[0]->address;
			defined $email or $email = "";
			local $ENV{GIT_AUTHOR_NAME} = $name;
			local $ENV{GIT_AUTHOR_EMAIL} = $email;
			local $ENV{GIT_AUTHOR_DATE} = $simple->header("Date");
			local $ENV{GIT_COMMITTER_EMAIL} = $recipient;
			local $ENV{GIT_COMMITTER_NAME} = $dst->{listname};

			$filter->pipe(MDA, '-1', $main_repo);
		}
	}
}
exit 0; # goes to failbox

# we depend on "report_safe 0" in /etc/spamassassin/*.cf with --headers
# not using Email::Filter->pipe here since we want the stdout of
# the command even on failure (spamc will set $? on error).
sub do_spamc {
	my ($simple, $out) = @_;
	eval {
		my $orig = $simple->as_string;
		run([qw/spamc -E --headers/], \$orig, $out);
	};

	return ($@ || $? || !defined($$out) || length($$out) == 0) ? 0 : 1;
}