From 64aea34d06f71828b0bdd6ae177b9bcf22d752b4 Mon Sep 17 00:00:00 2001
From: Eric Wong <e@80x24.org>
Date: Tue, 24 May 2016 03:41:53 +0000
Subject: git-http-backend: use qspawn to limit running processes

Having an excessive amount of git-pack-objects processes is
dangerous to the health of the server.  Queue up process spawning
for long-running responses and serve them sequentially, instead.
---
 lib/PublicInbox/Qspawn.pm | 52 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 lib/PublicInbox/Qspawn.pm

(limited to 'lib/PublicInbox/Qspawn.pm')

diff --git a/lib/PublicInbox/Qspawn.pm b/lib/PublicInbox/Qspawn.pm
new file mode 100644
index 00000000..9e4c8e08
--- /dev/null
+++ b/lib/PublicInbox/Qspawn.pm
@@ -0,0 +1,52 @@
+# Copyright (C) 2016 all contributors <meta@public-inbox.org>
+# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
+package PublicInbox::Qspawn;
+use strict;
+use warnings;
+use PublicInbox::Spawn qw(popen_rd);
+our $LIMIT = 1;
+my $running = 0;
+my @run_queue;
+
+sub new ($$$;) {
+	my ($class, $cmd, $env, $opt) = @_;
+	bless { args => [ $cmd, $env, $opt ] }, $class;
+}
+
+sub _do_spawn {
+	my ($self, $cb) = @_;
+	my $err;
+	($self->{rpipe}, $self->{pid}) = popen_rd(@{$self->{args}});
+	if ($self->{pid}) {
+		$running++;
+	} else {
+		$self->{err} = $!;
+	}
+	$cb->($self->{rpipe});
+}
+
+sub finish ($) {
+	my ($self) = @_;
+	if (delete $self->{rpipe}) {
+		my $pid = delete $self->{pid};
+		$self->{err} = $pid == waitpid($pid, 0) ? $? :
+				"PID:$pid still running?";
+		$running--;
+	}
+	if (my $next = shift @run_queue) {
+		_do_spawn(@$next);
+	}
+	$self->{err};
+}
+
+sub start ($$) {
+	my ($self, $cb) = @_;
+
+	if ($running < $LIMIT) {
+		_do_spawn($self, $cb);
+	} else {
+		push @run_queue, [ $self, $cb ];
+	}
+}
+
+1;
-- 
cgit v1.2.3-24-ge0c7