user/dev discussion of public-inbox itself
 help / color / mirror / code / Atom feed
b077d63a4b4f365b316541913856772879d1b783 blob 1455 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
 
# Copyright (C) 2020 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>

# for systems lacking Linux::Inotify2 or IO::KQueue, just emulates
# enough of Linux::Inotify2
package PublicInbox::FakeInotify;
use strict;
use Time::HiRes qw(stat);
my $IN_CLOSE = 0x08 | 0x10; # match Linux inotify

my $poll_intvl = 2; # same as Filesys::Notify::Simple
my $for_cancel = bless \(my $x), 'PublicInbox::FakeInotify::Watch';

sub poll_once {
	my ($self) = @_;
	sub {
		eval { $self->poll };
		warn "E: FakeInotify->poll: $@\n" if $@;
		PublicInbox::DS::add_timer($poll_intvl, poll_once($self));
	};
}

sub new {
	my $self = bless { watch => {} }, __PACKAGE__;
	PublicInbox::DS::add_timer($poll_intvl, poll_once($self));
	$self;
}

# behaves like Linux::Inotify2->watch
sub watch {
	my ($self, $path, $mask, $cb) = @_;
	my @st = stat($path) or return;
	$self->{watch}->{"$path\0$mask"} = [ @st, $cb ];
	$for_cancel;
}

# behaves like non-blocking Linux::Inotify2->poll
sub poll {
	my ($self) = @_;
	my $watch = $self->{watch} or return;
	for my $x (keys %$watch) {
		my ($path, $mask) = split(/\0/, $x, 2);
		my @now = stat($path) or next;
		my $prv = $watch->{$x};
		my $cb = $prv->[-1];
		# 10: ctime, 7: size
		if ($prv->[10] != $now[10]) {
			if (($mask & $IN_CLOSE) == $IN_CLOSE) {
				eval { $cb->() };
			}
		}
		@$prv = (@now, $cb);
	}
}

package PublicInbox::FakeInotify::Watch;
sub cancel {} # noop

1;
debug log:

solving b077d63a4b4 ...
found b077d63a4b4 in https://80x24.org/public-inbox.git

Code repositories for project(s) associated with this inbox:

	https://80x24.org/public-inbox.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).