public-inbox.git  about / heads / tags
an "archives first" approach to mailing lists
blob 4401a29b963fed06abcb670a93a8cc16f55defc9 1803 bytes (raw)
$ git show HEAD:lib/PublicInbox/NNTPD.pm	# shows this blob on the CLI

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
 
# Copyright (C) all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>

# represents an NNTPD (currently a singleton),
# see script/public-inbox-nntpd for how it is used
package PublicInbox::NNTPD;
use strict;
use v5.10.1;
use Sys::Hostname;
use PublicInbox::Config;
use PublicInbox::InboxIdle;
use PublicInbox::NNTP;

sub new {
	my ($class) = @_;
	bless {
		err => \*STDERR,
		out => \*STDOUT,
		# pi_cfg => $pi_cfg,
		# ssl_ctx_opt => { SSL_cert_file => ..., SSL_key_file => ... }
		# idler => PublicInbox::InboxIdle
	}, $class;
}

sub refresh_groups {
	my ($self, $sig) = @_;
	my $pi_cfg = PublicInbox::Config->new;
	my $name = $pi_cfg->{'publicinbox.nntpserver'};
	if (!defined($name) or $name eq '') {
		$name = hostname;
	} elsif (ref($name) eq 'ARRAY') {
		$name = $name->[0];
	}
	if ($name ne ($self->{servername} // '')) {
		$self->{servername} = $name;
		$self->{greet} = \"201 $name ready - post via email\r\n";
	}
	my $groups = $pi_cfg->{-by_newsgroup}; # filled during each_inbox
	my $cache = eval { $pi_cfg->ALL->misc->nntpd_cache_load } // {};
	$pi_cfg->each_inbox(sub {
		my ($ibx) = @_;
		my $ngname = $ibx->{newsgroup} // return;
		my $ce = $cache->{$ngname};
		if (($ce and (%$ibx = (%$ibx, %$ce))) || $ibx->nntp_usable) {
			# only valid if msgmap and over works
			# preload to avoid fragmentation:
			$ibx->description;
		} else {
			delete $groups->{$ngname};
			# Note: don't be tempted to delete more for memory
			# savings just yet: NNTP, IMAP, and WWW may all
			# run in the same process someday.
		}
	});
	@{$self->{groupnames}} = sort(keys %$groups);
	# this will destroy old groups that got deleted
	$self->{pi_cfg} = $pi_cfg;
}

sub idler_start {
	$_[0]->{idler} //= PublicInbox::InboxIdle->new($_[0]->{pi_cfg});
}

1;

git clone https://public-inbox.org/public-inbox.git
git clone http://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/public-inbox.git