public-inbox.git  about / heads / tags
an "archives first" approach to mailing lists
blob 53a626261e58aecfa1580a31ace931783b098c05 12856 bytes (raw)
$ git show viewdiff:lib/PublicInbox/SolverGit.pm	# shows this blob on the CLI

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
 
# Copyright (C) 2019 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>

# "Solve" blobs which don't exist in git code repositories by
# searching inboxes for post-image blobs.

# this emits a lot of debugging/tracing information which may be
# publically viewed over HTTP(S).  Be careful not to expose
# local filesystem layouts in the process.
package PublicInbox::SolverGit;
use strict;
use warnings;
use File::Temp qw();
use Fcntl qw(SEEK_SET);
use PublicInbox::Git qw(git_unquote git_quote);
use PublicInbox::Spawn qw(spawn popen_rd);
use PublicInbox::MsgIter qw(msg_iter msg_part_text);
use URI::Escape qw(uri_escape_utf8);

# don't bother if somebody sends us a patch with these path components,
# it's junk at best, an attack attempt at worse:
my %bad_component = map { $_ => 1 } ('', '.', '..');

sub new {
	my ($class, $gits, $inboxes) = @_;
	bless {
		gits => $gits,
		inboxes => $inboxes,
	}, $class;
}

# look for existing blobs already in git repos
sub solve_existing ($$$) {
	my ($self, $out, $want) = @_;
	my $oid_b = $want->{oid_b};
	my @ambiguous; # Array of [ git, $oids]
	foreach my $git (@{$self->{gits}}) {
		my ($oid_full, $type, $size) = $git->check($oid_b);
		if (defined($type) && $type eq 'blob') {
			return [ $git, $oid_full, $type, int($size) ];
		}

		next if length($oid_b) == 40;

		# parse stderr of "git cat-file --batch-check"
		my $err = $git->last_check_err;
		my (@oids) = ($err =~ /\b([a-f0-9]{40})\s+blob\b/g);
		next unless scalar(@oids);

		# TODO: do something with the ambiguous array?
		# push @ambiguous, [ $git, @oids ];

		print $out "`$oid_b' ambiguous in ",
				join("\n", $git->pub_urls), "\n",
				join('', map { "$_ blob\n" } @oids), "\n";
	}
	scalar(@ambiguous) ? \@ambiguous : undef;
}

# returns a hashref with information about a diff ($di):
# {
#	oid_a => abbreviated pre-image oid,
#	oid_b => abbreviated post-image oid,
#	tmp => anonymous file handle with the diff,
#	hdr_lines => arrayref of various header lines for mode information
#	mode_a => original mode of oid_a (string, not integer),
#	ibx => PublicInbox::Inbox object containing the diff
#	smsg => PublicInbox::SearchMsg object containing diff
#	path_a => pre-image path
#	path_b => post-image path
# }
sub extract_diff ($$$$) {
	my ($p, $re, $ibx, $smsg) = @_;
	my ($part) = @$p; # ignore $depth and @idx;
	my $hdr_lines; # diff --git a/... b/...
	my $tmp;
	my $ct = $part->content_type || 'text/plain';
	my ($s, undef) = msg_part_text($part, $ct);
	defined $s or return;
	my $di = {};

	# Email::MIME::Encodings forces QP to be CRLF upon decoding,
	# change it back to LF:
	my $cte = $part->header('Content-Transfer-Encoding') || '';
	if ($cte =~ /\bquoted-printable\b/i && $part->crlf eq "\n") {
		$s =~ s/\r\n/\n/sg;
	}

	foreach my $l (split(/^/m, $s)) {
		if ($l =~ $re) {
			$di->{oid_a} = $1;
			$di->{oid_b} = $2;
			if (defined($3)) {
				my $mode_a = $3;
				if ($mode_a =~ /\A(?:100644|120000|100755)\z/) {
					$di->{mode_a} = $mode_a;
				}
			}

			# start writing the diff out to a tempfile
			open($tmp, '+>', undef) or die "open(tmp): $!";
			$di->{tmp} = $tmp;

			push @$hdr_lines, $l;
			$di->{hdr_lines} = $hdr_lines;
			print $tmp @$hdr_lines or die "print(tmp): $!";

			# for debugging/diagnostics:
			$di->{ibx} = $ibx;
			$di->{smsg} = $smsg;
		} elsif ($l =~ m!\Adiff --git ("?a/.+) ("?b/.+)$!) {
			return $di if $tmp; # got our blob, done!

			my ($path_a, $path_b) = ($1, $2);

			# diff header lines won't have \r because git
			# will quote them, but Email::MIME gives CRLF
			# for quoted-printable:
			$path_b =~ tr/\r//d;

			# don't care for leading 'a/' and 'b/'
			my (undef, @a) = split(m{/}, git_unquote($path_a));
			my (undef, @b) = split(m{/}, git_unquote($path_b));

			# get rid of path-traversal attempts and junk patches:
			foreach (@a, @b) {
				return if $bad_component{$_};
			}

			$di->{path_a} = join('/', @a);
			$di->{path_b} = join('/', @b);
			$hdr_lines = [ $l ];
		} elsif ($tmp) {
			print $tmp $l or die "print(tmp): $!";
		} elsif ($hdr_lines) {
			push @$hdr_lines, $l;
			if ($l =~ /\Anew file mode (100644|120000|100755)$/) {
				$di->{mode_a} = $1;
			}
		}
	}
	$tmp ? $di : undef;
}

sub path_searchable ($) { defined($_[0]) && $_[0] =~ m!\A[\w/\. \-]+\z! }

sub find_extract_diff ($$$) {
	my ($self, $ibx, $want) = @_;
	my $srch = $ibx->search or return;

	my $post = $want->{oid_b} or die 'BUG: no {oid_b}';
	$post =~ /\A[a-f0-9]+\z/ or die "BUG: oid_b not hex: $post";

	my $q = "dfpost:$post";
	my $pre = $want->{oid_a};
	if (defined $pre && $pre =~ /\A[a-f0-9]+\z/) {
		$q .= " dfpre:$pre";
	} else {
		$pre = '[a-f0-9]{7}'; # for $re below
	}

	my $path_b = $want->{path_b};
	if (path_searchable($path_b)) {
		$q .= qq{ dfn:"$path_b"};

		my $path_a = $want->{path_a};
		if (path_searchable($path_a) && $path_a ne $path_b) {
			$q .= qq{ dfn:"$path_a"};
		}
	}

	my $msgs = $srch->query($q, { relevance => 1 });
	my $re = qr/\Aindex ($pre[a-f0-9]*)\.\.($post[a-f0-9]*)(?: (\d+))?/;

	my $di;
	foreach my $smsg (@$msgs) {
		$ibx->smsg_mime($smsg) or next;
		msg_iter(delete($smsg->{mime}), sub {
			$di ||= extract_diff($_[0], $re, $ibx, $smsg);
		});
		return $di if $di;
	}
}

# pure Perl "git init"
sub do_git_init_wt ($) {
	my ($self) = @_;
	my $wt = File::Temp->newdir('solver.wt-XXXXXXXX', TMPDIR => 1);
	my $dir = $wt->dirname;

	foreach ('', qw(objects refs objects/info refs/heads)) {
		mkdir("$dir/.git/$_") or die "mkdir $_: $!";
	}
	open my $fh, '>', "$dir/.git/config" or die "open .git/config: $!";
	print $fh <<'EOF' or die "print .git/config $!";
[core]
	repositoryFormatVersion = 0
	filemode = true
	bare = false
	fsyncObjectfiles = false
	logAllRefUpdates = false
EOF
	close $fh or die "close .git/config: $!";

	open $fh, '>', "$dir/.git/HEAD" or die "open .git/HEAD: $!";
	print $fh "ref: refs/heads/master\n" or die "print .git/HEAD: $!";
	close $fh or die "close .git/HEAD: $!";

	my $f = '.git/objects/info/alternates';
	open $fh, '>', "$dir/$f" or die "open: $f: $!";
	print($fh (map { "$_->{git_dir}/objects\n" } @{$self->{gits}})) or
		die "print $f: $!";
	close $fh or die "close: $f: $!";
	$wt;
}

sub extract_old_mode ($) {
	my ($di) = @_;
	if (grep(/\Aold mode (100644|100755|120000)$/, @{$di->{hdr_lines}})) {
		return $1;
	}
	'100644';
}

sub reap ($$) {
	my ($pid, $msg) = @_;
	waitpid($pid, 0) == $pid or die "waitpid($msg): $!";
	$? == 0 or die "$msg failed: $?";
}

sub prepare_index ($$$$) {
	my ($out, $wt_dir, $existing, $di) = @_;
	my $oid_full = $existing->[1];
	my ($r, $w);
	my $path_a = $di->{path_a} or die "BUG: path_a missing for $oid_full";
	my $mode_a = $di->{mode_a} || extract_old_mode($di);

	# unlike git-apply(1), this only gets called once in a patch
	# series and happens too quickly to be worth making async:
	pipe($r, $w) or die "pipe: $!";
	my $rdr = { 0 => fileno($r) };
	my $pid = spawn([qw(git -C), $wt_dir,
			 qw(update-index -z --index-info)], undef, $rdr);
	close $r or die "close pipe(r): $!";
	print $w "$mode_a $oid_full\t$path_a\0" or die "print update-index: $!";

	close $w or die "close update-index: $!";
	reap($pid, 'update-index -z --index-info');

	print $out "index prepared:\n",
		"$mode_a $oid_full\t", git_quote($path_a), "\n";
}

sub do_apply_begin ($$$) {
	my ($out, $wt_dir, $di) = @_;

	my $tmp = delete $di->{tmp} or die "BUG: no tmp ", di_url($di);
	$tmp->flush or die "tmp->flush failed: $!";
	$out->flush or die "err->flush failed: $!";
	sysseek($tmp, 0, SEEK_SET) or die "sysseek(tmp) failed: $!";

	defined(my $err_fd = fileno($out)) or die "fileno(out): $!";
	my $rdr = { 0 => fileno($tmp), 1 => $err_fd, 2 => $err_fd };

	# we need --ignore-whitespace because some patches are CRLF
	my $cmd = [ qw(git -C), $wt_dir,
	            qw(apply --cached --ignore-whitespace
		       --whitespace=warn --verbose) ];
	spawn($cmd, undef, $rdr);
}

sub do_apply_continue ($$) {
	my ($wt_dir, $apply_pid) = @_;
	reap($apply_pid, 'apply');
	popen_rd([qw(git -C), $wt_dir, qw(ls-files -s -z)]);
}

sub do_apply_end ($$$$) {
	my ($out, $wt_git, $rd, $di) = @_;

	local $/ = "\0";
	defined(my $line = <$rd>) or die "failed to read ls-files: $!";
	chomp $line or die "no trailing \\0 in [$line] from ls-files";

	my ($info, $file) = split(/\t/, $line, 2);
	my ($mode_b, $oid_b_full, $stage) = split(/ /, $info);

	defined($line = <$rd>) and die "extra files in index: $line";
	close $rd or die "close ls-files: $?";

	$file eq $di->{path_b} or
		die "index mismatch: file=$file != path_b=$di->{path_b}";

	my (undef, undef, $size) = $wt_git->check($oid_b_full);

	defined($size) or die "failed to read_size from $oid_b_full";

	print $out "$mode_b $oid_b_full\t$file\n";
	[ $wt_git, $oid_b_full, 'blob', $size, $di ];
}

sub di_url ($) {
	my ($di) = @_;
	# note: we don't pass the PSGI env here, different inboxes
	# can have different HTTP_HOST on the same instance.
	my $url = $di->{ibx}->base_url;
	my $mid = $di->{smsg}->{mid};
	defined($url) ? "$url$mid/" : "<$mid>";
}

# reconstruct the oid_b blob using patches we found:
sub apply_patches_cb ($$$$$) {
	my ($self, $out, $found, $patches, $oid_b) = @_;

	my $tot = scalar(@$patches) or return sub {
		print $out "no patch(es) for $oid_b\n";
		undef;
	};

	my $wt = do_git_init_wt($self);
	my $wt_dir = $wt->dirname;
	my $wt_git = PublicInbox::Git->new("$wt_dir/.git");
	$wt_git->{-wt} = $wt;

	my $cur = 0;
	my ($apply_pid, $rd, $di);

	# returns an empty string if in progress, undef if not found,
	# or the final [ ::Git, oid_full, type, size, $di ] arrayref
	# if found
	sub {
		if ($rd) {
			$found->{$di->{oid_b}} =
					do_apply_end($out, $wt_git, $rd, $di);
			$rd = undef;
			# continue to shift @$patches
		} elsif ($apply_pid) {
			$rd = do_apply_continue($wt_dir, $apply_pid);
			$apply_pid = undef;
			return ''; # $rd => do_apply_ned
		}

		# may return undef here
		$di = shift @$patches or return $found->{$oid_b};

		my $i = ++$cur;
		my $oid_a = $di->{oid_a};
		my $existing = $found->{$oid_a};
		my $empty_oid = $oid_a =~ /\A0+\z/;

		if ($empty_oid && $i != 1) {
			die "empty oid at [$i/$tot] ", di_url($di);
		}
		if (!$existing && !$empty_oid) {
			die "missing $oid_a at [$i/$tot] ", di_url($di);
		}

		# prepare the worktree for patch application:
		if ($i == 1 && $existing) {
			prepare_index($out, $wt_dir, $existing, $di);
		}

		print $out "\napplying [$i/$tot] ", di_url($di), "\n",
			   join('', @{$di->{hdr_lines}}), "\n"
			or die "print \$out failed: $!";

		# begin the patch application patch!
		$apply_pid = do_apply_begin($out, $wt_dir, $di);
		# next call to this callback will call do_apply_continue
		'';
	}
}

# recreate $oid_b
# Returns an array ref: [ ::Git object, oid_full, type, size, di ]
# or undef if nothing was found.
#
# TODO: complete the migration of this and ViewVCS into an evented
# model for fairness
sub solve ($$$$) {
	my ($self, $out, $oid_b, $hints) = @_;

	# should we even get here? Probably not, but somebody
	# could be manually typing URLs:
	return if $oid_b =~ /\A0+\z/;

	my $req = { %$hints, oid_b => $oid_b };
	my @todo = ($req);
	my $found = {}; # { abbrev => [ ::Git, oid_full, type, size, $di ] }
	my $patches = []; # [ array of $di hashes ]
	my $max = $self->{max_patches} || 200;
	my $apply_cb;
	my $cb = sub {
		my $want = pop @todo;
		unless ($want) {
			$apply_cb ||= apply_patches_cb($self, $out, $found,
			                               $patches, $oid_b);
			return $apply_cb->();
		}

		if (scalar(@$patches) > $max) {
			print $out "Aborting, too many steps to $oid_b\n";
			return;
		}
		# see if we can find the blob in an existing git repo:
		my $want_oid = $want->{oid_b};
		if (my $existing = solve_existing($self, $out, $want)) {
			print $out "found $want_oid in ",
				join("\n", $existing->[0]->pub_urls), "\n";

			return $existing if $want_oid eq $oid_b; # DONE!
			$found->{$want_oid} = $existing;
			return ''; # ok, one blob resolved, more to go?
		}

		# scan through inboxes to look for emails which results in
		# the oid we want:
		my $di;
		foreach my $ibx (@{$self->{inboxes}}) {
			$di = find_extract_diff($self, $ibx, $want) or next;

			unshift @$patches, $di;
			print $out "found $want_oid in ",di_url($di),"\n";

			# good, we can find a path to the oid we $want, now
			# lets see if we need to apply more patches:
			my $src = $di->{oid_a};

			last if $src =~ /\A0+\z/;

			# we have to solve it using another oid, fine:
			my $job = { oid_b => $src, path_b => $di->{path_a} };
			push @todo, $job;
			last; # onto the next @todo item
		}
		unless ($di) {
			print $out "$want_oid could not be found\n";
			return;
		}
		''; # continue onto next @todo item;
	};

	while (1) {
		my $ret = eval { $cb->() };
		unless (defined($ret)) {
			print $out "E: $@\n" if $@;
			return;
		}
		return $ret if ref($ret);
		# $ret == ''; so continue looping here
	}
}

1;

git clone https://public-inbox.org/public-inbox.git
git clone http://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/public-inbox.git