user/dev discussion of public-inbox itself
 help / color / mirror / code / Atom feed
8a54c608d7e1a87fa34c58e53822ca8bb1d8114f blob 1430 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
 
# Copyright (C) 2020 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
#
# internal class used by PublicInbox::Git + PublicInbox::DS
# This parses the output pipe of "git cat-file --batch"
#
# Note: this does NOT set the non-blocking flag, we expect `git cat-file'
# to be a local process, and git won't start writing a blob until it's
# fully read.  So minimize context switching and read as much as possible
# and avoid holding a buffer in our heap any longer than it has to live.
package PublicInbox::GitAsyncCat;
use strict;
use parent qw(PublicInbox::DS Exporter);
use PublicInbox::Syscall qw(EPOLLIN EPOLLET);
our @EXPORT = qw(git_async_cat);

sub event_step {
	my ($self) = @_;
	my $gitish = $self->{gitish};
	return $self->close if ($gitish->{in} // 0) != ($self->{sock} // 1);
	my $inflight = $gitish->{inflight};
	if ($inflight && @$inflight) {
		$gitish->cat_async_step($inflight);
		$self->requeue if @$inflight || exists $gitish->{cat_rbuf};
	}
}

sub git_async_cat ($$$$) {
	my ($git, $oid, $cb, $arg) = @_;
	my $gitish = $git->{gcf2c}; # PublicInbox::Gcf2Client
	if ($gitish) {
		$oid .= " $git->{git_dir}";
	} else {
		$gitish = $git;
	}
	$gitish->cat_async($oid, $cb, $arg);
	$gitish->{async_cat} //= do {
		my $self = bless { gitish => $gitish }, __PACKAGE__;
		$self->SUPER::new($gitish->{in}, EPOLLIN|EPOLLET);
		\undef; # this is a true ref()
	};
}

1;
debug log:

solving 8a54c608 ...
found 8a54c608 in https://80x24.org/public-inbox.git

Code repositories for project(s) associated with this inbox:

	https://80x24.org/public-inbox.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).