public-inbox.git  about / heads / tags
an "archives first" approach to mailing lists
blob 2565ea58a07d327b94c8947ceb705427c17fc0fb 3909 bytes (raw)
$ git show repobrowse:lib/PublicInbox/Mbox.pm	# shows this blob on the CLI

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
 
# Copyright (C) 2015 all contributors <meta@public-inbox.org>
# License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)

# Streaming interface for formatting messages as an mboxrd.
# Used by the web interface
package PublicInbox::Mbox;
use strict;
use warnings;
use PublicInbox::MID qw/mid_clean mid_escape/;
require Email::Simple;

sub emit1 {
	my ($ctx, $msg) = @_;
	$msg = Email::Simple->new($msg);
	# single message should be easily renderable in browsers
	[200, ['Content-Type', 'text/plain'], [ msg_str($ctx, $msg)] ]
}

sub msg_str {
	my ($ctx, $simple) = @_; # Email::Simple object
	my $header_obj = $simple->header_obj;

	# drop potentially confusing headers, ssoma already should've dropped
	# Lines and Content-Length
	foreach my $d (qw(Lines Bytes Content-Length Status)) {
		$header_obj->header_set($d);
	}
	my $ibx = $ctx->{-inbox};
	my $base = $ibx->base_url($ctx->{env});
	my $mid = mid_clean($header_obj->header('Message-ID'));
	$mid = mid_escape($mid);
	my @append = (
		'Archived-At', "<$base$mid/>",
		'List-Archive', "<$base>",
		'List-Post', "<mailto:$ibx->{-primary_address}>",
	);
	my $crlf = $simple->crlf;
	my $buf = "From mboxrd\@z Thu Jan  1 00:00:00 1970\n" .
			$header_obj->as_string;
	for (my $i = 0; $i < @append; $i += 2) {
		my $k = $append[$i];
		my $v = $append[$i + 1];
		my @v = $header_obj->header($k);
		foreach (@v) {
			if ($v eq $_) {
				$v = undef;
				last;
			}
		}
		$buf .= "$k: $v$crlf" if defined $v;
	}
	$buf .= $crlf;

	# mboxrd quoting style
	# ref: http://www.qmail.org/man/man5/mbox.html
	my $body = $simple->body;
	$body =~ s/^(>*From )/>$1/gm;
	$buf .= $body;
	$buf .= "\n";
}

sub thread_mbox {
	my ($ctx, $srch, $sfx) = @_;
	eval { require IO::Compress::Gzip };
	return sub { need_gzip(@_) } if $@;

	my $cb = sub { $srch->get_thread($ctx->{mid}, @_) };
	# http://www.iana.org/assignments/media-types/application/gzip
	[200, ['Content-Type' => 'application/gzip'],
		PublicInbox::MboxGz->new($ctx, $cb) ];
}

sub emit_range {
	my ($ctx, $range) = @_;

	eval { require IO::Compress::Gzip };
	return sub { need_gzip(@_) } if $@;
	my $query;
	if ($range eq 'all') { # TODO: YYYY[-MM]
		$query = '';
	} else {
		return [404, [qw(Content-Type text/plain)], []];
	}
	my $cb = sub { $ctx->{srch}->query($query, @_) };

	# http://www.iana.org/assignments/media-types/application/gzip
	[200, [qw(Content-Type application/gzip)],
		PublicInbox::MboxGz->new($ctx, $cb) ];
}

sub need_gzip {
	my $fh = $_[0]->([501, ['Content-Type' => 'text/html']]);
	my $title = 'gzipped mbox not available';
	$fh->write(<<EOF);
<html><head><title>$title</title><body><pre>$title
The administrator needs to install the IO::Compress::Gzip Perl module
to support gzipped mboxes.
<a href="../">Return to index</a></pre></body></html>
EOF
	$fh->close;
}

1;

package PublicInbox::MboxGz;
use strict;
use warnings;

sub new {
	my ($class, $ctx, $cb) = @_;
	my $buf = '';
	bless {
		buf => \$buf,
		gz => IO::Compress::Gzip->new(\$buf, Time => 0),
		cb => $cb,
		ctx => $ctx,
		msgs => [],
		opts => { offset => 0 },
	}, $class;
}

# called by Plack::Util::foreach or similar
sub getline {
	my ($self) = @_;
	my $ctx = $self->{ctx} or return;
	my $res;
	my $ibx = $ctx->{-inbox};
	my $gz = $self->{gz};
	do {
		while (defined(my $smsg = shift @{$self->{msgs}})) {
			my $msg = eval { $ibx->msg_by_smsg($smsg) } or next;
			$msg = Email::Simple->new($msg);
			$gz->write(PublicInbox::Mbox::msg_str($ctx, $msg));
			my $bref = $self->{buf};
			if (length($$bref) >= 8192) {
				my $ret = $$bref; # copy :<
				${$self->{buf}} = '';
				return $ret;
			}

			# be fair to other clients on public-inbox-httpd:
			return '';
		}
		$res = $self->{cb}->($self->{opts});
		$self->{msgs} = $res->{msgs};
		$res = scalar @{$self->{msgs}};
		$self->{opts}->{offset} += $res;
	} while ($res);
	$gz->close;
	delete $self->{ctx};
	${delete $self->{buf}};
}

sub close {} # noop

1;

git clone https://public-inbox.org/public-inbox.git
git clone http://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/public-inbox.git