about summary refs log tree commit homepage
path: root/lib/PublicInbox/MDA.pm
blob: e2b2f9143083c0b1979d283fda7d2b985096e9a9 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
# Copyright (C) 2013, Eric Wong <normalperson@yhbt.net> and all contributors
# License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
package PublicInbox::MDA;
use strict;
use warnings;
use Email::Address;
use Encode qw/decode/;
use Date::Parse qw(strptime);
use constant MAX_SIZE => 1024 * 500; # same as spamc default, should be tunable
use constant cmd => qw/ssoma-mda -1/;

# drop plus addressing for matching
sub __drop_plus {
	my ($str_addr) = @_;
	$str_addr =~ s/\+.*\@/\@/;
	$str_addr;
}

# do not allow Bcc, only Cc and To if recipient is set
sub precheck {
	my ($klass, $filter, $address) = @_;
	my $simple = $filter->simple;
	my $mid = $simple->header("Message-ID");
	return 0 unless usable_str(length('<m@h>'), $mid) && $mid =~ /\@/;
	return 0 unless usable_str(length('u@h'), $filter->from);
	return 0 unless usable_str(length(':o'), $simple->header("Subject"));
	return 0 unless usable_date($simple->header("Date"));
	return 0 if length($simple->as_string) > MAX_SIZE;
	alias_specified($filter, $address);
}

sub usable_str {
	my ($len, $str) = @_;
	defined($str) && length($str) >= $len;
}

sub usable_date {
	my @t = eval { strptime(@_) };
	scalar @t;
}

sub alias_specified {
	my ($filter, $address) = @_;

	my @address = ref($address) eq 'ARRAY' ? @$address : ($address);
	my %ok = map {
		my @recip = Email::Address->parse($_);
		lc(__drop_plus($recip[0]->address)) => 1;
	} @address;

	foreach my $line ($filter->cc, $filter->to) {
		foreach my $addr (Email::Address->parse($line)) {
			if ($ok{lc(__drop_plus($addr->address))}) {
				return 1;
			}
		}
	}
	return 0;
}

# RFC2919 and RFC2369
sub set_list_headers {
	my ($class, $simple, $dst) = @_;
	my $pa = "<$dst->{-primary_address}>";
	$simple->header_set("List-Id", $pa);
	$simple->header_set("List-Post", $pa);

	my $url = $dst->{url};
	if (defined $url) {
		$simple->header_set("List-Archive", "<$url>");
		$simple->header_set("List-Help", "<${url}help>");
	}
}

# returns a 3-element array: name, email, date
sub author_info {
	my ($class, $mime) = @_;

	my $from = $mime->header('From');
	my @from = Email::Address->parse($from);
	my $name = $from[0]->name;
	defined $name or $name = '';
	my $email = $from[0]->address;
	defined $email or $email = '';
	($name, $email, $mime->header('Date'));
}

1;