public-inbox.git  about / heads / tags
an "archives first" approach to mailing lists
blob 8ba41ba5fbea4285b5de6dccb1a3db8cf6efb5cc 12604 bytes (raw)
$ git show repobrowse:lib/PublicInbox/HTTP.pm	# shows this blob on the CLI

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
 
# Copyright (C) 2016 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
#
# Generic PSGI server for convenience.  It aims to provide
# a consistent experience for public-inbox admins so they don't have
# to learn different ways to admin both NNTP and HTTP components.
# There's nothing which depends on public-inbox, here.
# Each instance of this class represents a HTTP client socket

package PublicInbox::HTTP;
use strict;
use warnings;
use base qw(Danga::Socket);
use fields qw(httpd env rbuf input_left remote_addr remote_port forward pull);
use Fcntl qw(:seek);
use Plack::HTTPParser qw(parse_http_request); # XS or pure Perl
use HTTP::Status qw(status_message);
use HTTP::Date qw(time2str);
use IO::Handle;
use constant {
	CHUNK_START => -1,   # [a-f0-9]+\r\n
	CHUNK_END => -2,     # \r\n
	CHUNK_ZEND => -3,    # \r\n
	CHUNK_MAX_HDR => 256,
};

my $pipelineq = [];
my $pipet;
sub process_pipelineq () {
	my $q = $pipelineq;
	$pipet = undef;
	$pipelineq = [];
	foreach (@$q) {
		next if $_->{closed};
		rbuf_process($_);
	}
}

# Use the same configuration parameter as git since this is primarily
# a slow-client sponge for git-http-backend
# TODO: support per-respository http.maxRequestBuffer somehow...
our $MAX_REQUEST_BUFFER = $ENV{GIT_HTTP_MAX_REQUEST_BUFFER} ||
			(10 * 1024 * 1024);

open(my $null_io, '<', '/dev/null') or die "failed to open /dev/null: $!";
my $http_date;
my $prev = 0;
sub http_date () {
	my $now = time;
	$now == $prev ? $http_date : ($http_date = time2str($prev = $now));
}

sub new ($$$) {
	my ($class, $sock, $addr, $httpd) = @_;
	my $self = fields::new($class);
	$self->SUPER::new($sock);
	$self->{httpd} = $httpd;
	$self->{rbuf} = '';
	($self->{remote_addr}, $self->{remote_port}) =
		PublicInbox::Daemon::host_with_port($addr);
	$self->watch_read(1);
	$self;
}

sub event_read { # called by Danga::Socket
	my ($self) = @_;

	return event_read_input($self) if defined $self->{env};

	my $off = length($self->{rbuf});
	my $r = sysread($self->{sock}, $self->{rbuf}, 8192, $off);
	if (defined $r) {
		return $self->close if $r == 0;
		return rbuf_process($self);
	}
	return if $!{EAGAIN}; # no need to call watch_read(1) again

	# common for clients to break connections without warning,
	# would be too noisy to log here:
	return $self->close;
}

sub rbuf_process {
	my ($self) = @_;

	my %env = %{$self->{httpd}->{env}}; # full hash copy
	my $r = parse_http_request($self->{rbuf}, \%env);

	# We do not support Trailers in chunked requests, for now
	# (they are rarely-used and git (as of 2.7.2) does not use them)
	if ($r == -1 || $env{HTTP_TRAILER} ||
			# this length-check is necessary for PURE_PERL=1:
			($r == -2 && length($self->{rbuf}) > 0x4000)) {
		return quit($self, 400);
	}
	return $self->watch_read(1) if $r < 0; # incomplete
	$self->{rbuf} = substr($self->{rbuf}, $r);

	my $len = input_prepare($self, \%env);
	defined $len or return write_err($self, undef); # EMFILE/ENFILE

	$len ? event_read_input($self) : app_dispatch($self);
}

sub event_read_input ($) {
	my ($self) = @_;
	my $env = $self->{env};
	return event_read_input_chunked($self) if env_chunked($env);

	# env->{CONTENT_LENGTH} (identity)
	my $sock = $self->{sock};
	my $len = $self->{input_left};
	$self->{input_left} = undef;
	my $rbuf = \($self->{rbuf});
	my $input = $env->{'psgi.input'};

	while ($len > 0) {
		if ($$rbuf ne '') {
			my $w = write_in_full($input, $rbuf, $len);
			return write_err($self, $len) unless $w;
			$len -= $w;
			die "BUG: $len < 0 (w=$w)" if $len < 0;
			if ($len == 0) { # next request may be pipelined
				$$rbuf = substr($$rbuf, $w);
				last;
			}
			$$rbuf = '';
		}
		my $r = sysread($sock, $$rbuf, 8192);
		return recv_err($self, $r, $len) unless $r;
		# continue looping if $r > 0;
	}
	app_dispatch($self, $input);
}

sub app_dispatch {
	my ($self, $input) = @_;
	$self->watch_read(0);
	my $env = $self->{env};
	$env->{REMOTE_ADDR} = $self->{remote_addr};
	$env->{REMOTE_PORT} = $self->{remote_port};
	if (my $host = $env->{HTTP_HOST}) {
		$host =~ s/:(\d+)\z// and $env->{SERVER_PORT} = $1;
		$env->{SERVER_NAME} = $host;
	}
	if (defined $input) {
		sysseek($input, 0, SEEK_SET) or
			die "BUG: psgi.input seek failed: $!";
	}
	# note: NOT $self->{sock}, we want our close (+ Danga::Socket::close),
	# to do proper cleanup:
	$env->{'psgix.io'} = $self; # only for ->close
	my $res = Plack::Util::run_app($self->{httpd}->{app}, $env);
	eval {
		if (ref($res) eq 'CODE') {
			$res->(sub { response_write($self, $env, $_[0]) });
		} else {
			response_write($self, $env, $res);
		}
	};
	$self->close if $@;
}

sub response_header_write {
	my ($self, $env, $res) = @_;
	my $proto = $env->{SERVER_PROTOCOL} or return; # HTTP/0.9 :P
	my $status = $res->[0];
	my $h = "$proto $status " . status_message($status) . "\r\n";
	my ($len, $chunked);
	my $headers = $res->[1];

	for (my $i = 0; $i < @$headers; $i += 2) {
		my $k = $headers->[$i];
		my $v = $headers->[$i + 1];
		next if $k =~ /\A(?:Connection|Date)\z/i;

		$len = $v if $k =~ /\AContent-Length\z/i;
		if ($k =~ /\ATransfer-Encoding\z/i && $v =~ /\bchunked\b/i) {
			$chunked = 1;
		}
		$h .= "$k: $v\r\n";
	}

	my $conn = $env->{HTTP_CONNECTION} || '';
	my $term = defined($len) || $chunked;
	my $prot_persist = ($proto eq 'HTTP/1.1') && ($conn !~ /\bclose\b/i);
	my $alive;
	if (!$term && $prot_persist) { # auto-chunk
		$chunked = $alive = 2;
		$h .= "Transfer-Encoding: chunked\r\n";
		# no need for "Connection: keep-alive" with HTTP/1.1
	} elsif ($term && ($prot_persist || ($conn =~ /\bkeep-alive\b/i))) {
		$alive = 1;
		$h .= "Connection: keep-alive\r\n";
	} else {
		$alive = 0;
		$h .= "Connection: close\r\n";
	}
	$h .= 'Date: ' . http_date() . "\r\n\r\n";

	if (($len || $chunked) && $env->{REQUEST_METHOD} ne 'HEAD') {
		more($self, $h);
	} else {
		$self->write($h);
	}
	$alive;
}

# middlewares such as Deflater may write empty strings
sub chunked_wcb ($) {
	my ($self) = @_;
	sub {
		return if $_[0] eq '';
		more($self, sprintf("%x\r\n", bytes::length($_[0])));
		more($self, $_[0]);

		# use $self->write("\n\n") if you care about real-time
		# streaming responses, public-inbox WWW does not.
		more($self, "\r\n");
	}
}

sub identity_wcb ($) {
	my ($self) = @_;
	sub { $self->write(\($_[0])) if $_[0] ne '' }
}

sub next_request ($) {
	my ($self) = @_;
	$self->watch_write(0);
	if ($self->{rbuf} eq '') { # wait for next request
		$self->watch_read(1);
	} else { # avoid recursion for pipelined requests
		push @$pipelineq, $self;
		$pipet ||= PublicInbox::EvCleanup::asap(*process_pipelineq);
	}
}

sub response_done_cb ($$) {
	my ($self, $alive) = @_;
	sub {
		my $env = $self->{env};
		$self->{env} = undef;
		%$env = () if $env; # prevent circular references
		$self->write("0\r\n\r\n") if $alive == 2;
		$self->write(sub{$alive ? next_request($self) : $self->close});
	}
}

sub getline_cb ($$$) {
	my ($self, $write, $close) = @_;
	local $/ = \8192;
	my $forward = $self->{forward};
	# limit our own running time for fairness with other
	# clients and to avoid buffering too much:
	if ($forward) {
		my $buf = eval { $forward->getline };
		if (defined $buf) {
			$write->($buf); # may close in Danga::Socket::write
			unless ($self->{closed}) {
				my $next = $self->{pull};
				if ($self->{write_buf_size}) {
					$self->write($next);
				} else {
					PublicInbox::EvCleanup::asap($next);
				}
				return;
			}
		} elsif ($@) {
			err($self, "response ->getline error: $@");
			$forward = undef;
			$self->close;
		}
	}

	$self->{forward} = $self->{pull} = undef;
	# avoid recursion
	if ($forward) {
		eval { $forward->close };
		if ($@) {
			err($self, "response ->close error: $@");
			$self->close; # idempotent
		}
	}
	$close->();
}

sub getline_response ($$$) {
	my ($self, $write, $close) = @_;
	my $pull = $self->{pull} = sub { getline_cb($self, $write, $close) };
	$pull->();
}

sub response_write {
	my ($self, $env, $res) = @_;
	my $alive = response_header_write($self, $env, $res);
	my $close = response_done_cb($self, $alive);
	my $write = $alive == 2 ? chunked_wcb($self) : identity_wcb($self);
	if (defined(my $body = $res->[2])) {
		if (ref $body eq 'ARRAY') {
			$write->($_) foreach @$body;
			$close->();
		} else {
			$self->{forward} = $body;
			getline_response($self, $write, $close);
		}
	} else {
		# this is returned to the calling application:
		Plack::Util::inline_object(write => $write, close => $close);
	}
}

use constant MSG_MORE => ($^O eq 'linux') ? 0x8000 : 0;
sub more ($$) {
	my $self = $_[0];
	return if $self->{closed};
	if (MSG_MORE && !$self->{write_buf_size}) {
		my $n = send($self->{sock}, $_[1], MSG_MORE);
		if (defined $n) {
			my $dlen = length($_[1]);
			return 1 if $n == $dlen; # all done!
			$_[1] = substr($_[1], $n, $dlen - $n);
			# fall through to normal write:
		}
	}
	$self->write($_[1]);
}

sub input_prepare {
	my ($self, $env) = @_;
	my $input;
	my $len = $env->{CONTENT_LENGTH};
	if ($len) {
		if ($len > $MAX_REQUEST_BUFFER) {
			quit($self, 413);
			return;
		}
		open($input, '+>', undef);
	} elsif (env_chunked($env)) {
		$len = CHUNK_START;
		open($input, '+>', undef);
	} else {
		$input = $null_io;
	}

	# TODO: expire idle clients on ENFILE / EMFILE
	return unless $input;

	$env->{'psgi.input'} = $input;
	$self->{env} = $env;
	$self->{input_left} = $len || 0;
}

sub env_chunked { ($_[0]->{HTTP_TRANSFER_ENCODING} || '') =~ /\bchunked\b/i }

sub err ($$) {
	eval { $_[0]->{httpd}->{env}->{'psgi.errors'}->print($_[1]."\n") };
}

sub write_err {
	my ($self, $len) = @_;
	my $msg = $! || '(zero write)';
	$msg .= " ($len bytes remaining)" if defined $len;
	err($self, "error buffering to input: $msg");
	quit($self, 500);
}

sub recv_err {
	my ($self, $r, $len) = @_;
	return $self->close if (defined $r && $r == 0);
	if ($!{EAGAIN}) {
		$self->{input_left} = $len;
		return;
	}
	err($self, "error reading for input: $! ($len bytes remaining)");
	quit($self, 500);
}

sub write_in_full {
	my ($fh, $rbuf, $len) = @_;
	my $rv = 0;
	my $off = 0;
	while ($len > 0) {
		my $w = syswrite($fh, $$rbuf, $len, $off);
		return ($rv ? $rv : $w) unless $w; # undef or 0
		$rv += $w;
		$off += $w;
		$len -= $w;
	}
	$rv
}

sub event_read_input_chunked { # unlikely...
	my ($self) = @_;
	my $input = $self->{env}->{'psgi.input'};
	my $sock = $self->{sock};
	my $len = $self->{input_left};
	$self->{input_left} = undef;
	my $rbuf = \($self->{rbuf});

	while (1) { # chunk start
		if ($len == CHUNK_ZEND) {
			$$rbuf =~ s/\A\r\n//s and
				return app_dispatch($self, $input);
			return quit($self, 400) if length($$rbuf) > 2;
		}
		if ($len == CHUNK_END) {
			if ($$rbuf =~ s/\A\r\n//s) {
				$len = CHUNK_START;
			} elsif (length($$rbuf) > 2) {
				return quit($self, 400);
			}
		}
		if ($len == CHUNK_START) {
			if ($$rbuf =~ s/\A([a-f0-9]+).*?\r\n//i) {
				$len = hex $1;
				if (($len + -s $input) > $MAX_REQUEST_BUFFER) {
					return quit($self, 413);
				}
			} elsif (length($$rbuf) > CHUNK_MAX_HDR) {
				return quit($self, 400);
			}
			# will break from loop since $len >= 0
		}

		if ($len < 0) { # chunk header is trickled, read more
			my $off = length($$rbuf);
			my $r = sysread($sock, $$rbuf, 8192, $off);
			return recv_err($self, $r, $len) unless $r;
			# (implicit) goto chunk_start if $r > 0;
		}
		$len = CHUNK_ZEND if $len == 0;

		# drain the current chunk
		until ($len <= 0) {
			if ($$rbuf ne '') {
				my $w = write_in_full($input, $rbuf, $len);
				return write_err($self, "$len chunk") if !$w;
				$len -= $w;
				if ($len == 0) {
					# we may have leftover data to parse
					# in chunk
					$$rbuf = substr($$rbuf, $w);
					$len = CHUNK_END;
				} elsif ($len < 0) {
					die "BUG: len < 0: $len";
				} else {
					$$rbuf = '';
				}
			}
			if ($$rbuf eq '') {
				# read more of current chunk
				my $r = sysread($sock, $$rbuf, 8192);
				return recv_err($self, $r, $len) unless $r;
			}
		}
	}
}

sub quit {
	my ($self, $status) = @_;
	my $h = "HTTP/1.1 $status " . status_message($status) . "\r\n\r\n";
	$self->write($h);
	$self->close;
}

# callbacks for Danga::Socket

sub event_hup { $_[0]->close }
sub event_err { $_[0]->close }

sub close {
	my $self = shift;
	my $forward = $self->{forward};
	my $env = $self->{env};
	%$env = () if $env; # prevent circular references
	$self->{pull} = $self->{forward} = $self->{env} = undef;
	if ($forward) {
		eval { $forward->close };
		err($self, "forward ->close error: $@") if $@;
	}
	$self->SUPER::close(@_);
}

# for graceful shutdown in PublicInbox::Daemon:
sub busy () {
	my ($self) = @_;
	($self->{rbuf} ne '' || $self->{env} || $self->{write_buf_size});
}

1;

git clone https://public-inbox.org/public-inbox.git
git clone http://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/public-inbox.git