about summary refs log tree commit homepage
path: root/lib/PublicInbox/AltId.pm
blob: 4a6ff97cc5e4aca470504123bbc30ce68dac6744 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>

package PublicInbox::AltId;
use strict;
use warnings;
use URI::Escape qw(uri_unescape);

# spec: TYPE:PREFIX:param1=value1&param2=value2&...
# Example: serial:gmane:file=/path/to/altmsgmap.sqlite3
sub new {
	my ($class, $inbox, $spec, $writable) = @_;
	my ($type, $prefix, $query) = split(/:/, $spec, 3);
	$type eq 'serial' or die "non-serial not supported, yet\n";

	require PublicInbox::Msgmap;

	my %params = map {
		my ($k, $v) = split(/=/, uri_unescape($_), 2);
		$v = '' unless defined $v;
		($k, $v);
	} split(/[&;]/, $query);
	my $f = $params{file} or die "file: required for $type spec $spec\n";
	unless (index($f, '/') == 0) {
		if (($inbox->{version} || 1) == 1) {
			$f = "$inbox->{mainrepo}/public-inbox/$f";
		} else {
			$f = "$inbox->{mainrepo}/$f";
		}
	}
	bless {
		filename => $f,
		writable => $writable,
		xprefix => 'X'.uc($prefix),
	}, $class;
}

sub mm_alt {
	my ($self) = @_;
	$self->{mm_alt} ||= eval {
		my $f = $self->{filename};
		my $writable = $self->{writable};
		PublicInbox::Msgmap->new_file($f, $writable);
	};
}

sub mid2alt {
	my ($self, $mid) = @_;
	$self->mm_alt->num_for($mid);
}

1;