user/dev discussion of public-inbox itself
 help / color / mirror / code / Atom feed
c0b423f63e6b5774a0a1fead865dff033610cc6f blob 6444 bytes (raw)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
 
# Copyright (C) 2021 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>

# per-mitem/smsg iterators for search results
# "ovv" => "Overview viewer"
package PublicInbox::LeiOverview;
use strict;
use v5.10.1;
use parent qw(PublicInbox::Lock);
use POSIX qw(strftime);
use Fcntl qw(F_GETFL O_APPEND);
use File::Spec;
use File::Temp ();
use PublicInbox::MID qw($MID_EXTRACT);
use PublicInbox::Address qw(pairs);
use PublicInbox::Config;
use PublicInbox::Search qw(get_pct);
use PublicInbox::LeiDedupe;
use PublicInbox::LeiToMail;

# cf. https://en.wikipedia.org/wiki/JSON_streaming
my $JSONL = 'ldjson|ndjson|jsonl'; # 3 names for the same thing

sub _iso8601 ($) { strftime('%Y-%m-%dT%H:%M:%SZ', gmtime($_[0])) }

# we open this in the parent process before ->wq_do handoff
sub ovv_out_lk_init ($) {
	my ($self) = @_;
	$self->{tmp_lk_id} = "$self.$$";
	my $tmp = File::Temp->new("lei-ovv.dst.$$.lock-XXXXXX",
					TMPDIR => 1, UNLINK => 0);
	$self->{lock_path} = $tmp->filename;
}

sub ovv_out_lk_cancel ($) {
	my ($self) = @_;
	($self->{tmp_lk_id}//'') eq "$self.$$" and
		unlink(delete($self->{lock_path}));
}

sub new {
	my ($class, $lei) = @_;
	my $opt = $lei->{opt};
	my $dst = $opt->{output} // '-';
	$dst = '/dev/stdout' if $dst eq '-';

	my $fmt = $opt->{'format'};
	$fmt = lc($fmt) if defined $fmt;
	if ($dst =~ s/\A([a-z0-9]+)://is) { # e.g. Maildir:/home/user/Mail/
		my $ofmt = lc $1;
		$fmt //= $ofmt;
		return $lei->fail(<<"") if $fmt ne $ofmt;
--format=$fmt and --output=$ofmt conflict

	}
	$fmt //= 'json' if $dst eq '/dev/stdout';
	$fmt //= 'maildir';

	if (index($dst, '://') < 0) { # not a URL, so assume path
		 $dst = File::Spec->canonpath($dst);
	} # else URL

	my $self = bless { fmt => $fmt, dst => $dst }, $class;
	$lei->{ovv} = $self;
	my $json;
	if ($fmt =~ /\A($JSONL|(?:concat)?json)\z/) {
		$json = $self->{json} = ref(PublicInbox::Config->json);
	}
	my ($isatty, $seekable);
	if ($dst eq '/dev/stdout') {
		$isatty = -t $lei->{1};
		$lei->start_pager if $isatty;
		$opt->{pretty} //= $isatty;
		if (!$isatty && -f _) {
			my $fl = fcntl($lei->{1}, F_GETFL, 0) //
				return $lei->fail("fcntl(stdout): $!");
			ovv_out_lk_init($self) unless ($fl & O_APPEND);
		} else {
			ovv_out_lk_init($self);
		}
	}
	if (!$json) {
		# default to the cheapest sort since MUA usually resorts
		$lei->{opt}->{'sort'} //= 'docid' if $dst ne '/dev/stdout';
		$lei->{l2m} = PublicInbox::LeiToMail->new($lei);
	}
	$lei->{dedupe} //= PublicInbox::LeiDedupe->new($lei);
	$self;
}

# called once by parent
sub ovv_begin {
	my ($self, $lei) = @_;
	if ($self->{fmt} eq 'json') {
		print { $lei->{1} } '[';
	} # TODO HTML/Atom/...
}

# called once by parent (via PublicInbox::EOFpipe)
sub ovv_end {
	my ($self, $lei) = @_;
	if ($self->{fmt} eq 'json') {
		# JSON doesn't allow trailing commas, and preventing
		# trailing commas is a PITA when parallelizing outputs
		print { $lei->{1} } "null]\n";
	} elsif ($self->{fmt} eq 'concatjson') {
		print { $lei->{1} } "\n";
	}
}

sub ovv_atfork_child {
	my ($self) = @_;
	# reopen dedupe here
}

# prepares an smsg for JSON
sub _unbless_smsg {
	my ($smsg, $mitem) = @_;

	delete @$smsg{qw(lines bytes num tid)};
	$smsg->{rt} = _iso8601(delete $smsg->{ts}); # JMAP receivedAt
	$smsg->{dt} = _iso8601(delete $smsg->{ds}); # JMAP UTCDate
	$smsg->{relevance} = get_pct($mitem) if $mitem;

	if (my $r = delete $smsg->{references}) {
		$smsg->{refs} = [
				map { "<$_>" } ($r =~ m/$MID_EXTRACT/go) ];
	}
	if (my $m = delete($smsg->{mid})) {
		$smsg->{'m'} = "<$m>";
	}
	for my $f (qw(from to cc)) {
		my $v = delete $smsg->{$f} or next;
		$smsg->{substr($f, 0, 1)} = pairs($v);
	}
	$smsg->{'s'} = delete $smsg->{subject};
	# can we be bothered to parse From/To/Cc into arrays?
	scalar { %$smsg }; # unbless
}

sub ovv_atexit_child {
	my ($self, $lei) = @_;
	if (my $git = delete $self->{git}) {
		$git->async_wait_all;
	}
	if (my $bref = delete $lei->{ovv_buf}) {
		my $out = $lei->{1} or return;
		my $lk = $self->lock_for_scope;
		print $out $$bref;
	}
}

# JSON module ->pretty output wastes too much vertical white space,
# this (IMHO) provides better use of screen real-estate while not
# being excessively compact:
sub _json_pretty {
	my ($json, $k, $v) = @_;
	if (ref $v eq 'ARRAY') {
		if (@$v) {
			my $sep = ",\n" . (' ' x (length($k) + 7));
			if (ref($v->[0])) { # f/t/c
				$v = '[' . join($sep, map {
					my $pair = $json->encode($_);
					$pair =~ s/(null|"),"/$1, "/g;
					$pair;
				} @$v) . ']';
			} else { # references
				$v = '[' . join($sep, map {
					substr($json->encode([$_]), 1, -1);
				} @$v) . ']';
			}
		} else {
			$v = '[]';
		}
	}
	qq{  "$k": }.$v;
}

sub ovv_each_smsg_cb { # runs in wq worker usually
	my ($self, $lei, $ibxish) = @_;
	$lei->{ovv_buf} = \(my $buf = '');
	delete(@$self{qw(lock_path tmp_lk_id)}) unless $lei->{-parallel};
	my $json;
	$lei->{1}->autoflush(1);
	if (my $pkg = $self->{json}) {
		$json = $pkg->new;
		$json->utf8->canonical;
		$json->ascii(1) if $lei->{opt}->{ascii};
	}
	if (my $l2m = $lei->{l2m}) {
		my $wcb = $l2m->write_cb($lei);
		my $git = $ibxish->git; # (LeiXSearch|Inbox|ExtSearch)->git
		$self->{git} = $git; # for ovv_atexit_child
		my $g2m = $l2m->can('git_to_mail');
		sub {
			my ($smsg, $mitem) = @_;
			my $kw = []; # TODO get from mitem
			$git->cat_async($smsg->{blob}, $g2m, [ $wcb, $kw ]);
		};
	} elsif ($self->{fmt} =~ /\A(concat)?json\z/ && $lei->{opt}->{pretty}) {
		my $EOR = ($1//'') eq 'concat' ? "\n}" : "\n},";
		sub { # DIY prettiness :P
			my ($smsg, $mitem) = @_;
			$smsg = _unbless_smsg($smsg, $mitem);
			$buf .= "{\n";
			$buf .= join(",\n", map {
				my $v = $smsg->{$_};
				if (ref($v)) {
					_json_pretty($json, $_, $v);
				} else {
					$v = $json->encode([$v]);
					qq{  "$_": }.substr($v, 1, -1);
				}
			} sort keys %$smsg);
			$buf .= $EOR;
			if (length($buf) > 65536) {
				my $lk = $self->lock_for_scope;
				print { $lei->{1} } $buf;
				$buf = '';
			}
		}
	} elsif ($json) {
		my $ORS = $self->{fmt} eq 'json' ? ",\n" : "\n"; # JSONL
		sub {
			my ($smsg, $mitem) = @_;
			delete @$smsg{qw(tid num)};
			$buf .= $json->encode(_unbless_smsg(@_)) . $ORS;
			if (length($buf) > 65536) {
				my $lk = $self->lock_for_scope;
				print { $lei->{1} } $buf;
				$buf = '';
			}
		}
	} elsif ($self->{fmt} eq 'oid') {
		sub {
			my ($smsg, $mitem) = @_;
		}
	} # else { ...
}

no warnings 'once';
*DESTROY = \&ovv_out_lk_cancel;

1;
debug log:

solving c0b423f6 ...
found c0b423f6 in https://80x24.org/public-inbox.git

Code repositories for project(s) associated with this inbox:

	https://80x24.org/public-inbox.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).