public-inbox.git  about / heads / tags
an "archives first" approach to mailing lists
blob 8d32074fbefa2a9e6b06c3a38d941799d1a8dfb7 8427 bytes (raw)
$ git show HEAD:lib/PublicInbox/WwwStream.pm	# shows this blob on the CLI

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
 
# Copyright (C) all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
#
# HTML body stream for which yields getline+close methods for
# generic PSGI servers and callbacks for public-inbox-httpd.
#
# See PublicInbox::GzipFilter parent class for more info.
package PublicInbox::WwwStream;
use strict;
use v5.10.1;
use parent qw(Exporter PublicInbox::GzipFilter);
our @EXPORT_OK = qw(html_oneshot);
use PublicInbox::Hval qw(ascii_html prurl ts2str);

our $CODE_URL = [ qw(
http://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/public-inbox.git
https://public-inbox.org/public-inbox.git) ];

sub base_url ($) {
	my ($ctx) = @_;
	my $thing = $ctx->{ibx} // $ctx->{git} // return;
	my $base_url = $thing->base_url($ctx->{env});
	chop $base_url; # no trailing slash for clone
	$base_url;
}

sub init {
	my ($ctx, $cb) = @_;
	$ctx->{cb} = $cb;
	$ctx->{base_url} = base_url($ctx);
	$ctx->{-res_hdr} = [ 'Content-Type' => 'text/html; charset=UTF-8' ];
	$ctx->{gz} = PublicInbox::GzipFilter::gz_or_noop($ctx->{-res_hdr},
							$ctx->{env});
	bless $ctx, __PACKAGE__;
}

sub async_eml { # for async_blob_cb
	my ($ctx, $eml) = @_;
	$ctx->write($ctx->{cb}->($ctx, $eml));
}

sub html_repo_top ($) {
	my ($ctx) = @_;
	my $git = $ctx->{git} // return $ctx->html_top_fallback;
	my $desc = ascii_html($git->description);
	my $title = delete($ctx->{-title_html}) // $desc;
	my $upfx = $ctx->{-upfx} // '';
	my $atom = $ctx->{-atom} // (substr($upfx, -1) eq '/' ?
					"${upfx}atom/" : "$upfx/atom/");
	my $top = ascii_html($git->{nick});
	$top = qq(<a\nhref="$upfx">$top</a>) if length($upfx);
	$top .= <<EOM;
  <a href='$upfx#readme'>about</a> / <a
href='$upfx#heads'>heads</a> / <a
href='$upfx#tags'>tags</a>
<b>$desc</b>
EOM
	my @url = PublicInbox::ViewVCS::ibx_url_for($ctx);
	if (@url) {
		$ctx->{-has_srch} = 1;
		my $base_url = base_url($ctx);
		my ($pfx, $sfx) = ($base_url =~ m!\A(https?://[^/]+/)(.*)\z!i);
		my $iupfx = '../' x (($sfx =~ tr!/!/!) + 1);
		$pfx = ascii_html($pfx);
		$pfx = qr/\A\Q$pfx\E/i;
		my $tmp = $top;
		$top = '';
		my ($s, $u);
		my $q_val = delete($ctx->{-q_value_html}) // '';
		$q_val = qq(\nvalue="$q_val") if $q_val ne '';
		for (@url) {
			$u = $s = ascii_html($_);
			substr($u, 0, 0, $iupfx) if $u !~ m!://!;
			$s =~ s!$pfx!!;
			$s =~ s!/\z!!;
			$top .= qq{<form\naction="$u"><pre>$tmp} .
				qq{<input\nname=q type=text$q_val />} .
				qq{<input type=submit\n} .
				qq{value="search mail in `$s&#39;"/>} .
				q{</pre></form>};
			$tmp = '';
		}
	} else {
		$top = "<pre>$top</pre>";
	}
	"<html><head><title>$title</title>" .
		qq(<link\nrel=alternate\ntitle="Atom feed"\n).
		qq(href="$atom"\ntype="application/atom+xml"/>) .
		$ctx->{www}->style($upfx) .
		'</head><body>'.$top;
}

sub html_top ($) {
	my ($ctx) = @_;
	my $ibx = $ctx->{ibx} // return html_repo_top($ctx);
	my $desc = ascii_html($ibx->description);
	my $title = delete($ctx->{-title_html}) // $desc;
	my $upfx = $ctx->{-upfx} || '';
	my $atom = $ctx->{-atom} || $upfx.'new.atom';
	my $top = "<b>$desc</b>";
	if (my $t_max = $ctx->{-t_max}) {
		$t_max = ts2str($t_max);
		$top = qq(<a\nhref="$upfx?t=$t_max">$top</a>);
	# we had some kind of query, link to /$INBOX/?t=YYYYMMDDhhmmss
	} elsif ($ctx->{qp}->{t}) {
		$top = qq(<a\nhref="./">$top</a>);
	} elsif (length($upfx)) {
		$top = qq(<a\nhref="$upfx">$top</a>);
	}
	my $code = $ibx->{coderepo} ? qq( / <a\nhref=#code>code</a>) : '';
	# id=mirror must exist for legacy bookmarks
	my $links = qq(<a\nhref="${upfx}_/text/help/">help</a> / ).
			qq(<a\nhref="${upfx}_/text/color/">color</a> / ).
			qq(<a\nid=mirror) .
			qq(\nhref="${upfx}_/text/mirror/">mirror</a>$code / ).
			qq(<a\nhref="$atom">Atom feed</a>);
	$links .= delete($ctx->{-html_more_links}) if $ctx->{-html_more_links};
	if ($ibx->isrch) {
		my $q_val = delete($ctx->{-q_value_html}) // '';
		$q_val = qq(\nvalue="$q_val") if $q_val ne '';
		# XXX gross, for SearchView.pm
		my $extra = delete($ctx->{-extra_form_html}) // '';
		my $action = $upfx eq '' ? './' : $upfx;
		$top = qq{<form\naction="$action"><pre>$top} .
			  qq{\n<input\nname=q\ntype=text$q_val />} .
			  $extra .
			  qq{<input\ntype=submit\nvalue=search />} .
			  ' ' . $links .
			  q{</pre></form>}
	} else {
		$top = '<pre>' . $top . "\n" . $links . '</pre>';
	}
	"<html><head><title>$title</title>" .
		qq(<link\nrel=alternate\ntitle="Atom feed"\n).
		qq(href="$atom"\ntype="application/atom+xml"/>) .
	        $ctx->{www}->style($upfx) .
		'</head><body>'. $top . (delete($ctx->{-html_tip}) // '');
}

sub inboxes { () } # TODO

sub coderepos ($) {
	my ($ctx) = @_;
	$ctx->{ibx} // return inboxes($ctx);
	my $cr = $ctx->{ibx}->{coderepo} // return ();
	my $upfx = ($ctx->{-upfx} // ''). '../';
	my $pfx = $ctx->{base_url} //= $ctx->base_url;
	my $up = $upfx =~ tr!/!/!;
	$pfx =~ s!/[^/]+\z!/! for (1..$up);
	$pfx .= '/' if substr($pfx, -1, 1) ne '/';
	my $buf = '<a id=code>' .
		'Code repositories for project(s) associated with this '.
		$ctx->{ibx}->thing_type . "\n";
	for my $git (@{$ctx->{www}->{pi_cfg}->repo_objs($ctx->{ibx})}) {
		for ($git->pub_urls($ctx->{env})) {
			my $u = m!\A(?:[a-z\+]+:)?//!i ? $_ : $pfx.$_;
			$u = ascii_html(prurl($ctx->{env}, $u));
			$buf .= qq(\n\t<a\nhref="$u">$u</a>);
		}
	}
	($buf);
}

sub _html_end {
	my ($ctx) = @_;
	my $upfx = $ctx->{-upfx} || '';
	my $m = "${upfx}_/text/mirror/";
	my $x = '';
	if ($ctx->{ibx} && $ctx->{ibx}->can('cloneurl')) {
		$x = <<EOF;
This is a public inbox, see <a
href="$m">mirroring instructions</a>
for how to clone and mirror all data and code used for this inbox
EOF
		my $has_nntp = @{$ctx->{ibx}->nntp_url($ctx)};
		my $has_imap = @{$ctx->{ibx}->imap_url($ctx)};
		if ($has_nntp || $has_imap) {
			substr($x, -1, 1) = ";\n"; # s/\n/;\n
			if ($has_nntp && $has_imap) {
				$x .= <<EOM;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).
EOM
			} elsif ($has_nntp) {
				$x .= <<EOM;
as well as URLs for NNTP newsgroup(s).
EOM
			} else {
				$x .= <<EOM;
as well as URLs for IMAP folder(s).
EOM
			}
		}
	} elsif ($ctx->{ibx}) { # extindex
		$x = <<EOF;
This is an external index of several public inboxes,
see <a href="$m">mirroring instructions</a> on how to clone and mirror
all data and code used by this external index.
EOF
	} elsif ($ctx->{git}) { # coderepo
		$x = join('', map { "git clone $_\n" }
			@{$ctx->{git}->cloneurl($ctx->{env})});
	}
	chomp $x;
	'<hr><pre>'.join("\n\n", coderepos($ctx), $x).'</pre></body></html>'
}

# callback for HTTP.pm (and any other PSGI servers)
sub getline {
	my ($ctx) = @_;
	my $cb = $ctx->{cb} or return;
	while (defined(my $x = $cb->($ctx))) { # x = smsg or scalar non-ref
		if (ref($x)) { # smsg
			my $eml = $ctx->{ibx}->smsg_eml($x) or next;
			$ctx->{smsg} = $x;
			return $ctx->translate($cb->($ctx, $eml));
		} else { # scalar
			return $ctx->translate($x);
		}
	}
	delete $ctx->{cb};
	$ctx->zflush(_html_end($ctx));
}

sub html_done ($;@) {
	my $ctx = $_[0];
	my $bdy = $ctx->zflush(@_[1..$#_], _html_end($ctx));
	my $res_hdr = delete $ctx->{-res_hdr};
	push @$res_hdr, 'Content-Length', length($bdy);
	[ 200, $res_hdr, [ $bdy ] ]
}

sub html_oneshot ($$;@) {
	my ($ctx, $code) = @_[0, 1];
	my $res_hdr = [ 'Content-Type' => 'text/html; charset=UTF-8',
		'Content-Length' => undef ];
	bless $ctx, __PACKAGE__;
	$ctx->{gz} = PublicInbox::GzipFilter::gz_or_noop($res_hdr, $ctx->{env});
	my @top;
	$ctx->{base_url} // do {
		@top = html_top($ctx);
		$ctx->{base_url} = base_url($ctx);
	};
	my $bdy = $ctx->zflush(@top, @_[2..$#_], _html_end($ctx));
	$res_hdr->[3] = length($bdy);
	[ $code, $res_hdr, [ $bdy ] ]
}

sub async_next ($) {
	my ($http) = @_; # PublicInbox::HTTP
	my $ctx = $http->{forward} or return;
	eval {
		if (my $smsg = $ctx->{smsg} = $ctx->{cb}->($ctx)) {
			$ctx->smsg_blob($smsg);
		} else {
			$ctx->write(_html_end($ctx));
			$ctx->close; # GzipFilter->close
		}
	};
	warn "E: $@" if $@;
}

sub aresponse {
	my ($ctx, $cb) = @_;
	init($ctx, $cb);
	$ctx->psgi_response(200, delete $ctx->{-res_hdr});
}

sub html_init {
	my $ctx = $_[-1];
	$ctx->{base_url} = base_url($ctx);
	my $h = $ctx->{-res_hdr} = ['Content-Type', 'text/html; charset=UTF-8'];
	$ctx->{gz} = PublicInbox::GzipFilter::gz_or_noop($h, $ctx->{env});
	bless $ctx, @_ > 1 ? $_[0] : __PACKAGE__;
	print { $ctx->zfh } html_top($ctx);
}

sub DESTROY {
	my ($ctx) = @_;
	$ctx->{git}->cleanup if $ctx->{git} && $ctx->{git}->{-tmp};
}

1;

git clone https://public-inbox.org/public-inbox.git
git clone http://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/public-inbox.git