public-inbox.git  about / heads / tags
an "archives first" approach to mailing lists
blob ddaf3312ade566b50b6d051b32772c846107337b 1871 bytes (raw)
$ git show HEAD:lib/PublicInbox/Lock.pm	# shows this blob on the CLI

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
 
# Copyright (C) all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>

# Base class for per-inbox locking, subclassed by several
# only uses {lock_path} and {lockfh} fields
package PublicInbox::Lock;
use v5.12;
use Fcntl qw(LOCK_UN LOCK_EX O_RDWR O_CREAT);
use Carp qw(croak);
use PublicInbox::OnDestroy;
use Errno qw(EINTR);
use autodie qw(close sysopen syswrite);

sub xflock ($$) {
	until (flock($_[0], $_[1])) { return if $! != EINTR }
	1;
}

sub new { bless { lock_path => $_[1] }, $_[0] }

# we only acquire the flock if creating or reindexing;
# PublicInbox::Import already has the lock on its own.
sub lock_acquire {
	my ($self) = @_;
	my $fn = $self->{lock_path};
	croak 'already locked '.($fn // '(undef)') if $self->{lockfh};
	$fn // return;
	sysopen(my $fh, $fn, O_RDWR|O_CREAT);
	xflock($fh, LOCK_EX) or croak "LOCK_EX $fn: $!";
	$self->{lockfh} = $fh;
}

sub lock_release {
	my ($self, $wake) = @_;
	my $fn = $self->{lock_path} // return;
	my $fh = delete $self->{lockfh} or croak "not locked: $fn";
	syswrite($fh, '.') if $wake;
	xflock($fh, LOCK_UN) or croak "LOCK_UN $fn: $!";
	close $fh; # may detect errors
}

# caller must use return value
sub lock_for_scope {
	my ($self, @single_pid) = @_;
	lock_acquire($self) or return; # lock_path not set
	PublicInbox::OnDestroy->new(@single_pid, \&lock_release, $self);
}

sub lock_acquire_fast {
	my $fh = $_[0]->{lockfh} or return lock_acquire($_[0]);
	xflock($fh, LOCK_EX) or croak "LOCK_EX $_[0]->{lock_path}: $!";
}

sub lock_release_fast {
	xflock($_[0]->{lockfh} // return, LOCK_UN) or
		croak "LOCK_UN $_[0]->{lock_path}: $!"
}

# caller must use return value
sub lock_for_scope_fast {
	my ($self, @single_pid) = @_;
	lock_acquire_fast($self) or return; # lock_path not set
	PublicInbox::OnDestroy->new(@single_pid, \&lock_release_fast, $self);
}

1;

git clone https://public-inbox.org/public-inbox.git
git clone http://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/public-inbox.git