user/dev discussion of public-inbox itself
 help / color / mirror / code / Atom feed
fa3af71038dc1c7a222d68d38db4be7d1d6b9cd6 blob 19875 bytes (raw)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
 
# Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>

# Writes PublicInbox::Eml objects atomically to a mbox variant or Maildir
package PublicInbox::LeiToMail;
use strict;
use v5.10.1;
use parent qw(PublicInbox::IPC);
use PublicInbox::Eml;
use PublicInbox::ProcessPipe;
use PublicInbox::Spawn qw(spawn);
use PublicInbox::PktOp qw(pkt_do);
use Symbol qw(gensym);
use IO::Handle; # ->autoflush
use Fcntl qw(SEEK_SET SEEK_END O_CREAT O_EXCL O_WRONLY);

my %kw2char = ( # Maildir characters
	draft => 'D',
	flagged => 'F',
	forwarded => 'P', # passed
	answered => 'R',
	seen => 'S',
);

my %kw2status = (
	flagged => [ 'X-Status' => 'F' ],
	answered => [ 'X-Status' => 'A' ],
	seen => [ 'Status' => 'R' ],
	draft => [ 'X-Status' => 'T' ],
);

sub _mbox_hdr_buf ($$$) {
	my ($eml, $type, $smsg) = @_;
	$eml->header_set($_) for (qw(Lines Bytes Content-Length));

	my %hdr = (Status => []); # set Status, X-Status
	for my $k (@{$smsg->{kw} // []}) {
		if (my $ent = $kw2status{$k}) {
			push @{$hdr{$ent->[0]}}, $ent->[1];
		} else { # X-Label?
			warn "# keyword `$k' not supported for mbox\n";
		}
	}
	# Messages are always 'O' (non-\Recent in IMAP), it saves
	# MUAs the trouble of rewriting the mbox if no other
	# changes are made.  We put 'O' at the end (e.g. "Status: RO")
	# to match mutt(1) output.
	$eml->header_set('Status', join('', sort(@{$hdr{Status}})). 'O');
	if (my $chars = delete $hdr{'X-Status'}) {
		$eml->header_set('X-Status', join('', sort(@$chars)));
	}
	my $buf = delete $eml->{hdr};

	# fixup old bug from import (pre-a0c07cba0e5d8b6a)
	$$buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
	my $ident = $smsg->{blob} // 'lei';
	if (defined(my $pct = $smsg->{pct})) { $ident .= "=$pct" }

	substr($$buf, 0, 0, # prepend From line
		"From $ident\@$type Thu Jan  1 00:00:00 1970$eml->{crlf}");
	$buf;
}

sub atomic_append { # for on-disk destinations (O_APPEND, or O_EXCL)
	my ($lei, $buf) = @_;
	if (defined(my $w = syswrite($lei->{1} // return, $$buf))) {
		return if $w == length($$buf);
		$buf = "short atomic write: $w != ".length($$buf);
	} elsif ($!{EPIPE}) {
		return $lei->note_sigpipe(1);
	} else {
		$buf = "atomic write: $!";
	}
	$lei->fail($buf);
}

sub eml2mboxrd ($;$) {
	my ($eml, $smsg) = @_;
	my $buf = _mbox_hdr_buf($eml, 'mboxrd', $smsg);
	if (my $bdy = delete $eml->{bdy}) {
		$$bdy =~ s/^(>*From )/>$1/gm;
		$$buf .= $eml->{crlf};
		substr($$bdy, 0, 0, $$buf); # prepend header
		$buf = $bdy;
	}
	$$buf .= $eml->{crlf};
	$buf;
}

sub eml2mboxo {
	my ($eml, $smsg) = @_;
	my $buf = _mbox_hdr_buf($eml, 'mboxo', $smsg);
	if (my $bdy = delete $eml->{bdy}) {
		$$bdy =~ s/^From />From /gm;
		$$buf .= $eml->{crlf};
		substr($$bdy, 0, 0, $$buf); # prepend header
		$buf = $bdy;
	}
	$$buf .= $eml->{crlf};
	$buf;
}

sub _mboxcl_common ($$$) {
	my ($buf, $bdy, $crlf) = @_;
	# add Lines: so mutt won't have to add it on MUA close
	my $lines = $$bdy =~ tr!\n!\n!;
	$$buf .= 'Content-Length: '.length($$bdy).$crlf.
		'Lines: '.$lines.$crlf.$crlf;
	substr($$bdy, 0, 0, $$buf); # prepend header
	$_[0] = $bdy;
}

# mboxcl still escapes "From " lines
sub eml2mboxcl {
	my ($eml, $smsg) = @_;
	my $buf = _mbox_hdr_buf($eml, 'mboxcl', $smsg);
	my $crlf = $eml->{crlf};
	if (my $bdy = delete $eml->{bdy}) {
		$$bdy =~ s/^From />From /gm;
		_mboxcl_common($buf, $bdy, $crlf);
	}
	$$buf .= $crlf;
	$buf;
}

# mboxcl2 has no "From " escaping
sub eml2mboxcl2 {
	my ($eml, $smsg) = @_;
	my $buf = _mbox_hdr_buf($eml, 'mboxcl2', $smsg);
	my $crlf = $eml->{crlf};
	if (my $bdy = delete $eml->{bdy}) {
		_mboxcl_common($buf, $bdy, $crlf);
	}
	$$buf .= $crlf;
	$buf;
}

sub git_to_mail { # git->cat_async callback
	my ($bref, $oid, $type, $size, $arg) = @_;
	return warn("W: $oid is $type (!= blob)\n") if $type ne 'blob';
	return warn("E: $oid is empty\n") unless $size;
	my ($write_cb, $smsg) = @$arg;
	die "BUG: expected=$smsg->{blob} got=$oid" if $smsg->{blob} ne $oid;
	$write_cb->($bref, $smsg);
}

sub reap_compress { # dwaitpid callback
	my ($lei, $pid) = @_;
	my $cmd = delete $lei->{"pid.$pid"};
	return if $? == 0;
	$lei->fail("@$cmd failed", $? >> 8);
}

sub _post_augment_mbox { # open a compressor process from top-level process
	my ($self, $lei) = @_;
	my $zsfx = $self->{zsfx} or return;
	my $cmd = PublicInbox::MboxReader::zsfx2cmd($zsfx, undef, $lei);
	my ($r, $w) = @{delete $lei->{zpipe}};
	my $rdr = { 0 => $r, 1 => $lei->{1}, 2 => $lei->{2} };
	my $pid = spawn($cmd, undef, $rdr);
	my $pp = gensym;
	my $dup = bless { "pid.$pid" => $cmd }, ref($lei);
	$dup->{$_} = $lei->{$_} for qw(2 sock);
	tie *$pp, 'PublicInbox::ProcessPipe', $pid, $w, \&reap_compress, $dup;
	$lei->{1} = $pp;
}

# --augment existing output destination, with deduplication
sub _augment { # MboxReader eml_cb
	my ($eml, $lei) = @_;
	# ignore return value, just populate the skv
	$lei->{dedupe}->is_dup($eml);
}

sub _mbox_augment_kw_maybe {
	my ($eml, $lei, $lse, $augment) = @_;
	my $kw = PublicInbox::MboxReader::mbox_keywords($eml);
	update_kw_maybe($lei, $lse, $eml, $kw);
	_augment($eml, $lei) if $augment;
}

sub _mbox_write_cb ($$) {
	my ($self, $lei) = @_;
	my $ovv = $lei->{ovv};
	my $m = 'eml2'.$ovv->{fmt};
	my $eml2mbox = $self->can($m) or die "$self->$m missing";
	$lei->{1} // die "no stdout ($m, $ovv->{dst})"; # redirected earlier
	$lei->{1}->autoflush(1);
	my $atomic_append = !defined($ovv->{lock_path});
	my $dedupe = $lei->{dedupe};
	$dedupe->prepare_dedupe;
	my $lse = $lei->{lse}; # may be undef
	sub { # for git_to_mail
		my ($buf, $smsg, $eml) = @_;
		$eml //= PublicInbox::Eml->new($buf);
		return if $dedupe->is_dup($eml, $smsg);
		$lse->xsmsg_vmd($smsg) if $lse;
		$buf = $eml2mbox->($eml, $smsg);
		return atomic_append($lei, $buf) if $atomic_append;
		my $lk = $ovv->lock_for_scope;
		$lei->out($$buf);
	}
}

sub update_kw_maybe ($$$$) {
	my ($lei, $lse, $eml, $kw) = @_;
	return unless $lse;
	my $c = $lse->kw_changed($eml, $kw, my $docids = []);
	my $vmd = { kw => $kw };
	if (scalar @$docids) { # already in lei/store
		$lei->{sto}->ipc_do('set_eml_vmd', undef, $vmd, $docids) if $c;
	} elsif (my $xoids = $lei->{ale}->xoids_for($eml)) {
		# it's in an external, only set kw, here
		$lei->{sto}->ipc_do('set_xvmd', $xoids, $eml, $vmd);
	} else { # never-before-seen, import the whole thing
		# XXX this is critical in protecting against accidental
		# data loss without --augment
		$lei->{sto}->ipc_do('set_eml', $eml, $vmd);
	}
}

sub _md_update { # maildir_each_eml cb
	my ($f, $kw, $eml, $lei, $lse, $unlink) = @_;
	update_kw_maybe($lei, $lse, $eml, $kw);
	$unlink ? unlink($f) : _augment($eml, $lei);
}

# maildir_each_file callback, \&CORE::unlink doesn't work with it
sub _unlink { unlink($_[0]) }

sub _rand () {
	state $seq = 0;
	sprintf('%x,%x,%x,%x', rand(0xffffffff), time, $$, ++$seq);
}

sub _buf2maildir {
	my ($dst, $buf, $smsg) = @_;
	my $kw = $smsg->{kw} // [];
	my $sfx = join('', sort(map { $kw2char{$_} // () } @$kw));
	my $rand = ''; # chosen by die roll :P
	my ($tmp, $fh, $final, $ok);
	my $common = $smsg->{blob} // _rand;
	if (defined(my $pct = $smsg->{pct})) { $common .= "=$pct" }
	do {
		$tmp = $dst.'tmp/'.$rand.$common;
	} while (!($ok = sysopen($fh, $tmp, O_CREAT|O_EXCL|O_WRONLY)) &&
		$!{EEXIST} && ($rand = _rand.','));
	if ($ok && print $fh $$buf and close($fh)) {
		# ignore new/ and write only to cur/, otherwise MUAs
		# with R/W access to the Maildir will end up doing
		# a mass rename which can take a while with thousands
		# of messages.
		$dst .= 'cur/';
		$rand = '';
		do {
			$final = $dst.$rand.$common.':2,'.$sfx;
		} while (!($ok = link($tmp, $final)) && $!{EEXIST} &&
			($rand = _rand.','));
		die "link($tmp, $final): $!" unless $ok;
		unlink($tmp) or warn "W: failed to unlink $tmp: $!\n";
	} else {
		my $err = "Error writing $smsg->{blob} to $dst: $!\n";
		$_[0] = undef; # clobber dst
		unlink($tmp);
		die $err;
	}
}

sub _maildir_write_cb ($$) {
	my ($self, $lei) = @_;
	my $dedupe = $lei->{dedupe};
	$dedupe->prepare_dedupe if $dedupe;
	my $dst = $lei->{ovv}->{dst};
	my $lse = $lei->{lse}; # may be undef
	sub { # for git_to_mail
		my ($buf, $smsg, $eml) = @_;
		$dst // return $lei->fail; # dst may be undef-ed in last run
		$buf //= \($eml->as_string);
		$lse->xsmsg_vmd($smsg) if $lse;
		return _buf2maildir($dst, $buf, $smsg) if !$dedupe;
		$eml //= PublicInbox::Eml->new($$buf); # copy buf
		return if $dedupe->is_dup($eml, $smsg);
		undef $eml;
		_buf2maildir($dst, $buf, $smsg);
	}
}

sub _imap_write_cb ($$) {
	my ($self, $lei) = @_;
	my $dedupe = $lei->{dedupe};
	$dedupe->prepare_dedupe if $dedupe;
	my $imap_append = $lei->{net}->can('imap_append');
	my $mic = $lei->{net}->mic_get($self->{uri});
	my $folder = $self->{uri}->mailbox;
	my $lse = $lei->{lse}; # may be undef
	sub { # for git_to_mail
		my ($bref, $smsg, $eml) = @_;
		$mic // return $lei->fail; # mic may be undef-ed in last run
		if ($dedupe) {
			$eml //= PublicInbox::Eml->new($$bref); # copy bref
			return if $dedupe->is_dup($eml, $smsg);
		}
		$lse->xsmsg_vmd($smsg) if $lse;
		eval { $imap_append->($mic, $folder, $bref, $smsg, $eml) };
		if (my $err = $@) {
			undef $mic;
			die $err;
		}
	}
}

sub _text_write_cb ($$) {
	my ($self, $lei) = @_;
	my $dedupe = $lei->{dedupe};
	$dedupe->prepare_dedupe if $dedupe;
	my $lvt = $lei->{lvt};
	my $ovv = $lei->{ovv};
	$lei->{1} // die "no stdout ($ovv->{dst})"; # redirected earlier
	$lei->{1}->autoflush(1);
	binmode $lei->{1}, ':utf8';
	my $lse = $lei->{lse}; # may be undef
	sub { # for git_to_mail
		my ($bref, $smsg, $eml) = @_;
		$lse->xsmsg_vmd($smsg) if $lse;
		$eml //= PublicInbox::Eml->new($bref); # copy bref
		return if $dedupe && $dedupe->is_dup($eml, $smsg);
		my $lk = $ovv->lock_for_scope;
		$lei->out(${$lvt->eml_to_text($smsg, $eml)}, "\n");
	}
}

sub write_cb { # returns a callback for git_to_mail
	my ($self, $lei) = @_;
	# _mbox_write_cb, _maildir_write_cb or _imap_write_cb
	my $m = "_$self->{base_type}_write_cb";
	$self->$m($lei);
}

sub new {
	my ($cls, $lei) = @_;
	my $fmt = $lei->{ovv}->{fmt};
	my $dst = $lei->{ovv}->{dst};
	my $self = bless {}, $cls;
	if ($fmt eq 'maildir') {
		require PublicInbox::MdirReader;
		$self->{base_type} = 'maildir';
		-e $dst && !-d _ and die
				"$dst exists and is not a directory\n";
		$lei->{ovv}->{dst} = $dst .= '/' if substr($dst, -1) ne '/';
	} elsif (substr($fmt, 0, 4) eq 'mbox') {
		require PublicInbox::MboxReader;
		$self->can("eml2$fmt") or die "bad mbox format: $fmt\n";
		$self->{base_type} = 'mbox';
	} elsif ($fmt =~ /\Aimaps?\z/) { # TODO .onion support
		require PublicInbox::NetWriter;
		require PublicInbox::URIimap;
		my $net = PublicInbox::NetWriter->new;
		$net->{quiet} = $lei->{opt}->{quiet};
		my $uri = PublicInbox::URIimap->new($dst)->canonical;
		$net->add_url($uri);
		my $err = $net->errors;
		return $lei->fail($err) if $err;
		$uri->mailbox or return $lei->fail("No mailbox: $dst");
		$self->{uri} = $uri;
		$dst = $lei->{ovv}->{dst} = $$uri; # canonicalized
		$lei->{net} = $net;
		$self->{base_type} = 'imap';
	} elsif ($fmt eq 'text') {
		require PublicInbox::LeiViewText;
		$lei->{lvt} = PublicInbox::LeiViewText->new($lei);
		$self->{base_type} = 'text';
	} else {
		die "bad mail --format=$fmt\n";
	}
	if ($self->{base_type} =~ /\A(?:text|mbox)\z/) {
		(-d $dst || (-e _ && !-w _)) and die
			"$dst exists and is not a writable file\n";
	}
	if ($self->{base_type} eq 'text') {
		my @err = map {
			defined($lei->{opt}->{$_}) ? "--$_" : ();
		} (qw(mua save));
		die "@err incompatible with $fmt\n" if @err;
	}
	$self->{dst} = $dst;
	$lei->{dedupe} = $lei->{lss} // do {
		my $dd_cls = 'PublicInbox::'.
			($lei->{opt}->{save} ? 'LeiSavedSearch' : 'LeiDedupe');
		eval "require $dd_cls";
		die "$dd_cls: $@" if $@;
		$dd_cls->new($lei);
	};
	$self;
}

sub _pre_augment_maildir {
	my ($self, $lei) = @_;
	my $dst = $lei->{ovv}->{dst};
	for my $x (qw(tmp new cur)) {
		my $d = $dst.$x;
		next if -d $d;
		require File::Path;
		File::Path::mkpath($d);
		-d $d or die "$d is not a directory";
	}
	# for utime, so no opendir
	open $self->{poke_dh}, '<', "${dst}cur" or die "open ${dst}cur: $!";
}

sub _do_augment_maildir {
	my ($self, $lei) = @_;
	return if ($lei->{opt}->{save} // 0) < 0;
	my $dst = $lei->{ovv}->{dst};
	my $lse = $lei->{opt}->{'import-before'} ? $lei->{lse} : undef;
	my $mdr = PublicInbox::MdirReader->new;
	if ($lei->{opt}->{augment}) {
		my $dedupe = $lei->{dedupe};
		if ($dedupe && $dedupe->prepare_dedupe) {
			$mdr->{shard_info} = $self->{shard_info};
			$mdr->maildir_each_eml($dst, \&_md_update, $lei, $lse);
			$dedupe->pause_dedupe;
		}
	} elsif ($lse) {
		$mdr->{shard_info} = $self->{shard_info};
		$mdr->maildir_each_eml($dst, \&_md_update, $lei, $lse, 1);
	} else {# clobber existing Maildir
		$mdr->maildir_each_file($dst, \&_unlink);
	}
}

sub _imap_augment_or_delete { # PublicInbox::NetReader::imap_each cb
	my ($url, $uid, $kw, $eml, $lei, $lse, $delete_mic) = @_;
	update_kw_maybe($lei, $lse, $eml, $kw);
	if ($delete_mic) {
		$lei->{net}->imap_delete_1($url, $uid, $delete_mic);
	} else {
		_augment($eml, $lei);
	}
}

sub _do_augment_imap {
	my ($self, $lei) = @_;
	return if ($lei->{opt}->{save} // 0) < 0;
	my $net = $lei->{net};
	my $lse = $lei->{opt}->{'import-before'} ? $lei->{lse} : undef;
	if ($lei->{opt}->{augment}) {
		my $dedupe = $lei->{dedupe};
		if ($dedupe && $dedupe->prepare_dedupe) {
			$net->imap_each($self->{uri}, \&_imap_augment_or_delete,
					$lei, $lse);
			$dedupe->pause_dedupe;
		}
	} elsif ($lse) {
		my $delete_mic;
		$net->imap_each($self->{uri}, \&_imap_augment_or_delete,
					$lei, $lse, \$delete_mic);
		$delete_mic->expunge if $delete_mic;
	} elsif (!$self->{-wq_worker_nr}) { # undef or 0
		# clobber existing IMAP folder
		$net->imap_delete_all($self->{uri});
	}
}

sub _pre_augment_text {
	my ($self, $lei) = @_;
	my $dst = $lei->{ovv}->{dst};
	my $out;
	my $devfd = $lei->path_to_fd($dst) // die "bad $dst";
	if ($devfd >= 0) {
		$out = $lei->{$devfd};
	} else { # normal-looking path
		if (-p $dst) {
			open $out, '>', $dst or die "open($dst): $!";
		} elsif (-f _ || !-e _) {
			# text allows augment, HTML/Atom won't
			my $mode = $lei->{opt}->{augment} ? '>>' : '>';
			open $out, $mode, $dst or die "open($mode, $dst): $!";
		} else {
			die "$dst is not a file or FIFO\n";
		}
	}
	$lei->{ovv}->ovv_out_lk_init if !$lei->{ovv}->{lock_path};
	$lei->{1} = $out;
	undef;
}

sub _pre_augment_mbox {
	my ($self, $lei) = @_;
	my $dst = $lei->{ovv}->{dst};
	my $out;
	my $devfd = $lei->path_to_fd($dst) // die "bad $dst";
	if ($devfd >= 0) {
		$out = $lei->{$devfd};
	} else { # normal-looking path
		if (-p $dst) {
			open $out, '>', $dst or die "open($dst): $!";
		} elsif (-f _ || !-e _) {
			require PublicInbox::MboxLock;
			my $m = $lei->{opt}->{'lock'} //
					PublicInbox::MboxLock->defaults;
			$self->{mbl} = PublicInbox::MboxLock->acq($dst, 1, $m);
			$out = $self->{mbl}->{fh};
		} else {
			die "$dst is not a file or FIFO\n";
		}
		$lei->{old_1} = $lei->{1}; # keep for spawning MUA
	}
	# Perl does SEEK_END even with O_APPEND :<
	$self->{seekable} = seek($out, 0, SEEK_SET);
	if (!$self->{seekable} && !$!{ESPIPE} && !defined($devfd)) {
		die "seek($dst): $!\n";
	}
	if (!$self->{seekable}) {
		my $imp_before = $lei->{opt}->{'import-before'};
		die "--import-before specified but $dst is not seekable\n"
			if $imp_before && !ref($imp_before);
		die "--augment specified but $dst is not seekable\n" if
			$lei->{opt}->{augment};
	}
	if ($self->{zsfx} = PublicInbox::MboxReader::zsfx($dst)) {
		pipe(my ($r, $w)) or die "pipe: $!";
		$lei->{zpipe} = [ $r, $w ];
		$lei->{ovv}->{lock_path} and
			die 'BUG: unexpected {ovv}->{lock_path}';
		$lei->{ovv}->ovv_out_lk_init;
	} elsif (!$self->{seekable} && !$lei->{ovv}->{lock_path}) {
		$lei->{ovv}->ovv_out_lk_init;
	}
	$lei->{1} = $out;
	undef;
}

sub _do_augment_mbox {
	my ($self, $lei) = @_;
	return unless $self->{seekable};
	my $opt = $lei->{opt};
	return if ($opt->{save} // 0) < 0;
	my $out = $lei->{1};
	my ($fmt, $dst) = @{$lei->{ovv}}{qw(fmt dst)};
	return unless -s $out;
	unless ($opt->{augment} || $opt->{'import-before'}) {
		truncate($out, 0) or die "truncate($dst): $!";
		return;
	}
	my $rd;
	if (my $zsfx = $self->{zsfx}) {
		$rd = PublicInbox::MboxReader::zsfxcat($out, $zsfx, $lei);
	} else {
		open($rd, '+>>&', $out) or die "dup: $!";
	}
	my $dedupe;
	if ($opt->{augment}) {
		$dedupe = $lei->{dedupe};
		$dedupe->prepare_dedupe if $dedupe;
	}
	if ($opt->{'import-before'}) { # the default
		my $lse = $lei->{lse};
		PublicInbox::MboxReader->$fmt($rd, \&_mbox_augment_kw_maybe,
						$lei, $lse, $opt->{augment});
		if (!$opt->{augment} and !truncate($out, 0)) {
			die "truncate($dst): $!";
		}
	} else { # --augment --no-import-before
		PublicInbox::MboxReader->$fmt($rd, \&_augment, $lei);
	}
	# maybe some systems don't honor O_APPEND, Perl does this:
	seek($out, 0, SEEK_END) or die "seek $dst: $!";
	$dedupe->pause_dedupe if $dedupe;
}

sub pre_augment { # fast (1 disk seek), runs in same process as post_augment
	my ($self, $lei) = @_;
	# _pre_augment_maildir, _pre_augment_mbox
	my $m = $self->can("_pre_augment_$self->{base_type}") or return;
	$m->($self, $lei);
}

sub do_augment { # slow, runs in wq worker
	my ($self, $lei) = @_;
	# _do_augment_maildir, _do_augment_mbox, or _do_augment_imap
	my $m = $self->can("_do_augment_$self->{base_type}") or return;
	$m->($self, $lei);
}

# fast (spawn compressor or mkdir), runs in same process as pre_augment
sub post_augment {
	my ($self, $lei, @args) = @_;
	my $wait = $lei->{opt}->{'import-before'} ?
			$lei->{sto}->ipc_do('checkpoint', 1) : 0;
	# _post_augment_mbox
	my $m = $self->can("_post_augment_$self->{base_type}") or return;
	$m->($self, $lei, @args);
}

# called by every single l2m worker process
sub do_post_auth {
	my ($self) = @_;
	my $lei = $self->{lei};
	# lei_xsearch can start as soon as all l2m workers get here
	pkt_do($lei->{pkt_op_p}, 'incr_start_query') or
		die "incr_start_query: $!";
	my $aug;
	if (lock_free($self)) { # all workers do_augment
		my $mod = $self->{-wq_nr_workers};
		my $shard = $self->{-wq_worker_nr};
		if (my $net = $lei->{net}) {
			$net->{shard_info} = [ $mod, $shard ];
		} else { # Maildir
			$self->{shard_info} = [ $mod, $shard ];
		}
		$aug = '+'; # incr_post_augment
	} elsif ($self->{-wq_worker_nr} == 0) { # 1st worker do_augment
		$aug = '.'; # do_post_augment
	}
	if ($aug) {
		local $0 = 'do_augment';
		eval { do_augment($self, $lei) };
		$lei->fail($@) if $@;
		pkt_do($lei->{pkt_op_p}, $aug) == 1 or
				die "do_post_augment trigger: $!";
	}
	# done augmenting, connect the compressor pipe for each worker
	if (my $zpipe = delete $lei->{zpipe}) {
		$lei->{1} = $zpipe->[1];
		close $zpipe->[0];
	}
	$self->{wcb} = $self->write_cb($lei);
}

sub ipc_atfork_child {
	my ($self) = @_;
	my $lei = $self->{lei};
	$lei->_lei_atfork_child;
	$lei->{auth}->do_auth_atfork($self) if $lei->{auth};
	$SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
	$self->SUPER::ipc_atfork_child;
}

sub lock_free {
	$_[0]->{base_type} =~ /\A(?:maildir|imap|jmap)\z/ ? 1 : 0;
}

# wakes up the MUA when complete so it can refresh messages list
sub poke_dst {
	my ($self) = @_;
	if ($self->{base_type} eq 'maildir') {
		my $t = time + 1;
		utime($t, $t, $self->{poke_dh}) or warn "futimes: $!";
	}
}

sub write_mail { # via ->wq_io_do
	my ($self, $smsg, $eml) = @_;
	return $self->{wcb}->(undef, $smsg, $eml) if $eml;
	$self->{lei}->{ale}->git->cat_async($smsg->{blob}, \&git_to_mail,
				[$self->{wcb}, $smsg]);
}

sub wq_atexit_child {
	my ($self) = @_;
	delete $self->{wcb};
	$self->{lei}->{ale}->git->async_wait_all;
}

# called in top-level lei-daemon when LeiAuth is done
sub net_merge_complete {
	my ($self) = @_;
	$self->wq_broadcast('do_post_auth');
	$self->wq_close(1);
}

no warnings 'once'; # the following works even when LeiAuth is lazy-loaded
*net_merge_all = \&PublicInbox::LeiAuth::net_merge_all;
1;
debug log:

solving fa3af710 ...
found fa3af710 in public-inbox.git

user/dev discussion of public-inbox itself

This inbox may be cloned and mirrored by anyone:

	git clone --mirror https://public-inbox.org/meta
	git clone --mirror http://czquwvybam4bgbro.onion/meta
	git clone --mirror http://hjrcffqmbrq6wope.onion/meta
	git clone --mirror http://ou63pmih66umazou.onion/meta

	# If you have public-inbox 1.1+ installed, you may
	# initialize and index your mirror using the following commands:
	public-inbox-init -V1 meta meta/ https://public-inbox.org/meta \
		meta@public-inbox.org
	public-inbox-index meta

Example config snippet for mirrors.
Newsgroups are available over NNTP:
	nntp://news.public-inbox.org/inbox.comp.mail.public-inbox.meta
	nntp://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/inbox.comp.mail.public-inbox.meta
	nntp://ie5yzdi7fg72h7s4sdcztq5evakq23rdt33mfyfcddc5u3ndnw24ogqd.onion/inbox.comp.mail.public-inbox.meta
	nntp://4uok3hntl7oi7b4uf4rtfwefqeexfzil2w6kgk2jn5z2f764irre7byd.onion/inbox.comp.mail.public-inbox.meta
	nntp://news.gmane.io/gmane.mail.public-inbox.general
 note: .onion URLs require Tor: https://www.torproject.org/

code repositories for project(s) associated with this inbox:

	https://80x24.org/public-inbox.git

AGPL code for this site: git clone https://public-inbox.org/public-inbox.git