lei forget-search: support --prune=<local|remote>

Instead of:

	lei forget-search $OUTPUT && rm -r $OUTPUT

we'll also allow a user to do:

	rm -r $OUTPUT && lei forget-search --prune

This gives users flexibility to choose whatever flow
is most natural to them.

3 files changed, 67 insertions, 15 deletions

diff --git a/lib/PublicInbox/LEI.pm b/lib/PublicInbox/LEI.pm
index 43baeeb3..cb1e5433 100644
--- a/lib/PublicInbox/LEI.pm
+++ b/lib/PublicInbox/LEI.pm
@@ -222,8 +222,8 @@ our %CMD = ( # sorted in order of importance/use:
 
 'ls-search' => [ '[PREFIX]', 'list saved search queries',
                 qw(format|f=s pretty l ascii z|0), @c_opt ],
-'forget-search' => [ 'OUTPUT...', 'forget a saved search',
-                qw(verbose|v+), @c_opt ],
+'forget-search' => [ 'OUTPUT...|--prune', 'forget a saved search',
+                qw(verbose|v+ prune:s), @c_opt ],
 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
                         @c_opt ],
 'rm' => [ '--stdin|LOCATION...',
diff --git a/lib/PublicInbox/LeiForgetSearch.pm b/lib/PublicInbox/LeiForgetSearch.pm
index 0db9c75b..f353fe52 100644
--- a/lib/PublicInbox/LeiForgetSearch.pm
+++ b/lib/PublicInbox/LeiForgetSearch.pm
@@ -5,12 +5,12 @@
 package PublicInbox::LeiForgetSearch;
 use strict;
 use v5.10.1;
+use parent qw(PublicInbox::LeiUp);
 use PublicInbox::LeiSavedSearch;
-use PublicInbox::LeiUp;
 use File::Path ();
 use SelectSaver;
 
-sub lei_forget_search {
+sub do_forget_search {
         my ($lei, @outs) = @_;
         my @dirs; # paths in ~/.local/share/lei/saved-search/
         my $cwd;
@@ -30,9 +30,55 @@ sub lei_forget_search {
                 $save = SelectSaver->new($lei->{2});
         }
         File::Path::remove_tree(@dirs, $opt);
-        $lei->fail if defined $cwd;
+        $lei->child_error(0) if defined $cwd;
+}
+
+sub lei_forget_search {
+        my ($lei, @outs) = @_;
+        my $prune = $lei->{opt}->{prune};
+        $prune // return do_forget_search($lei, @outs);
+        return $lei->fail("--prune and @outs incompatible") if @outs;
+        my @tmp = PublicInbox::LeiSavedSearch::list($lei);
+        my $self = bless { -mail_sync => 1 }, __PACKAGE__;
+        $self->filter_lss($lei, $prune) // return
+                        $lei->fail("only --prune=$prune not understood");
+        if ($self->{o_remote}) { # setup lei->{auth}
+                $self->prepare_inputs($lei, $self->{o_remote}) or return;
+        }
+        my $ops = {};
+        $lei->{auth}->op_merge($ops, $self) if $lei->{auth};
+        (my $op_c, $ops) = $lei->workers_start($self, 1, $ops);
+        $lei->{wq1} = $self;
+        net_merge_all_done($self) unless $lei->{auth};
+        $lei->wait_wq_events($op_c, $ops);
+}
+
+sub do_prune {
+        my ($self) = @_;
+        my $lei = $self->{lei};
+        for my $o (@{$self->{o_local} // []}) {
+                next if -e $o;
+                $lei->qerr("# pruning $o");
+                eval { do_forget_search($lei, $o) };
+                $lei->child_error(0, "E: $@") if $@;
+        }
+        for my $o (@{$self->{o_remote} // []}) {
+                my $uri = PublicInbox::URIimap->new($o);
+                next if $lei->{net}->mic_for_folder($uri);
+                $lei->qerr("# pruning $uri");
+                eval { do_forget_search($lei, $o) };
+                $lei->child_error(0, "E: $@") if $@;
+        }
+}
+
+# called in top-level lei-daemon when LeiAuth is done
+sub net_merge_all_done {
+        my ($self) = @_;
+        $self->wq_do('do_prune');
+        $self->wq_close;
 }
 
+*_wq_done_wait = \&PublicInbox::LEI::wq_done_wait;
 *_complete_forget_search = \&PublicInbox::LeiUp::_complete_up;
 
 1;
diff --git a/lib/PublicInbox/LeiUp.pm b/lib/PublicInbox/LeiUp.pm
index dac0fc28..79639d5e 100644
--- a/lib/PublicInbox/LeiUp.pm
+++ b/lib/PublicInbox/LeiUp.pm
@@ -93,6 +93,21 @@ sub redispatch_all ($$) {
         }
 }
 
+sub filter_lss {
+        my ($self, $lei, $all) = @_;
+        my @outs = PublicInbox::LeiSavedSearch::list($lei);
+        if ($all eq 'local') {
+                $self->{o_local} = [ grep(!/$REMOTE_RE/, @outs) ];
+        } elsif ($all eq 'remote') {
+                $self->{o_remote} = [ grep(/$REMOTE_RE/, @outs) ];
+        } elsif ($all eq '') {
+                $self->{o_remote} = [ grep(/$REMOTE_RE/, @outs) ];
+                $self->{o_local} = [ grep(!/$REMOTE_RE/, @outs) ];
+        } else {
+                undef;
+        }
+}
+
 sub lei_up {
         my ($lei, @outs) = @_;
         my $opt = $lei->{opt};
@@ -101,17 +116,8 @@ sub lei_up {
                 return $lei->fail("--all and @outs incompatible") if @outs;
                 defined($opt->{mua}) and return
                         $lei->fail('--all and --mua= are incompatible');
-                @outs = PublicInbox::LeiSavedSearch::list($lei);
-                if ($all eq 'local') {
-                        $self->{o_local} = [ grep(!/$REMOTE_RE/, @outs) ];
-                } elsif ($all eq 'remote') {
-                        $self->{o_remote} = [ grep(/$REMOTE_RE/, @outs) ];
-                } elsif ($all eq '') {
-                        $self->{o_remote} = [ grep(/$REMOTE_RE/, @outs) ];
-                        $self->{o_local} = [ grep(!/$REMOTE_RE/, @outs) ];
-                } else {
+                filter_lss($self, $lei, $all) // return
                         $lei->fail("only --all=$all not understood");
-                }
         } elsif ($lei->{lse}) { # redispatched
                 scalar(@outs) == 1 or die "BUG: lse set w/ >1 out[@outs]";
                 return up1($lei, $outs[0]);