user/dev discussion of public-inbox itself
 help / color / Atom feed
e052bbffa938ec04f0946c09b109b7df903855e3 blob 5842 bytes (raw)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
 
# Copyright (C) 2019 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>

# Provide an HTTP-accessible listing of inboxes.
# Used by PublicInbox::WWW
package PublicInbox::WwwListing;
use strict;
use warnings;
use PublicInbox::Hval qw(ascii_html);
use PublicInbox::Linkify;
use PublicInbox::View;
use bytes ();
use HTTP::Date qw(time2str);
require Digest::SHA;
require File::Spec;
{ no warnings 'once'; *try_cat = *PublicInbox::Inbox::try_cat };

sub list_all ($$$) {
	my ($self, $env, $hide_key) = @_;
	my @list;
	$self->{pi_config}->each_inbox(sub {
		my ($ibx) = @_;
		push @list, $ibx unless $ibx->{-hide}->{$hide_key};
	});
	\@list;
}

sub list_match_domain ($$$) {
	my ($self, $env, $hide_key) = @_;
	my @list;
	my $host = $env->{HTTP_HOST} // $env->{SERVER_NAME};
	$host =~ s/:[0-9]+\z//;
	my $re = qr!\A(?:https?:)?//\Q$host\E(?::[0-9]+)?/!i;
	$self->{pi_config}->each_inbox(sub {
		my ($ibx) = @_;
		if (!$ibx->{-hide}->{$hide_key} && $ibx->{url} =~ $re) {
			push @list, $ibx;
		}
	});
	\@list;
}

sub list_404 ($$) { [] }

# TODO: +cgit
my %VALID = (
	all => *list_all,
	'match=domain' => *list_match_domain,
	404 => *list_404,
);

sub set_cb ($$$) {
	my ($pi_config, $k, $default) = @_;
	my $v = $pi_config->{lc $k} // $default;
	$VALID{$v} || do {
		warn <<"";
`$v' is not a valid value for `$k'
$k be one of `all', `match=domain', or `404'

		$VALID{$default};
	};
}

sub new {
	my ($class, $www) = @_;
	my $pi_config = $www->{pi_config};
	bless {
		pi_config => $pi_config,
		style => $www->style("\0"),
		www_cb => set_cb($pi_config, 'publicInbox.wwwListing', 404),
		manifest_cb => set_cb($pi_config, 'publicInbox.grokManifest',
					'match=domain'),
	}, $class;
}

sub ibx_entry {
	my ($mtime, $ibx, $env) = @_;
	my $ts = PublicInbox::View::fmt_ts($mtime);
	my $url = PublicInbox::Hval::prurl($env, $ibx->{url});
	my $tmp = <<"";
* $ts - $url
  ${\$ibx->description}

	if (defined(my $info_url = $ibx->{info_url})) {
		$tmp .= "\n$info_url";
	}
	$tmp;
}

sub html ($$) {
	my ($env, $list) = @_;
	my $title = 'public-inbox';
	my $out = '';
	my $code = 404;
	if (@$list) {
		$title .= ' - listing';
		$code = 200;

		# Swartzian transform since ->modified is expensive
		@$list = sort {
			$b->[0] <=> $a->[0]
		} map { [ $_->modified, $_ ] } @$list;

		my $tmp = join("\n", map { ibx_entry(@$_, $env) } @$list);
		my $l = PublicInbox::Linkify->new;
		$l->linkify_1($tmp);
		$out = '<pre>'.$l->linkify_2(ascii_html($tmp)).'</pre><hr>';
	}
	$out = "<html><head><title>$title</title></head><body>" . $out;
	$out .= '<pre>'. PublicInbox::WwwStream::code_footer($env) .
		'</pre></body></html>';

	my $h = [ 'Content-Type', 'text/html; charset=UTF-8' ];
	[ $code, $h, [ $out ] ];
}

my $json;
sub _json () {
	for my $mod (qw(JSON::MaybeXS JSON JSON::PP)) {
		eval "require $mod" or next;
		# ->ascii encodes non-ASCII to "\uXXXX"
		return $mod->new->ascii(1);
	}
	die;
}

sub fingerprint ($) {
	my ($git) = @_;
	my $fh = $git->popen('show-ref') or
		die "popen($git->{git_dir} show-ref) failed: $!";

	my $dig = Digest::SHA->new(1);
	while (read($fh, my $buf, 65536)) {
		$dig->add($buf);
	}
	close $fh;
	return if $?; # empty, uninitialized git repo
	$dig->hexdigest;
}

sub manifest_add ($$;$) {
	my ($manifest, $ibx, $epoch) = @_;
	my $url_path = "/$ibx->{name}";
	my $git_dir = $ibx->{mainrepo};
	if (defined $epoch) {
		$git_dir .= "/git/$epoch.git";
		$url_path .= "/git/$epoch.git";
	}
	return unless -d $git_dir;
	my $git = PublicInbox::Git->new($git_dir);
	my $fingerprint = fingerprint($git) or return; # no empty repos

	chomp(my $owner = $git->qx('config', 'gitweb.owner'));
	chomp(my $desc = try_cat("$git_dir/description"));
	$owner = undef if $owner eq '';
	$desc = 'Unnamed repository' if $desc eq '';

	my $reference;
	chomp(my $alt = try_cat("$git_dir/objects/info/alternates"));
	if ($alt) {
		# n.b.: GitPython doesn't seem to handle comments or C-quoted
		# strings like native git does; and we don't for now, either.
		my @alt = split(/\n+/, $alt);

		# grokmirror only supports 1 alternate for "reference",
		if (scalar(@alt) == 1) {
			my $objdir = "$git_dir/objects";
			$reference = File::Spec->rel2abs($alt[0], $objdir);
			$reference =~ s!/[^/]+/?\z!!; # basename
		}
	}
	$manifest->{-abs2urlpath}->{$git_dir} = $url_path;
	my $modified = $git->modified;
	if ($modified > $manifest->{-mtime}) {
		$manifest->{-mtime} = $modified;
	}
	$manifest->{$url_path} = {
		owner => $owner,
		reference => $reference,
		description => $desc,
		modified => $modified,
		fingerprint => $fingerprint,
	};
}

# manifest.js.gz
sub js ($$) {
	my ($env, $list) = @_;
	eval { require IO::Compress::Gzip } or return [ 404, [], [] ];

	my $manifest = { -abs2urlpath => {}, -mtime => 0 };
	for my $ibx (@$list) {
		if (defined(my $max = $ibx->max_git_epoch)) {
			for my $epoch (0..$max) {
				manifest_add($manifest, $ibx, $epoch);
			}
		} else {
			manifest_add($manifest, $ibx);
		}
	}
	my $abs2urlpath = delete $manifest->{-abs2urlpath};
	my $mtime = delete $manifest->{-mtime};
	while (my ($url_path, $repo) = each %$manifest) {
		defined(my $abs = $repo->{reference}) or next;
		$repo->{reference} = $abs2urlpath->{$abs};
	}
	my $out;
	IO::Compress::Gzip::gzip(\(($json ||= _json())->encode($manifest)) =>
				 \$out);
	$manifest = undef;
	[ 200, [ qw(Content-Type application/gzip),
		 'Last-Modified', time2str($mtime),
		 'Content-Length', bytes::length($out) ], [ $out ] ];
}

# not really a stand-alone PSGI app, but maybe it could be...
sub call {
	my ($self, $env) = @_;

	if ($env->{PATH_INFO} eq '/manifest.js.gz') {
		# grokmirror uses relative paths, so it's domain-dependent
		my $list = $self->{manifest_cb}->($self, $env, 'manifest');
		js($env, $list);
	} else { # /
		my $list = $self->{www_cb}->($self, $env, 'www');
		html($env, $list);
	}
}

1;
debug log:

solving e052bbff ...
found e052bbff in https://80x24.org/public-inbox.git

user/dev discussion of public-inbox itself

Archives are clonable:
	git clone --mirror https://public-inbox.org/meta
	git clone --mirror http://czquwvybam4bgbro.onion/meta
	git clone --mirror http://hjrcffqmbrq6wope.onion/meta
	git clone --mirror http://ou63pmih66umazou.onion/meta

Newsgroups are available over NNTP:
	nntp://news.public-inbox.org/inbox.comp.mail.public-inbox.meta
	nntp://ou63pmih66umazou.onion/inbox.comp.mail.public-inbox.meta
	nntp://czquwvybam4bgbro.onion/inbox.comp.mail.public-inbox.meta
	nntp://hjrcffqmbrq6wope.onion/inbox.comp.mail.public-inbox.meta
	nntp://news.gmane.org/gmane.mail.public-inbox.general

 note: .onion URLs require Tor: https://www.torproject.org/

AGPL code for this site: git clone https://public-inbox.org/ public-inbox