* [PATCH 14/82] imap: allow fetch of partial of BODY[...] and headers
2020-06-10 7:03 7% [PATCH 00/82] public-inbox-imapd: read-only IMAP server Eric Wong
@ 2020-06-10 7:04 5% ` Eric Wong
0 siblings, 0 replies; 2+ results
From: Eric Wong @ 2020-06-10 7:04 UTC (permalink / raw)
To: meta
IMAP supports a high level of granularity when it comes to
fetching, but fortunately Perl makes it fairly easy to support.
---
MANIFEST | 1 +
lib/PublicInbox/IMAP.pm | 154 ++++++++++++++++++++++++++++++++++++++--
t/imap.t | 43 +++++++++++
t/imapd.t | 61 +++++++++++++++-
4 files changed, 253 insertions(+), 6 deletions(-)
create mode 100644 t/imap.t
diff --git a/MANIFEST b/MANIFEST
index 8aff192c7ee..0803c3654d6 100644
--- a/MANIFEST
+++ b/MANIFEST
@@ -266,6 +266,7 @@ t/httpd-https.t
t/httpd-unix.t
t/httpd.t
t/hval.t
+t/imap.t
t/imapd-tls.t
t/imapd.t
t/import.t
diff --git a/lib/PublicInbox/IMAP.pm b/lib/PublicInbox/IMAP.pm
index 6c5e0290925..86e0a176be1 100644
--- a/lib/PublicInbox/IMAP.pm
+++ b/lib/PublicInbox/IMAP.pm
@@ -390,7 +390,9 @@ sub uid_fetch_cb { # called by git->cat_async
$self->msg_more(' BODYSTRUCTURE '.fetch_body($eml, 1));
$want->{BODY} and
$self->msg_more(' BODY '.fetch_body($eml));
-
+ if (my $partial = delete $want->{-partial}) {
+ partial_emit($self, $partial, $eml);
+ }
$self->msg_more(")\r\n");
}
@@ -454,16 +456,158 @@ sub cmd_list ($$$$) {
\(join('', @$l, "$tag OK List complete\r\n"));
}
+sub eml_index_offs_i { # PublicInbox::Eml::each_part callback
+ my ($p, $all) = @_;
+ my ($eml, undef, $idx) = @$p;
+ if ($idx && lc($eml->ct->{type}) eq 'multipart') {
+ $eml->{imap_bdy} = $eml->{bdy} // \'';
+ }
+ $all->{$idx} = $eml; # $idx => Eml
+}
+
+# prepares an index for BODY[$SECTION_IDX] fetches
+sub eml_body_idx ($$) {
+ my ($eml, $section_idx) = @_;
+ my $idx = $eml->{imap_all_parts} //= do {
+ my $all = {};
+ $eml->each_part(\&eml_index_offs_i, $all, 0, 1);
+ # top-level of multipart, BODY[0] not allowed (nz-number)
+ delete $all->{0};
+ $all;
+ };
+ $idx->{$section_idx};
+}
+
+# BODY[($SECTION_IDX)?(.$SECTION_NAME)?]<$offset.$bytes>
+sub partial_body {
+ my ($eml, $section_idx, $section_name) = @_;
+ if (defined $section_idx) {
+ $eml = eml_body_idx($eml, $section_idx) or return;
+ }
+ if (defined $section_name) {
+ if ($section_name eq 'MIME') {
+ # RFC 3501 6.4.5 states:
+ # The MIME part specifier MUST be prefixed
+ # by one or more numeric part specifiers
+ return unless defined $section_idx;
+ return $eml->header_obj->as_string . "\r\n";
+ }
+ my $bdy = $eml->{bdy} // $eml->{imap_bdy} // \'';
+ $eml = PublicInbox::Eml->new($$bdy);
+ if ($section_name eq 'TEXT') {
+ return $eml->body_raw;
+ } elsif ($section_name eq 'HEADER') {
+ return $eml->header_obj->as_string . "\r\n";
+ } else {
+ die "BUG: bad section_name=$section_name";
+ }
+ }
+ ${$eml->{bdy} // $eml->{imap_bdy} // \''};
+}
+
+# similar to what's in PublicInbox::Eml::re_memo, but doesn't memoize
+# to avoid OOM with malicious users
+sub hdrs_regexp ($) {
+ my ($hdrs) = @_;
+ my $names = join('|', map { "\Q$_" } split(/[ \t]+/, $hdrs));
+ qr/^(?:$names):[ \t]*[^\n]*\r?\n # 1st line
+ # continuation lines:
+ (?:[^:\n]*?[ \t]+[^\n]*\r?\n)*
+ /ismx;
+}
+
+# BODY[($SECTION_IDX.)?HEADER.FIELDS.NOT ($HDRS)]<$offset.$bytes>
+sub partial_hdr_not {
+ my ($eml, $section_idx, $hdrs) = @_;
+ if (defined $section_idx) {
+ $eml = eml_body_idx($eml, $section_idx) or return;
+ }
+ my $str = $eml->header_obj->as_string;
+ my $re = hdrs_regexp($hdrs);
+ $str =~ s/$re//g;
+ $str .= "\r\n";
+}
+
+# BODY[($SECTION_IDX.)?HEADER.FIELDS ($HDRS)]<$offset.$bytes>
+sub partial_hdr_get {
+ my ($eml, $section_idx, $hdrs) = @_;
+ if (defined $section_idx) {
+ $eml = eml_body_idx($eml, $section_idx) or return;
+ }
+ my $str = $eml->header_obj->as_string;
+ my $re = hdrs_regexp($hdrs);
+ join('', ($str =~ m/($re)/g), "\r\n");
+}
+
+sub partial_prepare ($$$) {
+ my ($partial, $want, $att) = @_;
+
+ # recombine [ "BODY[1.HEADER.FIELDS", "(foo", "bar)]" ]
+ # back to: "BODY[1.HEADER.FIELDS (foo bar)]"
+ return unless $att =~ /\ABODY(?:\.PEEK)?\[/s;
+ until (rindex($att, ']') >= 0) {
+ my $next = shift @$want or return;
+ $att .= ' ' . uc($next);
+ }
+ if ($att =~ /\ABODY(?:\.PEEK)?\[
+ ([0-9]+(?:\.[0-9]+)*)? # 1 - section_idx
+ (?:\.(HEADER|MIME|TEXT))? # 2 - section_name
+ \](?:<([0-9]+)(?:\.([0-9]+))?>)?\z/sx) { # 3, 4
+ $partial->{$att} = [ \&partial_body, $1, $2, $3, $4 ];
+ } elsif ($att =~ /\ABODY(?:\.PEEK)?\[
+ (?:([0-9]+(?:\.[0-9]+)*)\.)? # 1 - section_idx
+ (?:HEADER\.FIELDS(\.NOT)?)\x20 # 2
+ \(([A-Z0-9\-\x20]+)\) # 3 - hdrs
+ \](?:<([0-9]+)(?:\.([0-9]+))?>)?\z/sx) { # 4 5
+ $partial->{$att} = [ $2 ? \&partial_hdr_not
+ : \&partial_hdr_get,
+ $1, $3, $4, $5 ];
+ } else {
+ undef;
+ }
+}
+
+sub partial_emit ($$$) {
+ my ($self, $partial, $eml) = @_;
+ for my $k (sort keys %$partial) {
+ my ($cb, @args) = @{$partial->{$k}};
+ my ($offset, $len) = splice(@args, -2);
+ # $cb is partial_body|partial_hdr_get|partial_hdr_not
+ my $str = $cb->($eml, @args) // '';
+ if (defined $offset) {
+ if (defined $len) {
+ $str = substr($str, $offset, $len);
+ $k =~ s/\.$len>\z/>/ or warn
+"BUG: unable to remove `.$len>' from `$k'";
+ } else {
+ $str = substr($str, $offset);
+ $len = length($str);
+ }
+ } else {
+ $len = length($str);
+ }
+ $self->msg_more(" $k {$len}\r\n");
+ $self->msg_more($str);
+ }
+}
+
sub cmd_uid_fetch ($$$;@) {
my ($self, $tag, $range, @want) = @_;
my $ibx = $self->{ibx} or return "$tag BAD No mailbox selected\r\n";
if ($want[0] =~ s/\A\(//s) {
$want[-1] =~ s/\)\z//s or return "$tag BAD no rparen\r\n";
}
- my %want = map {;
- my $x = $FETCH_ATT{uc($_)} or return "$tag BAD param: $_\r\n";
- %$x;
- } @want;
+ my (%partial, %want);
+ while (defined(my $att = shift @want)) {
+ $att = uc($att);
+ my $x = $FETCH_ATT{$att};
+ if ($x) {
+ %want = (%want, %$x);
+ } elsif (!partial_prepare(\%partial, \@want, $att)) {
+ return "$tag BAD param: $att\r\n";
+ }
+ }
+ $want{-partial} = \%partial if scalar keys %partial;
my ($beg, $end);
my $msgs = [];
if ($range =~ /\A([0-9]+):([0-9]+)\z/s) {
diff --git a/t/imap.t b/t/imap.t
new file mode 100644
index 00000000000..c435d365543
--- /dev/null
+++ b/t/imap.t
@@ -0,0 +1,43 @@
+#!perl -w
+# Copyright (C) 2020 all contributors <meta@public-inbox.org>
+# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
+use strict;
+use Test::More;
+use PublicInbox::IMAP;
+{
+ my $partial_prepare = \&PublicInbox::IMAP::partial_prepare;
+ my $x = {};
+ my $r = $partial_prepare->($x, [], my $p = 'BODY.PEEK[9]');
+ ok($r, $p);
+ $r = $partial_prepare->($x, [], $p = 'BODY.PEEK[9]<5>');
+ ok($r, $p);
+ $r = $partial_prepare->($x, [], $p = 'BODY.PEEK[9]<5.1>');
+ ok($r, $p);
+ $r = $partial_prepare->($x, [], $p = 'BODY[1.1]');
+ ok($r, $p);
+ $r = $partial_prepare->($x, [], $p = 'BODY[HEADER.FIELDS (DATE FROM)]');
+ ok($r, $p);
+ $r = $partial_prepare->($x, [], $p = 'BODY[HEADER.FIELDS.NOT (TO)]');
+ ok($r, $p);
+ $r = $partial_prepare->($x, [], $p = 'BODY[HEDDER.FIELDS.NOT (TO)]');
+ ok(!$r, "rejected misspelling $p");
+ $r = $partial_prepare->($x, [], $p = 'BODY[1.1.HEADER.FIELDS (TO)]');
+ ok($r, $p);
+ my $partial_body = \&PublicInbox::IMAP::partial_body;
+ my $partial_hdr_get = \&PublicInbox::IMAP::partial_hdr_get;
+ my $partial_hdr_not = \&PublicInbox::IMAP::partial_hdr_not;
+ is_deeply($x, {
+ 'BODY.PEEK[9]' => [ $partial_body, 9, undef, undef, undef ],
+ 'BODY.PEEK[9]<5>' => [ $partial_body, 9, undef, 5, undef ],
+ 'BODY.PEEK[9]<5.1>' => [ $partial_body, 9, undef, 5, 1 ],
+ 'BODY[1.1]' => [ $partial_body, '1.1', undef, undef, undef ],
+ 'BODY[HEADER.FIELDS (DATE FROM)]' => [ $partial_hdr_get,
+ undef, 'DATE FROM', undef, undef ],
+ 'BODY[HEADER.FIELDS.NOT (TO)]' => [ $partial_hdr_not,
+ undef, 'TO', undef, undef ],
+ 'BODY[1.1.HEADER.FIELDS (TO)]' => [ $partial_hdr_get,
+ '1.1', 'TO', undef, undef ],
+ }, 'structure matches expected');
+}
+
+done_testing;
diff --git a/t/imapd.t b/t/imapd.t
index 31154bdf3e7..a63be0fd0c2 100644
--- a/t/imapd.t
+++ b/t/imapd.t
@@ -191,6 +191,31 @@ for my $r ('1:*', '1') {
$ret = $mic->fetch_hash($r, 'FLAGS') or BAIL_OUT "FETCH $@";
is_deeply($ret->{1}->{FLAGS}, '', 'no flags');
+ $ret = $mic->fetch_hash($r, 'BODY[1]') or BAIL_OUT "FETCH $@";
+ like($ret->{1}->{'BODY[1]'}, qr/\AThis is a test message/, 'BODY[1]');
+
+ $ret = $mic->fetch_hash($r, 'BODY[1]<1>') or BAIL_OUT "FETCH $@";
+ like($ret->{1}->{'BODY[1]<1>'}, qr/\Ahis is a test message/,
+ 'BODY[1]<1>');
+
+ $ret = $mic->fetch_hash($r, 'BODY[1]<2.3>') or BAIL_OUT "FETCH $@";
+ is($ret->{1}->{'BODY[1]<2>'}, "is ", 'BODY[1]<2.3>');
+ $ret = $mic->bodypart_string($r, 1, 3, 2) or
+ BAIL_OUT "bodypart_string $@";
+ is($ret, "is ", 'bodypart string');
+
+ $ret = $mic->fetch_hash($r, 'BODY[HEADER.FIELDS.NOT (Message-ID)]')
+ or BAIL_OUT "FETCH $@";
+ $ret = $ret->{1}->{'BODY[HEADER.FIELDS.NOT (MESSAGE-ID)]'};
+ unlike($ret, qr/message-id/i, 'Message-ID excluded');
+ like($ret, qr/\r\n\r\n\z/s, 'got header end');
+
+ $ret = $mic->fetch_hash($r, 'BODY[HEADER.FIELDS (Message-ID)]')
+ or BAIL_OUT "FETCH $@";
+ is($ret->{1}->{'BODY[HEADER.FIELDS (MESSAGE-ID)]'},
+ 'Message-ID: <testmessage@example.com>'."\r\n\r\n",
+ 'got only Message-ID');
+
my $bs = $mic->get_bodystructure($r) or BAIL_OUT("bodystructure: $@");
ok($bs, 'got a bodystructure');
is(lc($bs->bodytype), 'text', '->bodytype');
@@ -292,7 +317,41 @@ $pi_config->each_inbox(sub {
ok($bs, 'BODYSTRUCTURE ok for deeply nested');
$ret = $mic->fetch_hash($uidnext, 'BODY') or BAIL_OUT "FETCH $@";
ok($ret->{$uidnext}->{BODY}, 'got something in BODY');
-});
+
+ # this matches dovecot behavior
+ $ret = $mic->fetch_hash($uidnext, 'BODY[1]') or BAIL_OUT "FETCH $@";
+ is($ret->{$uidnext}->{'BODY[1]'},
+ "testing embedded message harder\r\n", 'BODY[1]');
+ $ret = $mic->fetch_hash($uidnext, 'BODY[2]') or BAIL_OUT "FETCH $@";
+ like($ret->{$uidnext}->{'BODY[2]'},
+ qr/\ADate: Sat, 18 Apr 2020 22:20:20 /, 'BODY[2]');
+
+ $ret = $mic->fetch_hash($uidnext, 'BODY[2.1.1]') or BAIL_OUT "FETCH $@";
+ is($ret->{$uidnext}->{'BODY[2.1.1]'},
+ "testing embedded message\r\n", 'BODY[2.1.1]');
+
+ $ret = $mic->fetch_hash($uidnext, 'BODY[2.1.2]') or BAIL_OUT "FETCH $@";
+ like($ret->{$uidnext}->{'BODY[2.1.2]'}, qr/\AFrom: /,
+ 'BODY[2.1.2] tip matched');
+ like($ret->{$uidnext}->{'BODY[2.1.2]'},
+ # trailing CRLF may vary depending on MIME parser
+ qr/done_testing;(?:\r\n){1,2}\z/,
+ 'BODY[2.1.2] tail matched');
+
+ $ret = $mic->fetch_hash($uidnext, 'BODY[2.HEADER]') or
+ BAIL_OUT "2.HEADER $@";
+ like($ret->{$uidnext}->{'BODY[2.HEADER]'},
+ qr/\ADate: Sat, 18 Apr 2020 22:20:20 /,
+ '2.HEADER of message/rfc822');
+
+ $ret = $mic->fetch_hash($uidnext, 'BODY[2.MIME]') or
+ BAIL_OUT "2.MIME $@";
+ is($ret->{$uidnext}->{'BODY[2.MIME]'}, <<EOF, 'BODY[2.MIME]');
+Content-Type: message/rfc822\r
+Content-Disposition: attachment; filename="embed2x\.eml"\r
+\r
+EOF
+}); # each_inbox
$td->kill;
$td->join;
^ permalink raw reply related [relevance 5%]
* [PATCH 00/82] public-inbox-imapd: read-only IMAP server
@ 2020-06-10 7:03 7% Eric Wong
2020-06-10 7:04 5% ` [PATCH 14/82] imap: allow fetch of partial of BODY[...] and headers Eric Wong
0 siblings, 1 reply; 2+ results
From: Eric Wong @ 2020-06-10 7:03 UTC (permalink / raw)
To: meta
So I finally wrote my first IMAP server! And I'm actually
fairly satisfied with how it's turning out to support a bunch
of other performance + scalability work I've wanted to do.
Some previous notes here:
https://public-inbox.org/meta/20200609113442.GA16856@dcvr/
I finally seem to have gotten it to play nicely with mutt header
caching, so it's fit for public consumption :)
imaps://news.public-inbox.org/INBOX.comp.mail.public-inbox.meta.0
You can use any username+password, and AUTH=ANONYMOUS also
works if your client does that.
It doesn't support UTF-7 (mailbox names) or advertise UTF-8
in CAPABILITIES, yet; I still have RFCs to read :P
And there's a bunch of new things which could use some
testing from non-mutt/mbsync/offlineimap users.
Maybe you'll find some client-side bugs like I did :P
v1 reindexing also gets a little bit of parallelism :)
Anyways, I'll probably be porting some of the scalability
and slow-storage work to older parts of the code before
fiddling with more IMAP extensions.
Eric Wong (82):
doc: add some IMAP standards
nntpd: restrict allowed newsgroup names
preliminary imap server implementation
inboxidle: new class to detect inbox changes
imap: support IDLE
msgmap: split ->max into its own method
imap: delay InboxIdle start, support refresh
imap: implement STATUS command
imap: use Text::ParseWords::parse_line to handle quoted words
imap: support LIST command
t/imapd: support FakeInotify and KQNotify
imap: support fetch for BODYSTRUCTURE and BODY
eml: each_part: single part $idx is 1
imap: allow fetch of partial of BODY[...] and headers
imap: always include `resp-text' in responses
imap: split out unit tests and benchmarks
imap: fix multi-message partial header fetches
imap: simplify partial fetch structure
imap: support sequence number FETCH
imap: do not include ".PEEK" in responses
imap: support the CLOSE command
imap: speed up HEADER.FIELDS[.NOT] range fetches
git: async: flatten the inflight array
git: do our own read buffering for cat-file
imap: use git-cat-file asynchronously
git: idle rbuf for async
imap: support LSUB command
imap: FETCH: support comma-delimited ranges
add imapd compression test
testcommon: tcp_(server|connect): BAIL_OUT on failure
*deflate: drop invalid comment about rbuf
imap: fix pipelining with async git
git: cat_async: provide requested OID + "missing" on missing blobs
git: move async_cat reference to PublicInbox::Git
git: async: automatic retry on alternates change
imapclient: wrapper for Mail::IMAPClient
xt: add imapd-validate and imapd-mbsync-oimap
imap: support out-of-bounds ranges
xt/perf-imap-list: time refresh_inboxlist
imap: case-insensitive mailbox name comparisons
imap: break giant inboxes into sub-inboxes of 50K messages
imap: start introducing iterative config reloading
imap: require ".$UID_MIN-$UID_END" suffix
imapd: ensure LIST is sorted alphabetically, for now
imap: omit $UID_END from mailbox name, use index
t/config.t: always compare against git bool behavior
xt/*: show some tunable parameters
imap: STATUS and LIST are case-insensitive, too
imap: EXAMINE/STATUS: return correct counts
imap: avoid uninitialized warnings on incomplete commands
imap: start parsing out queries for SQLite and Xapian
imap: SEARCH: clamp results to the 50K UID range
imap: allow UID range search on timestamps
over: get_art: use dbh->prepare_cached
search: index byte size of a message for IMAP search
search: index UID for IMAP search, too
imap: remove dummies from sequence number FETCH
imap: compile UID FETCH to opcodes
imap: UID FETCH: optimize for smsg-only case
imap: UID FETCH: optimize (UID FLAGS) harder
imap: IDLE: avoid extraneous wakeups, keep-alive
imap: 30 minute auto-logout timer
imap: split ->logged_in attribute into a separate class
searchidx: v1 (re)-index uses git asynchronously
index: account for CRLF conversion when storing bytes
imap: rely on smsg->{bytes} for RFC822.SIZE
imap: UID FETCH requires at least one data item
imap: LIST shows "INBOX" in all caps
imap: support 8000 octet lines
imap: reinstate some message sequence number support
imap: cleanup ->{uid_base} usage
imap: FETCH: more granular CRLF conversion
imap: further speed up HEADER.FIELDS FETCH requests
imap: FETCH: try to make fake MSNs sequentially
imap: STATUS/EXAMINE: rely on SQLite overview
imap: UID SEARCH: support multiple ranges
imap: wire up Xapian search, msn SEARCH and multiple ranges
imap: misc cleanups and notes
imapd: don't bother sorting LIST output
imap: drop non-UID SEARCH for now
over: uid_range: remove LIMIT
imap: FETCH: proper MSN => UID mapping for requests
Documentation/public-inbox-imapd.pod | 91 ++
Documentation/standards.perl | 10 +
MANIFEST | 18 +
lib/PublicInbox/Config.pm | 18 +
lib/PublicInbox/Daemon.pm | 24 +-
lib/PublicInbox/DummyInbox.pm | 22 +
lib/PublicInbox/Eml.pm | 9 +-
lib/PublicInbox/FakeInotify.pm | 59 ++
lib/PublicInbox/Git.pm | 163 +--
lib/PublicInbox/GitAsyncCat.pm | 51 +
lib/PublicInbox/IMAP.pm | 1397 ++++++++++++++++++++++++++
lib/PublicInbox/IMAPClient.pm | 119 +++
lib/PublicInbox/IMAPD.pm | 114 +++
lib/PublicInbox/IMAPdeflate.pm | 126 +++
lib/PublicInbox/Import.pm | 2 +-
lib/PublicInbox/In2Tie.pm | 17 +
lib/PublicInbox/Inbox.pm | 33 +-
lib/PublicInbox/InboxIdle.pm | 79 ++
lib/PublicInbox/KQNotify.pm | 66 ++
lib/PublicInbox/Lock.pm | 7 +
lib/PublicInbox/MsgIter.pm | 2 +-
lib/PublicInbox/Msgmap.pm | 20 +-
lib/PublicInbox/NNTPD.pm | 12 +-
lib/PublicInbox/NNTPdeflate.pm | 1 -
lib/PublicInbox/Over.pm | 50 +-
lib/PublicInbox/Search.pm | 32 +-
lib/PublicInbox/SearchIdx.pm | 89 +-
lib/PublicInbox/SearchIdxShard.pm | 11 +-
lib/PublicInbox/Smsg.pm | 8 +-
lib/PublicInbox/TestCommon.pm | 7 +-
lib/PublicInbox/V2Writable.pm | 10 +-
script/public-inbox-imapd | 14 +
t/config.t | 15 +-
t/eml.t | 2 +-
t/git.t | 40 +-
t/imap.t | 133 +++
t/imapd-tls.t | 204 ++++
t/imapd.t | 398 ++++++++
t/import.t | 5 +-
t/inbox_idle.t | 72 ++
t/nntpd.t | 5 +-
t/over.t | 3 +
t/search.t | 19 +
xt/cmp-msgstr.t | 1 -
xt/cmp-msgview.t | 1 -
xt/eml_check_limits.t | 6 +-
xt/git_async_cmp.t | 2 +-
xt/imapd-mbsync-oimap.t | 132 +++
xt/imapd-validate.t | 177 ++++
xt/mem-msgview.t | 1 +
xt/msgtime_cmp.t | 1 -
xt/perf-msgview.t | 1 -
52 files changed, 3718 insertions(+), 181 deletions(-)
create mode 100644 Documentation/public-inbox-imapd.pod
create mode 100644 lib/PublicInbox/DummyInbox.pm
create mode 100644 lib/PublicInbox/FakeInotify.pm
create mode 100644 lib/PublicInbox/GitAsyncCat.pm
create mode 100644 lib/PublicInbox/IMAP.pm
create mode 100644 lib/PublicInbox/IMAPClient.pm
create mode 100644 lib/PublicInbox/IMAPD.pm
create mode 100644 lib/PublicInbox/IMAPdeflate.pm
create mode 100644 lib/PublicInbox/In2Tie.pm
create mode 100644 lib/PublicInbox/InboxIdle.pm
create mode 100644 lib/PublicInbox/KQNotify.pm
create mode 100644 script/public-inbox-imapd
create mode 100644 t/imap.t
create mode 100644 t/imapd-tls.t
create mode 100644 t/imapd.t
create mode 100644 t/inbox_idle.t
create mode 100644 xt/imapd-mbsync-oimap.t
create mode 100644 xt/imapd-validate.t
^ permalink raw reply [relevance 7%]
Results 1-2 of 2 | reverse | options above
-- pct% links below jump to the message on this page, permalinks otherwise --
2020-06-10 7:03 7% [PATCH 00/82] public-inbox-imapd: read-only IMAP server Eric Wong
2020-06-10 7:04 5% ` [PATCH 14/82] imap: allow fetch of partial of BODY[...] and headers Eric Wong
Code repositories for project(s) associated with this public inbox
https://80x24.org/public-inbox.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).