user/dev discussion of public-inbox itself
 help / color / mirror / code / Atom feed
be518134ceb29d8a2dbad565f1e7f1e983325641 blob 3060 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
 
#!/usr/bin/perl -w
# Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
# Basic tool to create a Xapian search index for a public-inbox.
# Usage with libeatmydata <https://www.flamingspork.com/projects/libeatmydata/>
# highly recommended: eatmydata public-inbox-index INBOX_DIR

use strict;
use warnings;
use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
my $usage = "public-inbox-index INBOX_DIR";
use PublicInbox::Admin;
PublicInbox::Admin::require_or_die('-index');
use PublicInbox::Xapcmd;

my $compact_opt;
my $opt = { quiet => -1, compact => 0, maxsize => undef, sync => 1 };
GetOptions($opt, qw(verbose|v+ reindex rethread compact|c+ jobs|j=i prune sync!
		indexlevel|L=s maxsize|max-size=s batchsize|batch-size=s
		sequentialshard|seq-shard|sequential-shard))
	or die "bad command-line args\n$usage";
die "--jobs must be >= 0\n" if defined $opt->{jobs} && $opt->{jobs} < 0;

if ($opt->{compact}) {
	require PublicInbox::Xapcmd;
	PublicInbox::Xapcmd::check_compact();
	$compact_opt = { -coarse_lock => 1, compact => 1 };
	if (defined(my $jobs = $opt->{jobs})) {
		$compact_opt->{jobs} = $jobs;
	}
}

my $cfg = PublicInbox::Config->new;
my @ibxs = PublicInbox::Admin::resolve_inboxes(\@ARGV, undef, $cfg);
PublicInbox::Admin::require_or_die('-index');
unless (@ibxs) { print STDERR "Usage: $usage\n"; exit 1 }

my $max_size = $opt->{maxsize} // $cfg->{lc('publicInbox.indexMaxSize')};
if (defined $max_size) {
	PublicInbox::Admin::parse_unsigned(\$max_size) or
		die "`publicInbox.indexMaxSize=$max_size' not parsed\n";
}

if (my $bs = $opt->{batchsize} // $cfg->{lc('publicInbox.indexBatchSize')}) {
	PublicInbox::Admin::parse_unsigned(\$bs) or
		die "`publicInbox.indexBatchSize=$bs' not parsed\n";
	$PublicInbox::SearchIdx::BATCH_BYTES = $bs;
}

my $s = $opt->{sequentialshard} //
			$cfg->{lc('publicInbox.indexSequentialShard')};
if (defined $s) {
	my $v = $cfg->git_bool($s);
	defined($v) or
		die "`publicInbox.indexSequentialShard=$s' not boolean\n";
	$opt->{sequentialshard} = $v;
}

my $mods = {};
foreach my $ibx (@ibxs) {
	# XXX: users can shoot themselves in the foot, with opt->{indexlevel}
	$ibx->{indexlevel} //= $opt->{indexlevel} //
			PublicInbox::Admin::detect_indexlevel($ibx);
	$ibx->{index_max_size} = $max_size;
	PublicInbox::Admin::scan_ibx_modules($mods, $ibx);
}

PublicInbox::Admin::require_or_die(keys %$mods);
PublicInbox::Admin::progress_prepare($opt);
for my $ibx (@ibxs) {
	$ibx = PublicInbox::InboxWritable->new($ibx);
	if ($opt->{compact} >= 2) {
		PublicInbox::Xapcmd::run($ibx, 'compact', $compact_opt);
	}
	$ibx->{-no_sync} = 1 if !$opt->{sync};

	my $ibx_opt = $opt;
	if (defined(my $s = $ibx->{indexsequentialshard})) {
		defined(my $v = $cfg->git_bool($s)) or die <<EOL;
publicInbox.$ibx->{name}.indexSequentialShard not boolean
EOL
		$ibx_opt = { %$opt, sequentialshard => $v };
	}
	PublicInbox::Admin::index_inbox($ibx, undef, $ibx_opt);
	PublicInbox::Xapcmd::run($ibx, 'compact', $compact_opt) if $compact_opt;
}
debug log:

solving be518134 ...
found be518134 in https://80x24.org/public-inbox.git

Code repositories for project(s) associated with this inbox:

	https://80x24.org/public-inbox.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).