about summary refs log tree commit homepage
path: root/lib/PublicInbox/GitAsyncCat.pm
blob: 8701e4cfe4889b654f509f18032a5ebd8413fc64 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
# Copyright (C) 2020 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
#
# internal class used by PublicInbox::Git + Danga::Socket
# This parses the output pipe of "git cat-file --batch"
#
# Note: this does NOT set the non-blocking flag, we expect `git cat-file'
# to be a local process, and git won't start writing a blob until it's
# fully read.  So minimize context switching and read as much as possible
# and avoid holding a buffer in our heap any longer than it has to live.
package PublicInbox::GitAsyncCat;
use strict;
use parent qw(PublicInbox::DS Exporter);
use fields qw(git);
use PublicInbox::Syscall qw(EPOLLIN EPOLLET);
our @EXPORT = qw(git_async_cat);

sub new {
	my ($class, $git) = @_;
	my $self = fields::new($class);
	$git->batch_prepare;
	$self->SUPER::new($git->{in}, EPOLLIN|EPOLLET);
	$self->{git} = $git;
	$self;
}

sub event_step {
	my ($self) = @_;
	my $git = $self->{git} or return; # ->close-ed
	my $inflight = $git->{inflight};
	if (@$inflight) {
		$git->cat_async_step($inflight);
		$self->requeue if @$inflight || exists $git->{cat_rbuf};
	}
}

sub close {
	my ($self) = @_;
	if (my $git = delete $self->{git}) {
		delete $git->{async_cat}; # drop circular reference
	}
	$self->SUPER::close; # PublicInbox::DS::close
}

sub git_async_cat ($$$$) {
	my ($git, $oid, $cb, $arg) = @_;
	$git->cat_async($oid, $cb, $arg);
	$git->{async_cat} //= new(__PACKAGE__, $git); # circular reference
}

1;