about summary refs log tree commit homepage
path: root/public-inbox-learn
blob: 3b0dae8e9c04217334ff8f7173a6ecae245d0f5e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
#!/usr/bin/perl -w
# Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
# License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
my $usage = "$0 (spam|ham) < /path/to/message";
use strict;
use warnings;
use PublicInbox::Config;
use Email::MIME;
use Email::Address;
use IPC::Run qw/run/;
my $train = shift or die "usage: $usage\n";
if ($train !~ /\A(?:ham|spam)\z/) {
	die "`$train' not recognized.\nusage: $usage\n";
}

my $pi_config = PublicInbox::Config->new;
my $mime = Email::MIME->new(eval { local $/; <> });

# get all recipients
my %dests;
foreach my $h (qw(Cc To)) {
	foreach my $recipient (Email::Address->parse($mime->header($h))) {
		$dests{lc($recipient->address)} = 1;
	}
}

my ($name, $email, $date);

if ($train eq "ham") {
	require PublicInbox::MDA;
	require PublicInbox::Filter;
	PublicInbox::Filter->run($mime);
	($name, $email, $date) = PublicInbox::MDA->author_info($mime);
}

my $in = $mime->as_string;
my $err = 0;
my @output = qw(> /dev/null > /dev/null);

# n.b. message may be cross-posted to multiple public-inboxes
foreach my $recipient (keys %dests) {
	my $dst = $pi_config->lookup($recipient) or next;
	my $git_dir = $dst->{mainrepo} or next;
	my ($out, $err) = ("", "");

	# We do not touch GIT_COMMITTER_* env here so we can track
	# who trained the message.
	# We will not touch GIT_AUTHOR_* when learning spam messages, either
	if ($train eq "spam") {
		# This needs to be idempotent, as my inotify trainer
		# may train for each cross-posted message, and this
		# script already learns for every list in
		# ~/.public-inbox/config
		if (!run(["ssoma-rm", $git_dir], \$in, \$out, \$err)) {
			if ($err !~ /^git cat-file .+ failed: 32768$/) {
				$err = 1;
			}
		}
	} else { # $train eq "ham"
		# no checking for spam here, we assume the message has
		# been reviewed by a human at this point:
		PublicInbox::MDA->set_list_headers($mime, $dst);
		my $s  = $mime->as_string;

		local $ENV{GIT_AUTHOR_NAME} = $name;
		local $ENV{GIT_AUTHOR_EMAIL} = $email;
		local $ENV{GIT_AUTHOR_DATE} = $date;

		# Ham messages are trained when they're marked into
		# a SEEN state, so this is idempotent:
		run([PublicInbox::MDA->cmd, $git_dir], \$s, \$out, \$err);
		if ($err !~ /CONFLICT/) {
			$err = 1;
		}
	}
	if (!run([qw(spamc -L), $train], \$in, @output)) {
		$err = 1;
	}

	$err or eval {
		require PublicInbox::SearchIdx;
		PublicInbox::SearchIdx->new($git_dir, 2)->index_sync;
	};
}

exit $err;