user/dev discussion of public-inbox itself
 help / color / mirror / code / Atom feed
5d8e78ea78635211885271cb650f1ed48d76696e blob 2112 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
 
# Copyright (C) 2021 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>

# op dispatch socket, reads a message, runs a sub
# There may be multiple producers, but (for now) only one consumer
# Used for lei_xsearch and maybe other things
# "command" => [ $sub, @fixed_operands ]
package PublicInbox::PktOp;
use strict;
use v5.10.1;
use parent qw(PublicInbox::DS Exporter);
use Errno qw(EAGAIN EINTR);
use PublicInbox::Syscall qw(EPOLLIN EPOLLET);
use Socket qw(AF_UNIX MSG_EOR SOCK_SEQPACKET);
use PublicInbox::IPC qw(ipc_freeze ipc_thaw);
our @EXPORT_OK = qw(pkt_do);

sub new {
	my ($cls, $r, $ops) = @_;
	my $self = bless { sock => $r, ops => $ops }, $cls;
	if ($PublicInbox::DS::in_loop) { # iff using DS->EventLoop
		$r->blocking(0);
		$self->SUPER::new($r, EPOLLIN|EPOLLET);
	}
	$self;
}

# returns a blessed object as the consumer, and a GLOB/IO for the producer
sub pair {
	my ($cls, $ops) = @_;
	my ($c, $p);
	socketpair($c, $p, AF_UNIX, SOCK_SEQPACKET, 0) or die "socketpair: $!";
	(new($cls, $c, $ops), $p);
}

sub pkt_do { # for the producer to trigger event_step in consumer
	my ($producer, $cmd, @args) = @_;
	send($producer, @args ? "$cmd\0".ipc_freeze(\@args) : $cmd, MSG_EOR);
}

sub close {
	my ($self) = @_;
	my $c = $self->{sock} or return;
	$c->blocking ? delete($self->{sock}) : $self->SUPER::close;
}

sub event_step {
	my ($self) = @_;
	my $c = $self->{sock};
	my $msg;
	while (1) {
		my $n = recv($c, $msg, 4096, 0);
		unless (defined $n) {
			return if $! == EAGAIN;
			next if $! == EINTR;
			$self->close;
			die "recv: $!";
		}
		my ($cmd, @pargs);
		if (index($msg, "\0") > 0) {
			($cmd, my $pargs) = split(/\0/, $msg, 2);
			@pargs = @{ipc_thaw($pargs)};
		} else {
			# for compatibility with the script/lei in client mode,
			# it doesn't load Sereal||Storable for startup speed
			($cmd, @pargs) = split(/ /, $msg);
		}
		my $op = $self->{ops}->{$cmd //= $msg};
		die "BUG: unknown message: `$cmd'" unless $op;
		my ($sub, @args) = @$op;
		$sub->(@args, @pargs);
		return $self->close if $msg eq ''; # close on EOF
	}
}

1;
debug log:

solving 5d8e78ea ...
found 5d8e78ea in public-inbox.git

user/dev discussion of public-inbox itself

This inbox may be cloned and mirrored by anyone:

	git clone --mirror https://public-inbox.org/meta
	git clone --mirror http://czquwvybam4bgbro.onion/meta
	git clone --mirror http://hjrcffqmbrq6wope.onion/meta
	git clone --mirror http://ou63pmih66umazou.onion/meta

	# If you have public-inbox 1.1+ installed, you may
	# initialize and index your mirror using the following commands:
	public-inbox-init -V1 meta meta/ https://public-inbox.org/meta \
		meta@public-inbox.org
	public-inbox-index meta

Example config snippet for mirrors.
Newsgroups are available over NNTP:
	nntp://news.public-inbox.org/inbox.comp.mail.public-inbox.meta
	nntp://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/inbox.comp.mail.public-inbox.meta
	nntp://ie5yzdi7fg72h7s4sdcztq5evakq23rdt33mfyfcddc5u3ndnw24ogqd.onion/inbox.comp.mail.public-inbox.meta
	nntp://4uok3hntl7oi7b4uf4rtfwefqeexfzil2w6kgk2jn5z2f764irre7byd.onion/inbox.comp.mail.public-inbox.meta
	nntp://news.gmane.io/gmane.mail.public-inbox.general
 note: .onion URLs require Tor: https://www.torproject.org/

code repositories for project(s) associated with this inbox:

	https://80x24.org/public-inbox.git

AGPL code for this site: git clone https://public-inbox.org/public-inbox.git