From e925ee9eacaac438c87471bda8c28d5edff7523e Mon Sep 17 00:00:00 2001
From: Eric Wong <e@80x24.org>
Date: Sun, 21 Sep 2014 04:19:30 +0000
Subject: public-inbox-init: manages the config files

This hopefully allows easier setup.
---
 Makefile.PL       |  2 +-
 public-inbox-init | 63 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 t/init.t          | 22 +++++++++++++++++++
 3 files changed, 86 insertions(+), 1 deletion(-)
 create mode 100644 public-inbox-init
 create mode 100644 t/init.t

diff --git a/Makefile.PL b/Makefile.PL
index 3dfafe7b..1ee10896 100644
--- a/Makefile.PL
+++ b/Makefile.PL
@@ -9,7 +9,7 @@ WriteMakefile(
 	AUTHOR => 'Eric Wong <normalperson@yhbt.net>',
 	ABSTRACT => 'public-inbox server infrastructure',
 	EXE_FILES => [qw/public-inbox-mda public-inbox.cgi
-			public-inbox-learn/],
+			public-inbox-learn public-inbox-init/],
 	PREREQ_PM => {
 		# note: we use ssoma(1) and spamc(1), NOT the Perl modules
 		# We also depend on git through ssoma.
diff --git a/public-inbox-init b/public-inbox-init
new file mode 100644
index 00000000..5fc9d3ef
--- /dev/null
+++ b/public-inbox-init
@@ -0,0 +1,63 @@
+#!/usr/bin/perl -w
+# Copyright (C) 2014, all contributors (git clone git://80x24.org/public-inbox)
+# License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
+use strict;
+use warnings;
+my $usage = "public-inbox-init NAME GIT_DIR HTTP_URL ADDRESS [ADDRESS..]";
+use PublicInbox::Config;
+use File::Temp qw/tempfile/;
+use File::Basename qw/dirname/;
+use File::Path qw/mkpath/;
+use File::Path::Expand qw/expand_filename/;
+
+sub x { system(@_) and die join(' ', @_). " failed: $?\n" }
+sub usage { print STDERR "Usage: $usage\n"; exit 1 }
+
+my $name = shift @ARGV or usage();
+my $git_dir = shift @ARGV or usage();
+my $http_url = shift @ARGV or usage();
+my (@address) = @ARGV;
+@address or usage();
+
+my $pi_config = PublicInbox::Config->default_file;
+my $dir = dirname($pi_config);
+mkpath($dir); # will croak on fatal errors
+my ($fh, $filename) = tempfile('pi-init-XXXXXXXX', DIR => $dir);
+if (-e $pi_config) {
+	open(my $oh, '<', $pi_config) or die "unable to read $pi_config: $!\n";
+	local $/;
+	my $old = <$oh>;
+	print $fh $old or die "failed to write: $!\n";
+	close $oh or die "failed to close $pi_config: $!\n";
+
+	# yes, this conflict checking is racy if multiple instances of this
+	# script are run by the same $PI_DIR
+	my $cfg = PublicInbox::Config->new;
+	my $conflict;
+	foreach my $addr (@address) {
+		my $found = $cfg->lookup($addr);
+		if ($found && ($found->{listname} ne $name)) {
+			print STDERR
+				"`$addr' already defined for ",
+				"`$found->{listname}',\n",
+				"does not match intend `$name'\n";
+			$conflict = 1;
+		}
+	}
+
+	exit(1) if $conflict;
+}
+close $fh or die "failed to close $filename: $!\n";
+
+my $pfx = "publicinbox.$name";
+my @x = (qw/git config/, "--file=$filename");
+$git_dir = expand_filename($git_dir);
+x(qw(git init -q --bare), $git_dir);
+foreach my $addr (@address) {
+	x(@x, "$pfx.address", $addr);
+}
+x(@x, "$pfx.url", $http_url);
+x(@x, "$pfx.mainrepo", $git_dir);
+
+rename $filename, $pi_config or
+	die "failed to rename `$filename' to `$pi_config': $!\n";
diff --git a/t/init.t b/t/init.t
new file mode 100644
index 00000000..766e81b1
--- /dev/null
+++ b/t/init.t
@@ -0,0 +1,22 @@
+# Copyright (C) 2014, all contributors
+# License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
+use strict;
+use warnings;
+use Test::More;
+use PublicInbox::Config;
+use File::Temp qw/tempdir/;
+my $tmpdir = tempdir(CLEANUP => 1);
+use constant pi_init => 'blib/script/public-inbox-init';
+
+{
+	local $ENV{PI_DIR} = "$tmpdir/.public-inbox/";
+	my $cfgfile = "$ENV{PI_DIR}/config";
+	my @cmd = (pi_init, 'blist', "$tmpdir/blist",
+		   qw(http://example.com/blist blist@example.com));
+	is(system(@cmd), 0, join(' ', @cmd). ' failed');
+
+	ok(-e $cfgfile, "config exists, now");
+	is(system(@cmd), 0, join(' ', @cmd). ' failed (idempotent)');
+}
+
+done_testing();
-- 
cgit v1.2.3-24-ge0c7