user/dev discussion of public-inbox itself
 help / color / mirror / code / Atom feed
9566d23461bb71e67e967742e375133c51cd5cbf blob 5856 bytes (raw)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
 
# Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>

# Internal interface for a single Xapian shard in V2 inboxes.
# See L<public-inbox-v2-format(5)> for more info on how we shard Xapian
package PublicInbox::SearchIdxShard;
use strict;
use v5.10.1;
use parent qw(PublicInbox::SearchIdx);
use bytes qw(length);
use IO::Handle (); # autoflush
use PublicInbox::Eml;

sub new {
	my ($class, $v2w, $shard) = @_; # v2w may be ExtSearchIdx
	my $ibx = $v2w->{ibx};
	my $self = $ibx ? $class->SUPER::new($ibx, 1, $shard)
			: $class->eidx_shard_new($v2w, $shard);
	# create the DB before forking:
	$self->idx_acquire;
	$self->set_metadata_once;
	$self->idx_release;
	$self->spawn_worker($v2w, $shard) if $v2w->{parallel};
	$self;
}

sub spawn_worker {
	my ($self, $v2w, $shard) = @_;
	my ($r, $w);
	pipe($r, $w) or die "pipe failed: $!\n";
	$w->autoflush(1);
	my $pid = fork;
	defined $pid or die "fork failed: $!\n";
	if ($pid == 0) {
		my $bnote = $v2w->atfork_child;
		close $w or die "failed to close: $!";

		# F_SETPIPE_SZ = 1031 on Linux; increasing the pipe size here
		# speeds V2Writable batch imports across 8 cores by nearly 20%
		fcntl($r, 1031, 1048576) if $^O eq 'linux';

		eval { shard_worker_loop($self, $v2w, $r, $shard, $bnote) };
		die "worker $shard died: $@\n" if $@;
		die "unexpected MM $self->{mm}" if $self->{mm};
		exit;
	}
	$self->{pid} = $pid;
	$self->{w} = $w;
	close $r or die "failed to close: $!";
}

sub eml ($$) {
	my ($r, $len) = @_;
	my $n = read($r, my $bref, $len) or die "read: $!\n";
	$n == $len or die "short read: $n != $len\n";
	PublicInbox::Eml->new(\$bref);
}

# this reads all the writes to $self->{w} from the parent process
sub shard_worker_loop ($$$$$) {
	my ($self, $v2w, $r, $shard, $bnote) = @_;
	$0 = "shard[$shard]";
	$self->begin_txn_lazy;
	while (my $line = readline($r)) {
		$v2w->{current_info} = "[$shard] $line";
		if ($line eq "commit\n") {
			$self->commit_txn_lazy;
		} elsif ($line eq "close\n") {
			$self->idx_release;
		} elsif ($line eq "barrier\n") {
			$self->commit_txn_lazy;
			# no need to lock < 512 bytes is atomic under POSIX
			print $bnote "barrier $shard\n" or
					die "write failed for barrier $!\n";
		} elsif ($line =~ /\AD ([a-f0-9]{40,}) ([0-9]+)\n\z/s) {
			$self->remove_by_oid($1, $2 + 0);
		} elsif ($line =~ s/\A\+X //) {
			my ($len, $docid, $oid, $eidx_key) =
							split(/ /, $line, 4);
			$self->add_eidx_info($docid, $oid, $eidx_key,
							eml($r, $len));
		} elsif ($line =~ s/\A-X //) {
			my ($len, $docid, $oid, $eidx_key) =
							split(/ /, $line, 4);
			$self->remove_eidx_info($docid, $oid, $eidx_key,
							eml($r, $len));
		} else {
			chomp $line;
			my $eidx_key;
			if ($line =~ s/\AX=(.+)\0//) {
				$eidx_key = $1;
				$v2w->{current_info} =~ s/\0/\\0/;
			}
			# n.b. $mid may contain spaces(!)
			my ($len, $bytes, $num, $oid, $ds, $ts, $tid, $mid)
				= split(/ /, $line, 8);
			$self->begin_txn_lazy;
			my $smsg = bless {
				bytes => $bytes,
				num => $num + 0,
				blob => $oid,
				mid => $mid,
				tid => $tid,
				ds => $ds,
				ts => $ts,
			}, 'PublicInbox::Smsg';
			$smsg->{eidx_key} = $eidx_key if defined($eidx_key);
			$self->add_message(eml($r, $len), $smsg);
		}
	}
	$self->worker_done;
}

sub index_raw {
	my ($self, $msgref, $eml, $smsg, $ibx) = @_;
	if (my $w = $self->{w}) {
		my @ekey = $ibx ? ('X='.$ibx->eidx_key."\0") : ();
		$msgref //= \($eml->as_string);
		$smsg->{raw_bytes} //= length($$msgref);
		# mid must be last, it can contain spaces (but not LF)
		print $w @ekey, join(' ', @$smsg{qw(raw_bytes bytes
						num blob ds ts tid mid)}),
			"\n", $$msgref or die "failed to write shard $!\n";
	} else {
		if ($eml) {
			undef($$msgref) if $msgref;
		} else { # --xapian-only + --sequential-shard:
			$eml = PublicInbox::Eml->new($msgref);
		}
		$self->begin_txn_lazy;
		$smsg->{eidx_key} = $ibx->eidx_key if $ibx;
		$self->add_message($eml, $smsg);
	}
}

sub shard_add_eidx_info {
	my ($self, $docid, $oid, $xibx, $eml) = @_;
	my $eidx_key = $xibx->eidx_key;
	if (my $w = $self->{w}) {
		my $hdr = $eml->header_obj->as_string;
		my $len = length($hdr);
		print $w "+X $len $docid $oid $eidx_key\n", $hdr or
			die "failed to write shard: $!";
	} else {
		$self->add_eidx_info($docid, $oid, $eidx_key, $eml);
	}
}

sub shard_remove_eidx_info {
	my ($self, $docid, $oid, $xibx, $eml) = @_;
	my $eidx_key = $xibx->eidx_key;
	if (my $w = $self->{w}) {
		my $hdr = $eml->header_obj->as_string;
		my $len = length($hdr);
		print $w "-X $len $docid $oid $eidx_key\n", $hdr or
			die "failed to write shard: $!";
	} else {
		$self->remove_eidx_info($docid, $oid, $eidx_key, $eml);
	}
}

sub atfork_child {
	close $_[0]->{w} or die "failed to close write pipe: $!\n";
}

sub shard_barrier {
	my ($self) = @_;
	if (my $w = $self->{w}) {
		print $w "barrier\n" or die "failed to print: $!";
	} else {
		$self->commit_txn_lazy;
	}
}

sub shard_commit {
	my ($self) = @_;
	if (my $w = $self->{w}) {
		print $w "commit\n" or die "failed to write commit: $!";
	} else {
		$self->commit_txn_lazy;
	}
}

sub shard_close {
	my ($self) = @_;
	if (my $w = delete $self->{w}) {
		my $pid = delete $self->{pid} or die "no process to wait on\n";
		print $w "close\n" or die "failed to write to pid:$pid: $!\n";
		close $w or die "failed to close pipe for pid:$pid: $!\n";
		waitpid($pid, 0) == $pid or die "remote process did not finish";
		$? == 0 or die ref($self)." pid:$pid exited with: $?";
	} else {
		die "transaction in progress $self\n" if $self->{txn};
		$self->idx_release if $self->{xdb};
	}
}

sub shard_remove {
	my ($self, $oid, $num) = @_;
	if (my $w = $self->{w}) { # triggers remove_by_oid in a shard child
		print $w "D $oid $num\n" or die "failed to write remove $!";
	} else { # same process
		$self->remove_by_oid($oid, $num);
	}
}

1;
debug log:

solving 9566d234 ...
found 9566d234 in https://80x24.org/public-inbox.git

Code repositories for project(s) associated with this inbox:

	https://80x24.org/public-inbox.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).