user/dev discussion of public-inbox itself
 help / color / Atom feed
51d81a0a21560ef73cac1776f5176f8a29df16e0 blob 3300 bytes (raw)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
 
# Copyright (C) 2018 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>

# used to interface with a single Xapian partition in V2 repos.
# See L<public-inbox-v2-format(5)> for more info on how we partition Xapian
package PublicInbox::SearchIdxPart;
use strict;
use warnings;
use base qw(PublicInbox::SearchIdx);

sub new {
	my ($class, $v2writable, $part) = @_;
	my $self = $class->SUPER::new($v2writable->{-inbox}, 1, $part);
	# create the DB before forking:
	$self->_xdb_acquire;
	$self->_xdb_release;
	$self->spawn_worker($v2writable, $part) if $v2writable->{parallel};
	$self;
}

sub spawn_worker {
	my ($self, $v2writable, $part) = @_;
	my ($r, $w);
	pipe($r, $w) or die "pipe failed: $!\n";
	binmode $r, ':raw';
	binmode $w, ':raw';
	my $pid = fork;
	defined $pid or die "fork failed: $!\n";
	if ($pid == 0) {
		my $bnote = $v2writable->atfork_child;
		$v2writable = undef;
		close $w or die "failed to close: $!";

		# F_SETPIPE_SZ = 1031 on Linux; increasing the pipe size here
		# speeds V2Writable batch imports across 8 cores by nearly 20%
		fcntl($r, 1031, 1048576) if $^O eq 'linux';

		eval { partition_worker_loop($self, $r, $part, $bnote) };
		die "worker $part died: $@\n" if $@;
		die "unexpected MM $self->{mm}" if $self->{mm};
		exit;
	}
	$self->{pid} = $pid;
	$self->{w} = $w;
	close $r or die "failed to close: $!";
}

sub partition_worker_loop ($$$$) {
	my ($self, $r, $part, $bnote) = @_;
	$0 = "pi-v2-partition[$part]";
	my $current_info = '';
	my $warn_cb = $SIG{__WARN__} || sub { print STDERR @_ };
	local $SIG{__WARN__} = sub {
		chomp $current_info;
		$warn_cb->("[$part] $current_info: ", @_);
	};
	$self->begin_txn_lazy;
	while (my $line = $r->getline) {
		$current_info = $line;
		if ($line eq "commit\n") {
			$self->commit_txn_lazy;
		} elsif ($line eq "close\n") {
			$self->_xdb_release;
		} elsif ($line eq "barrier\n") {
			$self->commit_txn_lazy;
			# no need to lock < 512 bytes is atomic under POSIX
			print $bnote "barrier $part\n" or
					die "write failed for barrier $!\n";
		} elsif ($line =~ /\AD ([a-f0-9]{40,}) (.+)\n\z/s) {
			my ($oid, $mid) = ($1, $2);
			$self->begin_txn_lazy;
			$self->remove_by_oid($oid, $mid);
		} else {
			chomp $line;
			my ($len, $artnum, $oid, $mid0) = split(/ /, $line);
			$self->begin_txn_lazy;
			my $n = read($r, my $msg, $len) or die "read: $!\n";
			$n == $len or die "short read: $n != $len\n";
			my $mime = PublicInbox::MIME->new(\$msg);
			$artnum = int($artnum);
			$self->add_message($mime, $n, $artnum, $oid, $mid0);
		}
	}
	$self->worker_done;
}

# called by V2Writable
sub index_raw {
	my ($self, $bytes, $msgref, $artnum, $oid, $mid0, $mime) = @_;
	if (my $w = $self->{w}) {
		print $w "$bytes $artnum $oid $mid0\n", $$msgref or die
			"failed to write partition $!\n";
		$w->flush or die "failed to flush: $!\n";
	} else {
		$$msgref = undef;
		$self->begin_txn_lazy;
		$self->add_message($mime, $bytes, $artnum, $oid, $mid0);
	}
}

sub atfork_child {
	close $_[0]->{w} or die "failed to close write pipe: $!\n";
}

# called by V2Writable:
sub remote_barrier {
	my ($self) = @_;
	if (my $w = $self->{w}) {
		print $w "barrier\n" or die "failed to print: $!";
		$w->flush or die "failed to flush: $!";
	} else {
		$self->commit_txn_lazy;
	}
}

1;
debug log:

solving 51d81a0 ...
found 51d81a0 in https://80x24.org/public-inbox.git

user/dev discussion of public-inbox itself

Archives are clonable:
	git clone --mirror https://public-inbox.org/meta
	git clone --mirror http://czquwvybam4bgbro.onion/meta
	git clone --mirror http://hjrcffqmbrq6wope.onion/meta
	git clone --mirror http://ou63pmih66umazou.onion/meta

Newsgroups are available over NNTP:
	nntp://news.public-inbox.org/inbox.comp.mail.public-inbox.meta
	nntp://ou63pmih66umazou.onion/inbox.comp.mail.public-inbox.meta
	nntp://czquwvybam4bgbro.onion/inbox.comp.mail.public-inbox.meta
	nntp://hjrcffqmbrq6wope.onion/inbox.comp.mail.public-inbox.meta
	nntp://news.gmane.org/gmane.mail.public-inbox.general

 note: .onion URLs require Tor: https://www.torproject.org/

AGPL code for this site: git clone https://public-inbox.org/ public-inbox