public-inbox.git  about / heads / tags
an "archives first" approach to mailing lists
blob a5ba5b2b2386ef3643d261c8fe4db317a5d2c7c1 1396 bytes (raw)
$ git show repobrowse:lib/PublicInbox/WwwAttach.pm	# shows this blob on the CLI

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
 
# Copyright (C) 2016 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>

# For retrieving attachments from messages in the WWW interface
package PublicInbox::WwwAttach; # internal package
use strict;
use warnings;
use PublicInbox::MIME;
use Email::MIME::ContentType qw(parse_content_type);
$Email::MIME::ContentType::STRICT_PARAMS = 0;
use PublicInbox::MsgIter;

# /$LISTNAME/$MESSAGE_ID/$IDX-$FILENAME
sub get_attach ($$$) {
	my ($ctx, $idx, $fn) = @_;
	my $res = [ 404, [ 'Content-Type', 'text/plain' ], [ "Not found\n" ] ];
	my $mime = $ctx->{-inbox}->msg_by_mid($ctx->{mid}) or return $res;
	$mime = PublicInbox::MIME->new($mime);
	msg_iter($mime, sub {
		my ($part, $depth, @idx) = @{$_[0]};
		return if join('.', @idx) ne $idx;
		$res->[0] = 200;
		my $ct = $part->content_type;
		$ct = parse_content_type($ct) if $ct;

		# discrete == type, we remain Debian wheezy-compatible
		if ($ct && (($ct->{discrete} || '') eq 'text')) {
			# display all text as text/plain:
			my $cset = $ct->{attributes}->{charset};
			if ($cset && ($cset =~ /\A[\w-]+\z/)) {
				$res->[1]->[1] .= qq(; charset=$cset);
			}
		} else { # TODO: allow user to configure safe types
			$res->[1]->[1] = 'application/octet-stream';
		}
		$part = $part->body;
		push @{$res->[1]}, 'Content-Length', bytes::length($part);
		$res->[2]->[0] = $part;
	});
	$res;
}

1;

git clone https://public-inbox.org/public-inbox.git
git clone http://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/public-inbox.git