about summary refs log tree commit homepage
path: root/public-inbox-mda
blob: a3c959ac1ddeaf218b1b11bc59a8852d0963f189 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
#!/usr/bin/perl -w
# Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
# License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
use strict;
use warnings;
my $usage = 'public-inbox-mda < rfc2822_message';

use Email::Filter;
use Email::MIME;
use Email::Address;
use File::Path::Expand qw/expand_filename/;
use IPC::Run qw(run);
use PublicInbox::MDA;
use PublicInbox::Filter;
use PublicInbox::Config;

# n.b: hopefully we can setup the emergency path without bailing due to
# user error, we really want to setup the emergency destination ASAP
# in case there's bugs in our code or user error.
my $emergency = $ENV{PI_EMERGENCY} || '~/.public-inbox/emergency/';
$emergency = expand_filename($emergency);

# this reads the message from stdin
my $filter = Email::Filter->new(emergency => $emergency);
my $config = PublicInbox::Config->new;

my $recipient = $ENV{ORIGINAL_RECIPIENT};
defined $recipient or die "ORIGINAL_RECIPIENT not defined in ENV\n";
my $dst = $config->lookup($recipient); # first check
defined $dst or exit(1);
my $main_repo = $dst->{mainrepo} or exit(1);
my $filtered; # string dest

if (PublicInbox::MDA->precheck($filter, $dst->{address}) &&
    do_spamc($filter->simple, \$filtered)) {
	# update our message with SA headers (in case our filter rejects it)
	my $msg = Email::MIME->new(\$filtered);
	$filtered = undef;
	$filter->simple($msg);

	if (PublicInbox::Filter->run($msg, $filter)) {
		# run spamc again on the HTML-free message
		if (do_spamc($msg, \$filtered)) {
			$msg = Email::MIME->new(\$filtered);
			PublicInbox::MDA->set_list_headers($msg, $dst);
			$filter->simple($msg);

			my ($name, $email, $date) =
					PublicInbox::MDA->author_info($msg);

			END {
				search_index_sync($main_repo) if ($? == 0);
			};

			local $ENV{GIT_AUTHOR_NAME} = $name;
			local $ENV{GIT_AUTHOR_EMAIL} = $email;
			local $ENV{GIT_AUTHOR_DATE} = $date;
			local $ENV{GIT_COMMITTER_EMAIL} = $recipient;
			local $ENV{GIT_COMMITTER_NAME} = $dst->{listname};

			$filter->pipe(PublicInbox::MDA->cmd, $main_repo);
		}
	}
} else {
	# Ensure emergency spam gets spamassassin headers.
	# This makes it easier to prioritize obvious spam from less obvious
	if (defined($filtered) && length($filtered)) {
		my $drop = Email::MIME->new(\$filtered);
		$filtered = undef;
		$filter->simple($drop);
	}
}
exit 0; # goes to emergency

# we depend on "report_safe 0" in /etc/spamassassin/*.cf with --headers
# not using Email::Filter->pipe here since we want the stdout of
# the command even on failure (spamc will set $? on error).
sub do_spamc {
	my ($msg, $out) = @_;
	eval {
		my $orig = $msg->as_string;
		run([qw/spamc -E --headers/], \$orig, $out);
	};

	return ($@ || $? || !defined($$out) || length($$out) == 0) ? 0 : 1;
}

sub search_index_sync {
	my ($git_dir) = @_;
	eval {
		require PublicInbox::Search;
		umask 0022; # XXX FIXME use git config core.sharedRepository
		my $s = PublicInbox::Search->new($git_dir, 2);
		$s->index_sync;
	};
}