Merge remote-tracking branch 'origin/nntp-tls'

* origin/nntp-tls: (59 commits)
  ds: ->write must not clobber empty wbuf array
  Makefile: skip DSKQXS in global syntax check
  ds: reduce overhead of tempfile creation
  Revert "ci: require IO::KQueue on FreeBSD, for now"
  ds: reimplement IO::Poll support to look like epoll
  ds: split out IO::KQueue-specific code
  daemon: use FreeBSD accept filters on non-NNTP
  daemon: set TCP_DEFER_ACCEPT on everything but NNTP
  nntp: send greeting immediately for plain sockets
  ci: require IO::KQueue on FreeBSD, for now
  nntp: lazily allocate and stash rbuf
  ds: flush_write runs ->write callbacks even if closed
  nntp: simplify long response logic and fix nesting
  ds: always use EV_ADD with EV_SET
  nntp: reduce allocations for greeting
  ds: allow ->write callbacks to syswrite directly
  daemon: use SSL_MODE_RELEASE_BUFFERS
  t/nntpd-tls: slow client connection test
  nntp: call SSL_shutdown in normal cases
  ds|nntp: use CORE::close on socket
  ...

1 files changed, 73 insertions, 0 deletions

diff --git a/lib/PublicInbox/DSKQXS.pm b/lib/PublicInbox/DSKQXS.pm
new file mode 100644
index 00000000..38e13446
--- /dev/null
+++ b/lib/PublicInbox/DSKQXS.pm
@@ -0,0 +1,73 @@
+# Copyright (C) 2019 all contributors <meta@public-inbox.org>
+# Licensed the same as Danga::Socket (and Perl5)
+# License: GPL-1.0+ or Artistic-1.0-Perl
+#  <https://www.gnu.org/licenses/gpl-1.0.txt>
+#  <https://dev.perl.org/licenses/artistic.html>
+#
+# kqueue support via IO::KQueue XS module.  This makes kqueue look
+# like epoll to simplify the code in DS.pm.  This is NOT meant to be
+# an all encompassing emulation of epoll via IO::KQueue, but just to
+# support cases public-inbox-nntpd/httpd care about.
+# A pure-Perl version using syscall() is planned, and it should be
+# faster due to the lack of syscall overhead.
+package PublicInbox::DSKQXS;
+use strict;
+use warnings;
+use parent qw(IO::KQueue);
+use parent qw(Exporter);
+use IO::KQueue;
+use PublicInbox::Syscall qw(EPOLLONESHOT EPOLLIN EPOLLOUT EPOLL_CTL_DEL);
+our @EXPORT = qw(epoll_ctl epoll_wait);
+my $owner_pid = -1; # kqueue is close-on-fork (yes, fork, not exec)
+
+# map EPOLL* bits to kqueue EV_* flags for EV_SET
+sub kq_flag ($$) {
+        my ($bit, $ev) = @_;
+        if ($ev & $bit) {
+                my $fl = EV_ADD | EV_ENABLE;
+                ($ev & EPOLLONESHOT) ? ($fl | EV_ONESHOT) : $fl;
+        } else {
+                EV_ADD | EV_DISABLE;
+        }
+}
+
+sub new {
+        my ($class) = @_;
+        die 'non-singleton use not supported' if $owner_pid == $$;
+        $owner_pid = $$;
+        $class->SUPER::new;
+}
+
+sub epoll_ctl {
+        my ($self, $op, $fd, $ev) = @_;
+        if ($op != EPOLL_CTL_DEL) {
+                $self->EV_SET($fd, EVFILT_READ, kq_flag(EPOLLIN, $ev));
+                $self->EV_SET($fd, EVFILT_WRITE, kq_flag(EPOLLOUT, $ev));
+        }
+        0;
+}
+
+sub epoll_wait {
+        my ($self, $maxevents, $timeout_msec, $events) = @_;
+        @$events = eval { $self->kevent($timeout_msec) };
+        if (my $err = $@) {
+                # workaround https://rt.cpan.org/Ticket/Display.html?id=116615
+                if ($err =~ /Interrupted system call/) {
+                        @$events = ();
+                } else {
+                        die $err;
+                }
+        }
+        # caller only cares for $events[$i]->[0]
+        scalar(@$events);
+}
+
+sub DESTROY {
+        my ($self) = @_;
+        if ($owner_pid == $$) {
+                POSIX::close($$self);
+                $owner_pid = -1;
+        }
+}
+
+1;