tests: move giant inbox/git dependent tests to xt/

xt/ is typically reserved for "eXtended tests" intended for
the maintainers and not ordinary users.  Since these require
special configuration and do nothing by waste cycles
during startup, they qualify.

1 files changed, 52 insertions, 0 deletions

diff --git a/xt/perf-msgview.t b/xt/perf-msgview.t
new file mode 100644
index 00000000..22d8ce20
--- /dev/null
+++ b/xt/perf-msgview.t
@@ -0,0 +1,52 @@
+# Copyright (C) 2019 all contributors <meta@public-inbox.org>
+# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
+use strict;
+use warnings;
+use Test::More;
+use Benchmark qw(:all);
+use PublicInbox::Inbox;
+use PublicInbox::View;
+require './t/common.perl';
+
+my $inboxdir = $ENV{GIANT_INBOX_DIR} // $ENV{GIANT_PI_DIR};
+plan skip_all => "GIANT_INBOX_DIR not defined for $0" unless $inboxdir;
+
+my @cat = qw(cat-file --buffer --batch-check --batch-all-objects);
+if (require_git(2.19, 1)) {
+        push @cat, '--unordered';
+} else {
+        warn
+"git <2.19, cat-file lacks --unordered, locality suffers\n";
+}
+
+use_ok 'Plack::Util';
+my $ibx = PublicInbox::Inbox->new({ inboxdir => $inboxdir, name => 'name' });
+my $git = $ibx->git;
+my $fh = $git->popen(@cat);
+my $vec = '';
+vec($vec, fileno($fh), 1) = 1;
+select($vec, undef, undef, 60) or die "timed out waiting for --batch-check";
+
+my $ctx = {
+        env => { HTTP_HOST => 'example.com', 'psgi.url_scheme' => 'https' },
+        -inbox => $ibx,
+        www => Plack::Util::inline_object(style => sub {''}),
+};
+my ($str, $mime, $res, $cmt, $type);
+my $n = 0;
+my $t = timeit(1, sub {
+        while (<$fh>) {
+                ($cmt, $type) = split / /;
+                next if $type ne 'blob';
+                ++$n;
+                $str = $git->cat_file($cmt);
+                $mime = PublicInbox::MIME->new($str);
+                $res = PublicInbox::View::msg_html($ctx, $mime);
+                $res = $res->[2];
+                while (defined($res->getline)) {}
+                $res->close;
+        }
+});
+diag 'msg_html took '.timestr($t)." for $n messages";
+ok 1;
+done_testing();