public-inbox.git  about / heads / tags
an "archives first" approach to mailing lists
blob 230df166bbc82c712b6ac2115761e99da9b338c3 2839 bytes (raw)
$ git show HEAD:lib/PublicInbox/DirIdle.pm	# shows this blob on the CLI

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
 
# Copyright (C) all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>

# Used by public-inbox-watch for Maildir (and possibly MH in the future)
package PublicInbox::DirIdle;
use v5.12;
use parent 'PublicInbox::DS';
use PublicInbox::Syscall qw(EPOLLIN);
use PublicInbox::In2Tie;

my ($MAIL_IN, $MAIL_GONE, $ino_cls);
if ($^O eq 'linux' && eval { require PublicInbox::Inotify; 1 }) {
	$MAIL_IN = PublicInbox::Inotify::IN_MOVED_TO() |
		PublicInbox::Inotify::IN_CREATE();
	$MAIL_GONE = PublicInbox::Inotify::IN_DELETE() |
			PublicInbox::Inotify::IN_DELETE_SELF() |
			PublicInbox::Inotify::IN_MOVE_SELF() |
			PublicInbox::Inotify::IN_MOVED_FROM();
	$ino_cls = 'PublicInbox::Inotify';
# Perl 5.22+ is needed for fileno(DIRHANDLE) support:
} elsif ($^V ge v5.22 && eval { require PublicInbox::KQNotify }) {
	$MAIL_IN = PublicInbox::KQNotify::MOVED_TO_OR_CREATE();
	$MAIL_GONE = PublicInbox::KQNotify::NOTE_DELETE() |
		PublicInbox::KQNotify::NOTE_REVOKE() |
		PublicInbox::KQNotify::NOTE_RENAME();
	$ino_cls = 'PublicInbox::KQNotify';
} else {
	require PublicInbox::FakeInotify;
	$MAIL_IN = PublicInbox::FakeInotify::MOVED_TO_OR_CREATE();
	$MAIL_GONE = PublicInbox::FakeInotify::IN_DELETE() |
			PublicInbox::FakeInotify::IN_DELETE_SELF() |
			PublicInbox::FakeInotify::IN_MOVE_SELF();
}

sub new {
	my ($class, $cb) = @_;
	my $self = bless { cb => $cb }, $class;
	my $inot;
	if ($ino_cls) {
		$inot = $ino_cls->new or die "E: $ino_cls->new: $!";
		my $io = PublicInbox::In2Tie::io($inot);
		$self->SUPER::new($io, EPOLLIN);
	} else {
		require PublicInbox::FakeInotify;
		$inot = PublicInbox::FakeInotify->new; # starts timer
	}
	$self->{inot} = $inot;
	$self;
}

sub add_watches {
	my ($self, $dirs, $gone) = @_;
	my $fl = $MAIL_IN | ($gone ? $MAIL_GONE : 0);
	my @ret;
	for my $d (@$dirs) {
		my $w = $self->{inot}->watch($d, $fl) or next;
		push @ret, $w;
	}
	PublicInbox::FakeInotify::poll_once($self) if !$ino_cls;
	@ret
}

sub rm_watches {
	my ($self, $dir) = @_;
	my $inot = $self->{inot};
	if (my $cb = $inot->can('rm_watches')) { # TODO for fake watchers
		$cb->($inot, $dir);
	}
}

sub close {
	my ($self) = @_;
	delete $self->{cb};
	$self->SUPER::close; # if using real kevent/inotify
}

sub event_step {
	my ($self) = @_;
	my $cb = $self->{cb} or return;
	local $PublicInbox::DS::in_loop = 0; # waitpid() synchronously (FIXME)
	eval {
		my @events = $self->{inot}->read; # Inotify3->read
		$cb->($_) for @events;
	};
	warn "$self->{inot}->read err: $@\n" if $@;
}

sub force_close {
	my ($self) = @_;
	my $inot = delete $self->{inot} // return;
	if ($inot->can('fh')) { # Inotify3 or Linux::Inotify2 2.3+
		$inot->fh->close or warn "CLOSE ERROR: $!";
	} elsif ($inot->isa('Linux::Inotify2')) {
		require PublicInbox::LI2Wrap;
		PublicInbox::LI2Wrap::wrapclose($inot);
	}
}

1;

git clone https://public-inbox.org/public-inbox.git
git clone http://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/public-inbox.git