user/dev discussion of public-inbox itself
 help / color / mirror / code / Atom feed
Search results ordered by [date|relevance]  view[summary|nested|Atom feed]
thread overview below | download mbox.gz: |
* [PATCH 1/6] msg_iter: new internal API for iterating through MIME
  @ 2016-05-19 21:28  7% ` Eric Wong
  0 siblings, 0 replies; 1+ results
From: Eric Wong @ 2016-05-19 21:28 UTC (permalink / raw)
  To: meta

Unlike Email::MIME::walk_parts, this is non-recursive and gives
depth + index offset information about the part for creating
links for later retrieval

It is intended for read-only access and changes are not
propagated to the parent; however future versions of it
may clobber bodies or the original version as it iterates
to reduce memory overhead.

It is intended for making it easy to locate attachments within a
message in the WWW view.
---
 lib/PublicInbox/MsgIter.pm | 36 ++++++++++++++++++++++++++++++++++++
 t/msg_iter.t               | 40 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 76 insertions(+)
 create mode 100644 lib/PublicInbox/MsgIter.pm
 create mode 100644 t/msg_iter.t

diff --git a/lib/PublicInbox/MsgIter.pm b/lib/PublicInbox/MsgIter.pm
new file mode 100644
index 0000000..d0dd82f
--- /dev/null
+++ b/lib/PublicInbox/MsgIter.pm
@@ -0,0 +1,36 @@
+# Copyright (C) 2016 all contributors <meta@public-inbox.org>
+# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
+#
+package PublicInbox::MsgIter;
+use strict;
+use warnings;
+use base qw(Exporter);
+our @EXPORT = qw(msg_iter);
+
+# Like Email::MIME::walk_parts, but this is:
+# * non-recursive
+# * passes depth and indices to the iterator callback
+sub msg_iter ($$) {
+	my ($mime, $cb) = @_;
+	my @parts = $mime->subparts;
+	if (@parts) {
+		my $i = 0;
+		@parts = map { [ $_, 1, ++$i ] } @parts;
+		while (my $p = shift @parts) {
+			my ($part, $depth, @idx) = @$p;
+			my @sub = $part->subparts;
+			if (@sub) {
+				$depth++;
+				$i = 0;
+				@sub = map { [ $_, $depth, @idx, ++$i ] } @sub;
+				@parts = (@sub, @parts);
+			} else {
+				$cb->($p);
+			}
+		}
+	} else {
+		$cb->([$mime, 0, 0]);
+	}
+}
+
+1;
diff --git a/t/msg_iter.t b/t/msg_iter.t
new file mode 100644
index 0000000..cc58b93
--- /dev/null
+++ b/t/msg_iter.t
@@ -0,0 +1,40 @@
+# Copyright (C) 2016 all contributors <meta@public-inbox.org>
+# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
+use strict;
+use warnings;
+use Test::More;
+use Email::MIME;
+use_ok('PublicInbox::MsgIter');
+
+{
+	my $parts = [ Email::MIME->create(body => 'a'),
+			Email::MIME->create(body => 'b') ];
+	my $mime = Email::MIME->create(parts => $parts,
+				header_str => [ From => 'root@localhost' ]);
+	my @parts;
+	msg_iter($mime, sub {
+		my ($part, $level, @ex) = @{$_[0]};
+		push @parts, [ $part->body_str, $level, @ex ];
+	});
+	is_deeply(\@parts, [ [ qw(a 1 1) ], [ qw(b 1 2) ] ], 'order is fine');
+}
+
+{
+	my $parts = [ Email::MIME->create(body => 'a'),
+			Email::MIME->create(body => 'b') ];
+	$parts = [ Email::MIME->create(parts => $parts,
+				header_str => [ From => 'sub@localhost' ]),
+			Email::MIME->create(body => 'sig') ];
+	my $mime = Email::MIME->create(parts => $parts,
+				header_str => [ From => 'root@localhost' ]);
+	my @parts;
+	msg_iter($mime, sub {
+		my ($part, $level, @ex) = @{$_[0]};
+		push @parts, [ $part->body_str, $level, @ex ];
+	});
+	is_deeply(\@parts, [ [ qw(a 2 1 1)], [qw(b 2 1 2)], [qw(sig 1 2)] ],
+		'nested part shows up properly');
+}
+
+done_testing();
+1;
-- 
EW


^ permalink raw reply	[relevance 7%]

Results 1-1 of 1 | reverse | sort options + mbox downloads above
-- links below jump to the message on this page --
2016-05-19 21:25     [PATCH 1/7] view: rely on Email::MIME::body_str for decoding Eric Wong
2016-05-19 21:28  7% ` [PATCH 1/6] msg_iter: new internal API for iterating through MIME Eric Wong

Code repositories for project(s) associated with this inbox:

	https://80x24.org/public-inbox.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).