user/dev discussion of public-inbox itself
 help / color / mirror / code / Atom feed
debd2d39ae58baf08deea2198547f64f99dc743b blob 2221 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
 
# Copyright (C) 2020 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>

# for systems lacking Linux::Inotify2 or IO::KQueue, just emulates
# enough of Linux::Inotify2
package PublicInbox::FakeInotify;
use strict;
use Time::HiRes qw(stat);
use PublicInbox::DS;
my $IN_CLOSE = 0x08 | 0x10; # match Linux inotify
# my $IN_MOVED_TO = 0x80;
# my $IN_CREATE = 0x100;
sub MOVED_TO_OR_CREATE () { 0x80 | 0x100 }

my $poll_intvl = 2; # same as Filesys::Notify::Simple

sub poll_once {
	my ($self) = @_;
	eval { $self->poll };
	warn "E: FakeInotify->poll: $@\n" if $@;
	PublicInbox::DS::add_timer($poll_intvl, \&poll_once, $self);
}

sub new {
	my $self = bless { watch => {} }, __PACKAGE__;
	PublicInbox::DS::add_timer($poll_intvl, \&poll_once, $self);
	$self;
}

# behaves like Linux::Inotify2->watch
sub watch {
	my ($self, $path, $mask, $cb) = @_;
	my @st = stat($path) or return;
	my $k = "$path\0$mask";
	$self->{watch}->{$k} = [ $st[10], $cb ]; # 10 - ctime
	bless [ $self->{watch}, $k ], 'PublicInbox::FakeInotify::Watch';
}

sub on_new_files ($$$$) {
	my ($dh, $cb, $path, $old_ctime) = @_;
	while (defined(my $base = readdir($dh))) {
		next if $base =~ /\A\.\.?\z/;
		my $full = "$path/$base";
		my @st = stat($full);
		if (@st && $st[10] > $old_ctime) {
			bless \$full, 'PublicInbox::FakeInotify::Event';
			eval { $cb->(\$full) };
		}
	}
}

# behaves like non-blocking Linux::Inotify2->poll
sub poll {
	my ($self) = @_;
	my $watch = $self->{watch} or return;
	for my $x (keys %$watch) {
		my ($path, $mask) = split(/\0/, $x, 2);
		my @now = stat($path) or next;
		my $prv = $watch->{$x};
		my $cb = $prv->[-1];
		my $old_ctime = $prv->[0];
		if ($old_ctime != $now[10]) {
			if (($mask & $IN_CLOSE) == $IN_CLOSE) {
				eval { $cb->() };
			} elsif ($mask & MOVED_TO_OR_CREATE) {
				opendir(my $dh, $path) or do {
					warn "W: opendir $path: $!\n";
					next;
				};
				on_new_files($dh, $cb, $path, $old_ctime);
			}
		}
		@$prv = ($now[10], $cb);
	}
}

package PublicInbox::FakeInotify::Watch;
use strict;

sub cancel {
	my ($self) = @_;
	delete $self->[0]->{$self->[1]};
}

package PublicInbox::FakeInotify::Event;
use strict;

sub fullname { ${$_[0]} }
1;
debug log:

solving debd2d39ae5 ...
found debd2d39ae5 in public-inbox.git

user/dev discussion of public-inbox itself

This inbox may be cloned and mirrored by anyone:

	git clone --mirror https://public-inbox.org/meta
	git clone --mirror http://czquwvybam4bgbro.onion/meta
	git clone --mirror http://hjrcffqmbrq6wope.onion/meta
	git clone --mirror http://ou63pmih66umazou.onion/meta

	# If you have public-inbox 1.1+ installed, you may
	# initialize and index your mirror using the following commands:
	public-inbox-init -V1 meta meta/ https://public-inbox.org/meta \
		meta@public-inbox.org
	public-inbox-index meta

Example config snippet for mirrors.
Newsgroups are available over NNTP:
	nntp://news.public-inbox.org/inbox.comp.mail.public-inbox.meta
	nntp://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/inbox.comp.mail.public-inbox.meta
	nntp://ie5yzdi7fg72h7s4sdcztq5evakq23rdt33mfyfcddc5u3ndnw24ogqd.onion/inbox.comp.mail.public-inbox.meta
	nntp://4uok3hntl7oi7b4uf4rtfwefqeexfzil2w6kgk2jn5z2f764irre7byd.onion/inbox.comp.mail.public-inbox.meta
	nntp://news.gmane.io/gmane.mail.public-inbox.general
 note: .onion URLs require Tor: https://www.torproject.org/

code repositories for project(s) associated with this inbox:

	https://80x24.org/public-inbox.git

AGPL code for this site: git clone https://public-inbox.org/public-inbox.git