about summary refs log tree commit homepage
path: root/lib/PublicInbox/View.pm
blob: 42601677922cd177a6571b8ab1a1fcea20e47696 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
# Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
# License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
#
# Used for displaying the HTML web interface.
# See Documentation/design_www.txt for this.
package PublicInbox::View;
use strict;
use warnings;
use URI::Escape qw/uri_escape_utf8/;
use Date::Parse qw/str2time/;
use Encode qw/find_encoding/;
use Encode::MIME::Header;
use Email::MIME::ContentType qw/parse_content_type/;
use PublicInbox::Hval qw/ascii_html/;
use PublicInbox::Linkify;
use PublicInbox::MID qw/mid_clean id_compress mid2path mid_mime/;
use PublicInbox::MsgIter;
require POSIX;

use constant INDENT => '  ';
use constant TCHILD => '` ';
sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };

# public functions:
sub msg_html {
	my ($ctx, $mime, $footer) = @_;
	$footer = defined($footer) ? "\n$footer" : '';
	my $hdr = $mime->header_obj;
	headers_to_html_header($hdr, $ctx) .
		multipart_text_as_html($mime) .
		'</pre><hr /><pre>' .
		html_footer($hdr, 1, $ctx, 'R/') .
		$footer .
		'</pre></body></html>';
}

# /$INBOX/$MESSAGE_ID/R/
sub msg_reply {
	my ($ctx, $hdr, $footer) = @_;
	my $s = $hdr->header('Subject');
	$s = '(no subject)' if (!defined $s) || ($s eq '');
	my $f = $hdr->header('From');
	$f = '' unless defined $f;
	my $mid = $hdr->header_raw('Message-ID');
	$mid = PublicInbox::Hval->new_msgid($mid);
	my $t = ascii_html($s);
	my $se_url =
	 'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';

	my ($arg, $link) = mailto_arg_link($hdr);
	push @$arg, '/path/to/YOUR_REPLY';

	"<html><head><title>replying to \"$t\"</title></head><body><pre>" .
	"replying to message:\n\n" .
	"Subject: <b>$t</b>\n" .
	"From: ". ascii_html($f) .
	"\nDate: " .  ascii_html($hdr->header('Date')) .
	"\nMessage-ID: &lt;" . $mid->as_html . "&gt;\n\n" .
	"There are multiple ways to reply:\n\n" .
	"* Save the following mbox file, import it into your mail client,\n" .
	"  and reply-to-all from there: <a\nhref=../raw>mbox</a>\n\n" .
	"* Reply to all the recipients using the <b>--to</b>, <b>--cc</b>,\n" .
	"  and <b>--in-reply-to</b> switches of git-send-email(1):\n\n" .
	"\tgit send-email \\\n\t\t" .
	join(" \\ \n\t\t", @$arg ). "\n\n" .
	qq(  <a\nhref="$se_url">$se_url</a>\n\n) .
	"* If your mail client supports setting the <b>In-Reply-To</b>" .
	" header\n  via mailto: links, try the " .
	qq(<a\nhref="$link">mailto: link</a>\n) .
	"\nFor context, the original <a\nhref=../>message</a> or " .
	qq(<a\nhref="../t/#u">thread</a>) .
	'</pre><hr /><pre>' . $footer .  '</pre></body></html>';
}

sub in_reply_to {
	my ($hdr) = @_;
	my $irt = $hdr->header_raw('In-Reply-To');

	return mid_clean($irt) if (defined $irt);

	my $refs = $hdr->header_raw('References');
	if ($refs && $refs =~ /<([^>]+)>\s*\z/s) {
		return $1;
	}
	undef;
}

# this is already inside a <pre>
sub index_entry {
	my ($mime, $level, $state) = @_;
	my $midx = $state->{anchor_idx}++;
	my $ctx = $state->{ctx};
	my $srch = $ctx->{srch};
	my $hdr = $mime->header_obj;
	my $subj = $hdr->header('Subject');

	my $mid_raw = mid_clean(mid_mime($mime));
	my $id = anchor_for($mid_raw);
	my $seen = $state->{seen};
	$seen->{$id} = "#$id"; # save the anchor for children, later

	my $mid = PublicInbox::Hval->new_msgid($mid_raw);
	my $from = $hdr->header('From');
	my @from = Email::Address->parse($from);
	$from = $from[0]->name;

	my $root_anchor = $state->{root_anchor} || '';
	my $path = $root_anchor ? '../../' : '';
	my $href = $mid->as_href;
	my $irt = in_reply_to($hdr);
	my $parent_anchor = $seen->{anchor_for($irt)} if defined $irt;

	$from = ascii_html($from);
	$subj = ascii_html($subj);
	$subj = "<a\nhref=\"${path}$href/\">$subj</a>";
	$subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id;

	my $ts = _msg_date($hdr);
	my $rv = "<pre\nid=s$midx>";
	$rv .= "<b\nid=$id>$subj</b>\n";
	my $txt = "${path}$href/raw";
	my $fh = $state->{fh};
	$fh->write($rv .= "- $from @ $ts UTC (<a\nhref=\"$txt\">raw</a>)\n\n");

	my $mhref = "${path}$href/";

	# scan through all parts, looking for displayable text
	msg_iter($mime, sub { index_walk($fh, $_[0]) });
	$rv = "\n" . html_footer($hdr, 0, $ctx, "$path$href/R/");

	if (defined $irt) {
		unless (defined $parent_anchor) {
			my $v = PublicInbox::Hval->new_msgid($irt, 1);
			$v = $v->as_href;
			$parent_anchor = "${path}$v/";
		}
		$rv .= " <a\nhref=\"$parent_anchor\">parent</a>";
	}
	if (my $pct = $state->{pct}) { # used by SearchView.pm
		$rv .= " [relevance $pct->{$mid_raw}%]";
	} elsif ($srch) {
		my $threaded = 'threaded';
		my $flat = 'flat';
		my $end = '';
		if ($ctx->{flat}) {
			$flat = "<b>$flat</b>";
			$end = "\n"; # for lynx
		} else {
			$threaded = "<b>$threaded</b>";
		}
		$rv .= " [<a\nhref=\"${path}$href/t/#u\">$threaded</a>";
		$rv .= "|<a\nhref=\"${path}$href/T/#u\">$flat</a>]$end";
	}
	$fh->write($rv .= '</pre>');
}

sub thread_html {
	my ($ctx, $foot, $srch) = @_;
	# $_[0] in sub is the Plack callback
	sub { emit_thread_html($_[0], $ctx, $foot, $srch) }
}

# only private functions below.

sub emit_thread_html {
	my ($res, $ctx, $foot, $srch) = @_;
	my $mid = $ctx->{mid};
	my $flat = $ctx->{flat};
	my $msgs = load_results($srch->get_thread($mid, { asc => $flat }));
	my $nr = scalar @$msgs;
	return missing_thread($res, $ctx) if $nr == 0;
	my $seen = {};
	my $state = {
		res => $res,
		ctx => $ctx,
		seen => $seen,
		root_anchor => anchor_for($mid),
		anchor_idx => 0,
		cur_level => 0,
	};

	require PublicInbox::Git;
	$ctx->{git} ||= PublicInbox::Git->new($ctx->{git_dir});
	if ($flat) {
		pre_anchor_entry($seen, $_) for (@$msgs);
		__thread_entry($state, $_, 0) for (@$msgs);
	} else {
		my $th = thread_results($msgs);
		thread_entry($state, $_, 0) for $th->rootset;
		if (my $max = $state->{cur_level}) {
			$state->{fh}->write(
				('</ul></li>' x ($max - 1)) . '</ul>');
		}
	}
	Email::Address->purge_cache;

	# there could be a race due to a message being deleted in git
	# but still being in the Xapian index:
	my $fh = delete $state->{fh} or return missing_thread($res, $ctx);

	my $final_anchor = $state->{anchor_idx};
	my $next = "<a\nid=s$final_anchor>";
	$next .= $final_anchor == 1 ? 'only message in' : 'end of';
	$next .= " thread</a>, back to <a\nhref=\"../../\">index</a>";
	$next .= "\ndownload thread: ";
	$next .= "<a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
	$next .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>";
	$fh->write('<hr /><pre>' . $next . "\n\n".
			$foot .  '</pre></body></html>');
	$fh->close;
}

sub index_walk {
	my ($fh, $p) = @_;
	my $s = add_text_body($p);

	return if $s eq '';

	$s .= "\n"; # ensure there's a trailing newline

	$fh->write($s);
}

sub multipart_text_as_html {
	my ($mime) = @_;
	my $rv = "";

	# scan through all parts, looking for displayable text
	msg_iter($mime, sub {
		my ($p) = @_;
		$p = add_text_body($p);
		$rv .= $p;
		$rv .= "\n" if $p ne '';
	});
	$rv;
}

sub flush_quote {
	my ($s, $l, $quot) = @_;

	# show everything in the full version with anchor from
	# short version (see above)
	my $rv = $l->linkify_1(join('', @$quot));
	@$quot = ();

	# we use a <div> here to allow users to specify their own
	# color for quoted text
	$rv = $l->linkify_2(ascii_html($rv));
	$$s .= qq(<span\nclass="q">) . $rv . '</span>'
}

sub attach_link ($$$) {
	my ($ct, $p, $fn) = @_;
	my ($part, $depth, @idx) = @$p;
	my $nl = $idx[-1] > 1 ? "\n" : '';
	my $idx = join('.', @idx);
	my $size = bytes::length($part->body);
	$ct ||= 'text/plain';
	$ct =~ s/;.*//; # no attributes
	$ct = ascii_html($ct);
	my $desc = $part->header('Content-Description');
	$desc = $fn unless defined $desc;
	$desc = '' unless defined $desc;
	$desc = ': '.$desc if $desc;
	"$nl<b>[-- Attachment #$idx$desc --]\n" .
	"[-- Type: $ct, Size: $size bytes --]</b>"
}

sub add_text_body {
	my ($p) = @_; # from msg_iter: [ Email::MIME, depth, @idx ]
	my ($part, $depth, @idx) = @$p;
	my $ct = $part->content_type;
	my $fn = $part->filename;

	if (defined $ct && $ct =~ m!\btext/x?html\b!i) {
		return attach_link($ct, $p, $fn);
	}

	my $s = eval { $part->body_str };

	# badly-encoded message? tell the world about it!
	return attach_link($ct, $p, $fn) if $@;

	my @lines = split(/^/m, $s);
	$s = '';
	if (defined($fn) || $depth > 1 || $idx[0] > 1) {
		$s .= attach_link($ct, $p, $fn);
		$s .= "\n\n";
	}
	my @quot;
	my $l = PublicInbox::Linkify->new;
	while (defined(my $cur = shift @lines)) {
		if ($cur !~ /^>/) {
			# show the previously buffered quote inline
			flush_quote(\$s, $l, \@quot) if @quot;

			# regular line, OK
			$cur = $l->linkify_1($cur);
			$cur = ascii_html($cur);
			$s .= $l->linkify_2($cur);
		} else {
			push @quot, $cur;
		}
	}

	flush_quote(\$s, $l, \@quot) if @quot;
	$s =~ s/[ \t]+$//sgm; # kill per-line trailing whitespace
	$s =~ s/\A\n+//s; # kill leading blank lines
	$s =~ s/\s+\z//s; # kill all trailing spaces (final "\n" added if ne '')
	$s;
}

sub headers_to_html_header {
	my ($hdr, $ctx) = @_;
	my $srch = $ctx->{srch} if $ctx;
	my $atom = '';
	my $rv = '';
	my $upfx = '';

	if ($srch) {
		$atom = qq{<link\nrel=alternate\ntitle="Atom feed"\n} .
			qq!href="${upfx}t.atom"\ntype="application/atom+xml"/>!;
	}

	my @title;
	my $mid = $hdr->header_raw('Message-ID');
	$mid = PublicInbox::Hval->new_msgid($mid);
	foreach my $h (qw(From To Cc Subject Date)) {
		my $v = $hdr->header($h);
		defined($v) && ($v ne '') or next;
		$v = PublicInbox::Hval->new($v);

		if ($h eq 'From') {
			my @from = Email::Address->parse($v->raw);
			$title[1] = ascii_html($from[0]->name);
		} elsif ($h eq 'Subject') {
			$title[0] = $v->as_html;
			if ($srch) {
				$rv .= qq($h: <a\nhref="#r"\nid=t>);
				$rv .= $v->as_html . "</a>\n";
				next;
			}
		}
		$rv .= "$h: " . $v->as_html . "\n";

	}
	$rv .= 'Message-ID: &lt;' . $mid->as_html . '&gt; ';
	$rv .= "(<a\nhref=\"${upfx}raw\">raw</a>)\n";
	$rv .= _parent_headers($hdr, $srch);
	$rv .= "\n";

	("<html><head><title>".  join(' - ', @title) . "</title>$atom".
	 PublicInbox::Hval::STYLE .
	 "</head><body><pre\nid=b>" . # anchor for body start
	 $rv);
}

sub thread_skel {
	my ($dst, $ctx, $hdr, $tpfx) = @_;
	my $srch = $ctx->{srch};
	my $mid = mid_clean($hdr->header_raw('Message-ID'));
	my $sres = $srch->get_thread($mid);
	my $nr = $sres->{total};
	my $expand = qq(<a\nhref="${tpfx}t/#u">expand</a> ) .
			qq(/ <a\nhref="${tpfx}t.mbox.gz">mbox.gz</a> ) .
			qq(/ <a\nhref="${tpfx}t.atom">Atom feed</a>);

	my $parent = in_reply_to($hdr);
	if ($nr <= 1) {
		if (defined $parent) {
			$$dst .= "($expand)\n ";
			$$dst .= ghost_parent("$tpfx../", $parent) . "\n";
		} else {
			$$dst .= "[no followups, yet] ($expand)\n";
		}
		$ctx->{next_msg} = undef;
		$ctx->{parent_msg} = $parent;
		return;
	}

	$$dst .= "$nr+ messages in thread ($expand";
	$$dst .= qq! / <a\nhref="#b">[top]</a>)\n!;

	my $subj = $srch->subject_path($hdr->header('Subject'));
	my $state = {
		seen => { $subj => 1 },
		srch => $srch,
		cur => $mid,
		prev_attr => '',
		prev_level => 0,
	};
	for (thread_results(load_results($sres))->rootset) {
		skel_dump($dst, $state, $tpfx, $_, 0);
	}
	$ctx->{next_msg} = $state->{next_msg};
	$ctx->{parent_msg} = $parent;
}

sub _parent_headers {
	my ($hdr, $srch) = @_;
	my $rv = '';

	my $irt = in_reply_to($hdr);
	if (defined $irt) {
		my $v = PublicInbox::Hval->new_msgid($irt, 1);
		my $html = $v->as_html;
		my $href = $v->as_href;
		$rv .= "In-Reply-To: &lt;";
		$rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
	}

	# do not display References: if search is present,
	# we show the thread skeleton at the bottom, instead.
	return $rv if $srch;

	my $refs = $hdr->header_raw('References');
	if ($refs) {
		# avoid redundant URLs wasting bandwidth
		my %seen;
		$seen{$irt} = 1 if defined $irt;
		my @refs;
		my @raw_refs = ($refs =~ /<([^>]+)>/g);
		foreach my $ref (@raw_refs) {
			next if $seen{$ref};
			$seen{$ref} = 1;
			push @refs, linkify_ref_nosrch($ref);
		}

		if (@refs) {
			$rv .= 'References: '. join(' ', @refs) . "\n";
		}
	}
	$rv;
}

sub mailto_arg_link {
	my ($hdr) = @_;
	my %cc; # everyone else
	my $to; # this is the From address

	foreach my $h (qw(From To Cc)) {
		my $v = $hdr->header($h);
		defined($v) && ($v ne '') or next;
		my @addrs = Email::Address->parse($v);
		foreach my $recip (@addrs) {
			my $address = $recip->address;
			my $dst = lc($address);
			$cc{$dst} ||= $address;
			$to ||= $dst;
		}
	}
	Email::Address->purge_cache;
	my @arg;

	my $subj = $hdr->header('Subject') || '';
	$subj = "Re: $subj" unless $subj =~ /\bRe:/i;
	my $mid = $hdr->header_raw('Message-ID');
	push @arg, "--in-reply-to='" . ascii_html($mid) . "'";
	my $irt = uri_escape_utf8($mid);
	delete $cc{$to};
	push @arg, '--to=' . ascii_html($to);
	$to = uri_escape_utf8($to);
	$subj = uri_escape_utf8($subj);
	my $cc = join(',', sort values %cc);
	push @arg, '--cc=' . ascii_html($cc);
	$cc = uri_escape_utf8($cc);
	my $href = "mailto:$to?In-Reply-To=$irt&Cc=${cc}&Subject=$subj";
	$href =~ s/%20/+/g;

	(\@arg, $href);
}

sub html_footer {
	my ($hdr, $standalone, $ctx, $rhref) = @_;

	my $srch = $ctx->{srch} if $ctx;
	my $upfx = '../';
	my $tpfx = '';
	my $idx = $standalone ? " <a\nhref=\"$upfx\">index</a>" : '';
	my $irt = '';
	if ($idx && $srch) {
		$idx .= "\n";
		thread_skel(\$idx, $ctx, $hdr, $tpfx);
		my $p = $ctx->{parent_msg};
		my $next = $ctx->{next_msg};
		if ($p) {
			$p = PublicInbox::Hval->new_msgid($p);
			$p = $p->as_href;
			$irt = "<a\nhref=\"$upfx$p/\"rel=prev>parent</a> ";
		} else {
			$irt = ' ' x length('parent ');
		}
		if ($next) {
			my $n = PublicInbox::Hval->new_msgid($next)->as_href;
			$irt .= "<a\nhref=\"$upfx$n/\"\nrel=next>next</a> ";
		} else {
			$irt .= ' ' x length('next ');
		}
	} else {
		$irt = '';
	}

	$irt . qq(<a\nhref="$rhref">reply</a>) . $idx;
}

sub linkify_ref_nosrch {
	my $v = PublicInbox::Hval->new_msgid($_[0], 1);
	my $html = $v->as_html;
	my $href = $v->as_href;
	"&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
}

sub anchor_for {
	my ($msgid) = @_;
	my $id = $msgid;
	if ($id !~ /\A[a-f0-9]{40}\z/) {
		$id = id_compress(mid_clean($id), 1);
	}
	'm' . $id;
}

sub thread_html_head {
	my ($hdr, $state) = @_;
	my $res = delete $state->{res} or die "BUG: no Plack callback in {res}";
	my $fh = $res->([200, ['Content-Type'=> 'text/html; charset=UTF-8']]);
	$state->{fh} = $fh;

	my $s = ascii_html($hdr->header('Subject'));
	$fh->write("<html><head><title>$s</title>".
		qq{<link\nrel=alternate\ntitle="Atom feed"\n} .
		qq!href="../t.atom"\ntype="application/atom+xml"/>! .
		PublicInbox::Hval::STYLE .
		"</head><body>");
}

sub pre_anchor_entry {
	my ($seen, $mime) = @_;
	my $id = anchor_for(mid_mime($mime));
	$seen->{$id} = "#$id"; # save the anchor for children, later
}

sub ghost_parent {
	my ($upfx, $mid) = @_;
	# 'subject dummy' is used internally by Mail::Thread
	return '[no common parent]' if ($mid eq 'subject dummy');

	$mid = PublicInbox::Hval->new_msgid($mid);
	my $href = $mid->as_href;
	my $html = $mid->as_html;
	qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
}

sub thread_adj_level {
	my ($state, $level) = @_;

	my $max = $state->{cur_level};
	if ($level <= 0) {
		return '' if $max == 0; # flat output

		# reset existing lists
		my $x = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
		$state->{fh}->write($x . '</ul>');
		$state->{cur_level} = 0;
		return '';
	}
	if ($level == $max) { # continue existing list
		$state->{fh}->write('<li>');
	} elsif ($level < $max) {
		my $x = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
		$state->{fh}->write($x .= '<li>');
		$state->{cur_level} = $level;
	} else { # ($level > $max) # start a new level
		$state->{cur_level} = $level;
		$state->{fh}->write(($max ? '<li>' : '') . '<ul><li>');
	}
	'</li>';
}

sub ghost_flush {
	my ($state, $upfx, $mid, $level) = @_;
	my $end = '<pre>'. ghost_parent($upfx, $mid) . '</pre>';
	$state->{fh}->write($end .= thread_adj_level($state, $level));
}

sub __thread_entry {
	my ($state, $mime, $level) = @_;

	# lazy load the full message from mini_mime:
	$mime = eval {
		my $path = mid2path(mid_clean(mid_mime($mime)));
		Email::MIME->new($state->{ctx}->{git}->cat_file('HEAD:'.$path));
	} or return;

	thread_html_head($mime, $state) if $state->{anchor_idx} == 0;
	if (my $ghost = delete $state->{ghost}) {
		# n.b. ghost messages may only be parents, not children
		foreach my $g (@$ghost) {
			ghost_flush($state, '../../', @$g);
		}
	}
	my $end = thread_adj_level($state, $level);
	index_entry($mime, $level, $state);
	$state->{fh}->write($end) if $end;

	1;
}

sub indent_for {
	my ($level) = @_;
	INDENT x ($level - 1);
}

sub __ghost_prepare {
	my ($state, $node, $level) = @_;
	my $ghost = $state->{ghost} ||= [];
	push @$ghost, [ $node->messageid, $level ];
}

sub thread_entry {
	my ($state, $node, $level) = @_;
	return unless $node;
	if (my $mime = $node->message) {
		unless (__thread_entry($state, $mime, $level)) {
			__ghost_prepare($state, $node, $level);
		}
	} else {
		__ghost_prepare($state, $node, $level);
	}

	thread_entry($state, $node->child, $level + 1);
	thread_entry($state, $node->next, $level);
}

sub load_results {
	my ($sres) = @_;

	[ map { $_->mini_mime } @{delete $sres->{msgs}} ];
}

sub msg_timestamp {
	my ($hdr) = @_;
	my $ts = eval { str2time($hdr->header('Date')) };
	defined($ts) ? $ts : 0;
}

sub thread_results {
	my ($msgs) = @_;
	require PublicInbox::Thread;
	my $th = PublicInbox::Thread->new(@$msgs);
	$th->thread;
	$th->order(*sort_ts);
	$th
}

sub missing_thread {
	my ($res, $ctx) = @_;
	require PublicInbox::ExtMsg;

	$res->(PublicInbox::ExtMsg::ext_msg($ctx))
}

sub _msg_date {
	my ($hdr) = @_;
	my $ts = $hdr->header('X-PI-TS') || msg_timestamp($hdr);
	fmt_ts($ts);
}

sub fmt_ts { POSIX::strftime('%Y-%m-%d %k:%M', gmtime($_[0])) }

sub _skel_header {
	my ($dst, $state, $upfx, $hdr, $level) = @_;

	my $cur = $state->{cur};
	my $mid = mid_clean($hdr->header_raw('Message-ID'));
	my $f = ascii_html($hdr->header('X-PI-From'));
	my $d = _msg_date($hdr);
	my $pfx = "$d " . indent_for($level) . th_pfx($level);
	my $attr = $f;
	$state->{first_level} ||= $level;

	if ($attr ne $state->{prev_attr} || $state->{prev_level} > $level) {
		$state->{prev_attr} = $attr;
	} else {
		$attr = '';
	}
	$state->{prev_level} = $level;

	if ($cur) {
		if ($cur eq $mid) {
			delete $state->{cur};
			$$dst .= "$pfx<b><a\nid=r\nhref=\"#t\">".
				 "$attr [this message]</a></b>\n";

			return;
		}
	} else {
		$state->{next_msg} ||= $mid;
	}

	# Subject is never undef, this mail was loaded from
	# our Xapian which would've resulted in '' if it were
	# really missing (and Filter rejects empty subjects)
	my $s = $hdr->header('Subject');
	my $h = $state->{srch}->subject_path($s);
	if ($state->{seen}->{$h}) {
		$s = undef;
	} else {
		$state->{seen}->{$h} = 1;
		$s = PublicInbox::Hval->new($s);
		$s = $s->as_html;
	}
	my $m = PublicInbox::Hval->new_msgid($mid);
	$m = $upfx . '../' . $m->as_href . '/';
	$$dst .= "$pfx<a\nhref=\"$m\">";
	$$dst .= defined($s) ? "$s</a> $f\n" : "$f</a>\n";
}

sub skel_dump {
	my ($dst, $state, $upfx, $node, $level) = @_;
	return unless $node;
	if (my $mime = $node->message) {
		my $hdr = $mime->header_obj;
		my $mid = mid_clean($hdr->header_raw('Message-ID'));
		_skel_header($dst, $state, $upfx, $hdr, $level);
	} else {
		my $mid = $node->messageid;
		if ($mid eq 'subject dummy') {
			$$dst .= "\t[no common parent]\n";
		} else {
			$$dst .= '     [not found] ';
			$$dst .= indent_for($level) . th_pfx($level);
			$mid = PublicInbox::Hval->new_msgid($mid);
			my $href = "$upfx../" . $mid->as_href . '/';
			my $html = $mid->as_html;
			$$dst .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
		}
	}
	skel_dump($dst, $state, $upfx, $node->child, $level+1);
	skel_dump($dst, $state, $upfx, $node->next, $level);
}

sub sort_ts {
	sort {
		(eval { $a->topmost->message->header('X-PI-TS') } || 0) <=>
		(eval { $b->topmost->message->header('X-PI-TS') } || 0)
	} @_;
}

# accumulate recent topics if search is supported
# returns 1 if done, undef if not
sub add_topic {
	my ($state, $node, $level) = @_;
	return unless $node;
	my $child_adjust = 1;

	if (my $x = $node->message) {
		$x = $x->header_obj;
		my $subj;

		$subj = $x->header('Subject');
		$subj = $state->{srch}->subject_normalized($subj);

		if (++$state->{subjs}->{$subj} == 1) {
			push @{$state->{order}}, [ $level, $subj ];
		}

		my $mid = mid_clean($x->header_raw('Message-ID'));

		my $ts = $x->header('X-PI-TS');
		my $exist = $state->{latest}->{$subj};
		if (!$exist || $exist->[1] < $ts) {
			$state->{latest}->{$subj} = [ $mid, $ts ];
		}
	} else {
		# ghost message, do not bump level
		$child_adjust = 0;
	}

	add_topic($state, $node->child, $level + $child_adjust);
	add_topic($state, $node->next, $level);
}

sub emit_topics {
	my ($state) = @_;
	my $order = $state->{order};
	my $subjs = $state->{subjs};
	my $latest = $state->{latest};
	my $fh = $state->{fh};
	return $fh->write("\n[No topics in range]</pre>") unless scalar @$order;
	my $pfx;
	my $prev = 0;
	my $prev_attr = '';
	my $cur;
	my @recent;
	while (defined(my $info = shift @$order)) {
		my ($level, $subj) = @$info;
		my $n = delete $subjs->{$subj};
		my ($mid, $ts) = @{delete $latest->{$subj}};
		$mid = PublicInbox::Hval->new_msgid($mid)->as_href;
		$subj = PublicInbox::Hval->new($subj)->as_html;
		$pfx = indent_for($level);
		my $nl = $level == $prev ? "\n" : '';
		if ($nl && $cur) {
			push @recent, $cur;
			$cur = undef;
		}
		$cur ||= [ $ts, '' ];
		$cur->[0] = $ts if $ts > $cur->[0];
		$cur->[1] .= $nl . $pfx . th_pfx($level) .
				"<a\nhref=\"$mid/t/#u\"><b>" .
				$subj . "</b></a>\n";

		$ts = fmt_ts($ts);
		my $attr = " $ts UTC";

		# $n isn't the total number of posts on the topic,
		# just the number of posts in the current results window
		$n = $n == 1 ? '' : " ($n+ messages)";

		if ($level == 0 || $attr ne $prev_attr) {
			my $mbox = qq(<a\nhref="$mid/t.mbox.gz">mbox.gz</a>);
			my $atom = qq(<a\nhref="$mid/t.atom">Atom</a>);
			$pfx .= INDENT if $level > 0;
			$cur->[1] .= $pfx . $attr . $n . " - $mbox / $atom\n";
			$prev_attr = $attr;
		}
	}
	push @recent, $cur if $cur;
	@recent = map { $_->[1] } sort { $b->[0] <=> $a->[0] } @recent;
	$fh->write(join('', @recent) . '</pre>');
}

sub emit_index_topics {
	my ($state) = @_;
	my $off = $state->{ctx}->{cgi}->param('o');
	$off = 0 unless defined $off;
	$state->{order} = [];
	$state->{subjs} = {};
	$state->{latest} = {};
	my $max = 25;
	my %opts = ( offset => int $off, limit => $max * 4 );
	while (scalar @{$state->{order}} < $max) {
		my $sres = $state->{srch}->query('', \%opts);
		my $nr = scalar @{$sres->{msgs}} or last;

		for (thread_results(load_results($sres))->rootset) {
			add_topic($state, $_, 0);
		}
		$opts{offset} += $nr;
	}

	emit_topics($state);
	$opts{offset};
}

1;