about summary refs log tree commit homepage
path: root/lib/PublicInbox/Config.pm
blob: 935b04450b3c4f2cbdb32348355894e9fcb8be82 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
# Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
# License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
#
# Used throughout the project for reading configuration
package PublicInbox::Config;
use strict;
use warnings;
use base qw/Exporter/;
our @EXPORT_OK = qw/try_cat/;
require PublicInbox::Inbox;
use PublicInbox::Spawn qw(popen_rd);
use File::Path::Expand qw/expand_filename/;

# returns key-value pairs of config directives in a hash
# if keys may be multi-value, the value is an array ref containing all values
sub new {
	my ($class, $file) = @_;
	$file = default_file() unless defined($file);
	$file = ref $file ? $file : git_config_dump($file);
	my $self = bless $file, $class;

	# caches
	$self->{-by_addr} ||= {};
	$self->{-by_name} ||= {};
	$self;
}

sub lookup {
	my ($self, $recipient) = @_;
	my $addr = lc($recipient);
	my $inbox = $self->{-by_addr}->{$addr};
	return $inbox if $inbox;

	my $pfx;

	foreach my $k (keys %$self) {
		$k =~ /\A(publicinbox\.[\w-]+)\.address\z/ or next;
		my $v = $self->{$k};
		if (ref($v) eq "ARRAY") {
			foreach my $alias (@$v) {
				(lc($alias) eq $addr) or next;
				$pfx = $1;
				last;
			}
		} else {
			(lc($v) eq $addr) or next;
			$pfx = $1;
			last;
		}
	}
	defined $pfx or return;
	_fill($self, $pfx);
}

sub lookup_name {
	my ($self, $name) = @_;
	my $rv = $self->{-by_name}->{$name};
	return $rv if $rv;
	$self->{-by_name}->{$name} = _fill($self, "publicinbox.$name");
}

sub get {
	my ($self, $inbox, $key) = @_;

	$self->{"publicinbox.$inbox.$key"};
}

sub config_dir { $ENV{PI_DIR} || expand_filename('~/.public-inbox') }

sub default_file {
	my $f = $ENV{PI_CONFIG};
	return $f if defined $f;
	config_dir() . '/config';
}

sub git_config_dump {
	my ($file) = @_;
	my ($in, $out);
	my @cmd = (qw/git config/, "--file=$file", '-l');
	my $cmd = join(' ', @cmd);
	my $fh = popen_rd(\@cmd);
	my %rv;
	local $/ = "\n";
	foreach my $line (<$fh>) {
		chomp $line;
		my ($k, $v) = split(/=/, $line, 2);
		my $cur = $rv{$k};

		if (defined $cur) {
			if (ref($cur) eq "ARRAY") {
				push @$cur, $v;
			} else {
				$rv{$k} = [ $cur, $v ];
			}
		} else {
			$rv{$k} = $v;
		}
	}
	close $fh or die "failed to close ($cmd) pipe: $?";
	\%rv;
}

sub try_cat {
	my ($path) = @_;
	my $rv;
	if (open(my $fh, '<', $path)) {
		local $/;
		$rv = <$fh>;
	}
	$rv;
}

sub _fill {
	my ($self, $pfx) = @_;
	my $rv = {};

	foreach my $k (qw(mainrepo address filter url)) {
		my $v = $self->{"$pfx.$k"};
		$rv->{$k} = $v if defined $v;
	}
	my $inbox = $pfx;
	$inbox =~ s/\Apublicinbox\.//;
	$rv->{name} = $inbox;
	my $v = $rv->{address} ||= 'public-inbox@example.com';
	$rv->{-primary_address} = ref($v) eq 'ARRAY' ? $v->[0] : $v;
	$rv = PublicInbox::Inbox->new($rv);
	if (ref($v) eq 'ARRAY') {
		$self->{-by_addr}->{lc($_)} = $rv foreach @$v;
	} else {
		$self->{-by_addr}->{lc($v)} = $rv;
	}
	$rv;
}


1;