user/dev discussion of public-inbox itself
 help / color / mirror / code / Atom feed
cb605e2eac1dc7bf9259b84e95dc506e5e8df4d9 blob 3658 bytes (raw)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
 
#!perl -w
# Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
use strict;
use v5.10.1;
use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
use PublicInbox::CmdIPC4;
my $narg = 5;
my $sock;
my $recv_cmd = PublicInbox::CmdIPC4->can('recv_cmd4');
my $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4') // do {
	require PublicInbox::Spawn; # takes ~50ms even if built *sigh*
	$recv_cmd = PublicInbox::Spawn->can('recv_cmd4');
	PublicInbox::Spawn->can('send_cmd4');
};

my %pids;
my $sigchld = sub {
	my $flags = scalar(@_) ? POSIX::WNOHANG() : 0;
	for my $pid (keys %pids) {
		delete($pids{$pid}) if waitpid($pid, $flags) == $pid;
	}
};

my $exec_cmd = sub {
	my ($fds, $argc, @argv) = @_;
	my @old = (*STDIN{IO}, *STDOUT{IO}, *STDERR{IO});
	my @rdr;
	for my $fd (@$fds) {
		open(my $tmpfh, '+<&=', $fd) or die "open +<&=$fd: $!";
		push @rdr, shift(@old), $tmpfh;
	}
	require POSIX; # WNOHANG
	$SIG{CHLD} = $sigchld;
	my $pid = fork // die "fork: $!";
	if ($pid == 0) {
		my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
		while (my ($old_io, $tmpfh) = splice(@rdr, 0, 2)) {
			open $old_io, '+<&', $tmpfh or die "open +<&=: $!";
		}
		%ENV = (%ENV, %env);
		exec(@argv);
		warn "exec: @argv: $!\n";
		POSIX::_exit(1);
	}
	$pids{$pid} = 1;
};

if ($send_cmd && eval {
	my $path = do {
		my $runtime_dir = ($ENV{XDG_RUNTIME_DIR} // '') . '/lei';
		if ($runtime_dir eq '/lei') {
			require File::Spec;
			$runtime_dir = File::Spec->tmpdir."/lei-$<";
		}
		unless (-d $runtime_dir) {
			require File::Path;
			File::Path::mkpath($runtime_dir, 0, 0700);
		}
		"$runtime_dir/$narg.seq.sock";
	};
	my $addr = pack_sockaddr_un($path);
	socket($sock, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
	unless (connect($sock, $addr)) { # start the daemon if not started
		local $ENV{PERL5LIB} = join(':', @INC);
		open(my $daemon, '-|', $^X, qw[-MPublicInbox::LEI
			-E PublicInbox::LEI::lazy_start(@ARGV)],
			$path, $! + 0, $narg) or die "popen: $!";
		while (<$daemon>) { warn $_ } # EOF when STDERR is redirected
		close($daemon) or warn <<"";
lei-daemon could not start, exited with \$?=$?

		# try connecting again anyways, unlink+bind may be racy
		connect($sock, $addr) or die <<"";
connect($path): $! (after attempted daemon start)
Falling back to (slow) one-shot mode

	}
	# (Socket::MsgHdr|Inline::C), $sock are all available:
	open my $dh, '<', '.' or die "open(.) $!";
	my $buf = join("\0", scalar(@ARGV), @ARGV);
	while (my ($k, $v) = each %ENV) { $buf .= "\0$k=$v" }
	$buf .= "\0\0";
	my $n = $send_cmd->($sock, [0, 1, 2, fileno($dh)], $buf, MSG_EOR);
	if (!$n) {
		die "sendmsg: $! (check RLIMIT_NOFILE)\n" if $!{ETOOMANYREFS};
		die "sendmsg: $!\n";
	}
	1;
}) { # connected and request sent to lei-daemon, wait for responses or EOF
	my $x_it_code = 0;
	while (1) {
		my (@fds) = $recv_cmd->($sock, my $buf, 4096 * 33);
		if (scalar(@fds) == 1 && !defined($fds[0])) {
			next if $!{EINTR};
			last if $!{ECONNRESET};
			die "recvmsg: $!";
		}
		last if $buf eq '';
		if ($buf =~ /\Aexec (.+)\z/) {
			$exec_cmd->(\@fds, split(/\0/, $1));
		} elsif ($buf eq '-WINCH') {
			kill($buf, $$); # for MUA
		} elsif ($buf =~ /\Ax_it ([0-9]+)\z/) {
			$x_it_code = $1 + 0;
			last;
		} elsif ($buf =~ /\Achild_error ([0-9]+)\z/) {
			$x_it_code = $1 + 0;
		} else {
			$sigchld->();
			die $buf;
		}
	}
	$sigchld->();
	if (my $sig = ($x_it_code & 127)) {
		kill $sig, $$;
		sleep(1) while 1;
	}
	exit($x_it_code >> 8);
} else { # for systems lacking Socket::MsgHdr or Inline::C
	warn $@ if $@;
	require PublicInbox::LEI;
	PublicInbox::LEI::oneshot(__PACKAGE__);
}
debug log:

solving cb605e2e ...
found cb605e2e in public-inbox.git

user/dev discussion of public-inbox itself

This inbox may be cloned and mirrored by anyone:

	git clone --mirror https://public-inbox.org/meta
	git clone --mirror http://czquwvybam4bgbro.onion/meta
	git clone --mirror http://hjrcffqmbrq6wope.onion/meta
	git clone --mirror http://ou63pmih66umazou.onion/meta

	# If you have public-inbox 1.1+ installed, you may
	# initialize and index your mirror using the following commands:
	public-inbox-init -V1 meta meta/ https://public-inbox.org/meta \
		meta@public-inbox.org
	public-inbox-index meta

Example config snippet for mirrors.
Newsgroups are available over NNTP:
	nntp://news.public-inbox.org/inbox.comp.mail.public-inbox.meta
	nntp://ou63pmih66umazou.onion/inbox.comp.mail.public-inbox.meta
	nntp://czquwvybam4bgbro.onion/inbox.comp.mail.public-inbox.meta
	nntp://hjrcffqmbrq6wope.onion/inbox.comp.mail.public-inbox.meta
	nntp://news.gmane.io/gmane.mail.public-inbox.general
 note: .onion URLs require Tor: https://www.torproject.org/

code repositories for project(s) associated with this inbox:

	https://80x24.org/public-inbox.git

AGPL code for this site: git clone https://public-inbox.org/public-inbox.git