user/dev discussion of public-inbox itself
 help / color / mirror / code / Atom feed
50ab4c8515288357cf223f5306076d8f2cd61109 blob 9375 bytes (raw)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
 
# Copyright (C) 2021 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>

# "lei add-external --mirror" support
package PublicInbox::LeiMirror;
use strict;
use v5.10.1;
use parent qw(PublicInbox::IPC);
use IO::Uncompress::Gunzip qw(gunzip $GunzipError);
use PublicInbox::Spawn qw(popen_rd spawn);

sub do_finish_mirror { # dwaitpid callback
	my ($arg, $pid) = @_;
	my ($mrr, $lei) = @$arg;
	my $f = "$mrr->{dst}/mirror.done";
	if ($?) {
		$lei->child_error($?);
	} elsif (!unlink($f)) {
		$lei->err("unlink($f): $!");
	} else {
		$lei->add_external_finish($mrr->{dst});
		$lei->qerr("# mirrored $mrr->{src} => $mrr->{dst}");
	}
	$lei->dclose;
}

sub _lei_wq_eof { # EOF callback for main daemon
	my ($lei) = @_;
	my $mrr = delete $lei->{mrr} or return;
	$mrr->wq_wait_old(\&do_finish_mirror, $lei);
}

# for old installations without manifest.js.gz
sub try_scrape {
	my ($self) = @_;
	my $uri = URI->new($self->{src});
	my $lei = $self->{lei};
	my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
	my $cmd = $curl->for_uri($lei, $uri, '--compressed');
	my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
	my $fh = popen_rd($cmd, undef, $opt);
	my $html = do { local $/; <$fh> } // die "read(curl $uri): $!";
	close($fh) or return $lei->child_error($?, "@$cmd failed");

	# we grep with URL below, we don't want Subject/From headers
	# making us clone random URLs
	my @urls = ($html =~ m!\bgit clone --mirror ([a-z\+]+://\S+)!g);
	my $url = $uri->as_string;
	chop($url) eq '/' or die "BUG: $uri not canonicalized";

	# since this is for old instances w/o manifest.js.gz, try v1 first
	return clone_v1($self) if grep(m!\A\Q$url\E/*\z!, @urls);
	if (my @v2_urls = grep(m!\A\Q$url\E/[0-9]+\z!, @urls)) {
		my %v2_uris = map { $_ => URI->new($_) } @v2_urls; # uniq
		return clone_v2($self, [ values %v2_uris ]);
	}

	# filter out common URLs served by WWW (e.g /$MSGID/T/)
	if (@urls && $url =~ s!/+[^/]+\@[^/]+/.*\z!! &&
			grep(m!\A\Q$url\E/*\z!, @urls)) {
		die <<"";
E: confused by scraping <$uri>, did you mean <$url>?

	}
	@urls and die <<"";
E: confused by scraping <$uri>, got ambiguous results:
@urls

	die "E: scraping <$uri> revealed nothing\n";
}

sub clone_cmd {
	my ($lei, $opt) = @_;
	my @cmd = qw(git);
	$opt->{$_} = $lei->{$_} for (0..2);
	# we support "-c $key=$val" for arbitrary git config options
	# e.g.: git -c http.proxy=socks5h://127.0.0.1:9050
	push(@cmd, '-c', $_) for @{$lei->{opt}->{c} // []};
	push @cmd, qw(clone --mirror);
	push @cmd, '-q' if $lei->{opt}->{quiet};
	push @cmd, '-v' if $lei->{opt}->{verbose};
	# XXX any other options to support?
	# --reference is tricky with multiple epochs...
	@cmd;
}

# tries the relatively new /$INBOX/_/text/config/raw endpoint
sub _try_config {
	my ($self) = @_;
	my $dst = $self->{dst};
	if (!-d $dst || !mkdir($dst)) {
		require File::Path;
		File::Path::mkpath($dst);
		-d $dst or die "mkpath($dst): $!\n";
	}
	my $uri = URI->new($self->{src});
	my $lei = $self->{lei};
	my $path = $uri->path;
	chop($path) eq '/' or die "BUG: $uri not canonicalized";
	$uri->path($path . '/_/text/config/raw');
	my $cmd = $self->{curl}->for_uri($lei, $uri, '--compressed');
	my $ce = "$dst/inbox.config.example";
	my $f = "$ce-$$.tmp";
	open(my $fh, '+>', $f) or return $lei->err("open $f: $! (non-fatal)");
	my $opt = { 0 => $lei->{0}, 1 => $fh, 2 => $lei->{2} };
	my $cerr = run_reap($lei, $cmd, $opt) // return;
	if (($cerr >> 8) == 22) { # 404 missing
		unlink($f) if -s $fh == 0;
		return;
	}
	return $lei->err("# @$cmd failed (non-fatal)") if $cerr;
	rename($f, $ce) or return $lei->err("link($f, $ce): $! (non-fatal)");
	my $cfg = PublicInbox::Config->git_config_dump($f);
	my $ibx = $self->{ibx} = {};
	for my $sec (grep(/\Apublicinbox\./, @{$cfg->{-section_order}})) {
		for (qw(address newsgroup nntpmirror)) {
			$ibx->{$_} = $cfg->{"$sec.$_"};
		}
	}
}

sub index_cloned_inbox {
	my ($self, $iv) = @_;
	my $ibx = delete($self->{ibx}) // {
		address => [ 'lei@example.com' ],
		version => $iv,
	};
	$ibx->{inboxdir} = $self->{dst};
	PublicInbox::Inbox->new($ibx);
	PublicInbox::InboxWritable->new($ibx);
	my $opt = {};
	my $lei = $self->{lei};
	for my $sw ($lei->index_opt) {
		my ($k) = ($sw =~ /\A([\w-]+)/);
		$opt->{$k} = $lei->{opt}->{$k};
	}
	# force synchronous dwaitpid for v2:
	local $PublicInbox::DS::in_loop = 0;
	my $cfg = PublicInbox::Config->new;
	my $env = PublicInbox::Admin::index_prepare($opt, $cfg);
	local %ENV = (%ENV, %$env) if $env;
	PublicInbox::Admin::progress_prepare($opt, $lei->{2});
	PublicInbox::Admin::index_inbox($ibx, undef, $opt);
	open my $x, '>', "$self->{dst}/mirror.done"; # for do_finish_mirror
}

sub run_reap {
	my ($lei, $cmd, $opt) = @_;
	$lei->qerr("# @$cmd");
	$opt->{pgid} = 0;
	my $pid = spawn($cmd, undef, $opt);
	my $reap = PublicInbox::OnDestroy->new($lei->can('sigint_reap'), $pid);
	my $err = waitpid($pid, 0) == $pid ? undef : "waitpid @$cmd: $!";
	@$reap = (); # cancel reap
	$err ? $lei->err($err) : $?
}

sub clone_v1 {
	my ($self) = @_;
	my $lei = $self->{lei};
	my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
	my $uri = URI->new($self->{src});
	my $pfx = $curl->torsocks($lei, $uri) or return;
	my $cmd = [ @$pfx, clone_cmd($lei, my $opt = {}),
			$uri->as_string, $self->{dst} ];
	my $cerr = run_reap($lei, $cmd, $opt) // return;
	return $lei->child_error($cerr, "@$cmd failed") if $cerr;
	_try_config($self);
	index_cloned_inbox($self, 1);
}

sub clone_v2 {
	my ($self, $v2_uris) = @_;
	my $lei = $self->{lei};
	my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
	my $pfx //= $curl->torsocks($lei, $v2_uris->[0]) or return;
	my @epochs;
	my $dst = $self->{dst};
	my @src_edst;
	for my $uri (@$v2_uris) {
		my $src = $uri->as_string;
		my $edst = $dst;
		$src =~ m!/([0-9]+)(?:\.git)?\z! or die <<"";
failed to extract epoch number from $src

		my $nr = $1 + 0;
		$edst .= "/git/$nr.git";
		push @src_edst, [ $src, $edst ];
	}
	my $lk = bless { lock_path => "$dst/inbox.lock" }, 'PublicInbox::Lock';
	_try_config($self);
	my $on_destroy = $lk->lock_for_scope($$);
	my @cmd = clone_cmd($lei, my $opt = {});
	while (my $pair = shift(@src_edst)) {
		my $cmd = [ @$pfx, @cmd, @$pair ];
		my $cerr = run_reap($lei, $cmd, $opt) // return;
		return $lei->child_error($cerr, "@$cmd failed") if $cerr;
	}
	undef $on_destroy; # unlock
	index_cloned_inbox($self, 2);
}

sub try_manifest {
	my ($self) = @_;
	my $uri = URI->new($self->{src});
	my $lei = $self->{lei};
	my $curl = $self->{curl} //= PublicInbox::LeiCurl->new($lei) or return;
	my $path = $uri->path;
	chop($path) eq '/' or die "BUG: $uri not canonicalized";
	$uri->path($path . '/manifest.js.gz');
	my $cmd = $curl->for_uri($lei, $uri);
	$lei->qerr("# @$cmd");
	my $opt = { 0 => $lei->{0}, 2 => $lei->{2} };
	my ($fh, $pid) = popen_rd($cmd, undef, $opt);
	my $reap = PublicInbox::OnDestroy->new($lei->can('sigint_reap'), $pid);
	my $gz = do { local $/; <$fh> } // die "read(curl $uri): $!";
	close $fh;
	my $err = waitpid($pid, 0) == $pid ? undef : "waitpid @$cmd: $!";
	@$reap = ();
	return $lei->err($err) if $err;
	if ($?) {
		return try_scrape($self) if ($? >> 8) == 22; # 404 missing
		return $lei->child_error($?, "@$cmd failed");
	}
	my $js;
	gunzip(\$gz => \$js, MultiStream => 1) or
		die "gunzip($uri): $GunzipError";
	my $m = eval { PublicInbox::Config->json->decode($js) };
	die "$uri: error decoding `$js': $@" if $@;
	ref($m) eq 'HASH' or die "$uri unknown type: ".ref($m);

	my $v1_bare = $m->{$path};
	my @v2_epochs = grep(m!\A\Q$path\E/git/[0-9]+\.git\z!, keys %$m);
	if (@v2_epochs) {
		# It may be possible to have v1 + v2 in parallel someday:
		$lei->err(<<EOM) if defined $v1_bare;
# `$v1_bare' appears to be a v1 inbox while v2 epochs exist:
# @v2_epochs
# ignoring $v1_bare (use --inbox-version=1 to force v1 instead)
EOM
		@v2_epochs = map { $uri->path($_); $uri->clone } @v2_epochs;
		clone_v2($self, \@v2_epochs);
	} elsif ($v1_bare) {
		clone_v1($self);
	} elsif (my @maybe = grep(m!\Q$path\E!, keys %$m)) {
		die "E: confused by <$uri>, possible matches:\n@maybe";
	} else {
		die "E: confused by <$uri>";
	}
}

sub start_clone_url {
	my ($self) = @_;
	return try_manifest($self) if $self->{src} =~ m!\Ahttps?://!;
	die "TODO: non-HTTP/HTTPS clone of $self->{src} not supported, yet";
}

sub do_mirror { # via wq_io_do
	my ($self) = @_;
	my $lei = $self->{lei};
	eval {
		my $iv = $lei->{opt}->{'inbox-version'};
		if (defined $iv) {
			return clone_v1($self) if $iv == 1;
			return try_scrape($self) if $iv == 2;
			die "bad --inbox-version=$iv\n";
		}
		return start_clone_url($self) if $self->{src} =~ m!://!;
		die "TODO: cloning local directories not supported, yet";
	};
	$lei->fail($@) if $@;
}

sub start {
	my ($cls, $lei, $src, $dst) = @_;
	my $self = bless { src => $src, dst => $dst }, $cls;
	if ($src =~ m!https?://!) {
		require URI;
		require PublicInbox::LeiCurl;
	}
	require PublicInbox::Lock;
	require PublicInbox::Inbox;
	require PublicInbox::Admin;
	require PublicInbox::InboxWritable;
	my ($op, $ops) = $lei->workers_start($self, 'lei_mirror', 1);
	$lei->{mrr} = $self;
	$self->wq_io_do('do_mirror', []);
	$self->wq_close(1);
	$op->op_wait_event($ops);
}

sub ipc_atfork_child {
	my ($self) = @_;
	$self->{lei}->_lei_atfork_child;
	$SIG{TERM} = sub { exit(128 + 15) }; # trigger OnDestroy $reap
	$self->SUPER::ipc_atfork_child;
}

1;
debug log:

solving 50ab4c85 ...
found 50ab4c85 in public-inbox.git

user/dev discussion of public-inbox itself

This inbox may be cloned and mirrored by anyone:

	git clone --mirror https://public-inbox.org/meta
	git clone --mirror http://czquwvybam4bgbro.onion/meta
	git clone --mirror http://hjrcffqmbrq6wope.onion/meta
	git clone --mirror http://ou63pmih66umazou.onion/meta

	# If you have public-inbox 1.1+ installed, you may
	# initialize and index your mirror using the following commands:
	public-inbox-init -V1 meta meta/ https://public-inbox.org/meta \
		meta@public-inbox.org
	public-inbox-index meta

Example config snippet for mirrors.
Newsgroups are available over NNTP:
	nntp://news.public-inbox.org/inbox.comp.mail.public-inbox.meta
	nntp://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/inbox.comp.mail.public-inbox.meta
	nntp://ie5yzdi7fg72h7s4sdcztq5evakq23rdt33mfyfcddc5u3ndnw24ogqd.onion/inbox.comp.mail.public-inbox.meta
	nntp://4uok3hntl7oi7b4uf4rtfwefqeexfzil2w6kgk2jn5z2f764irre7byd.onion/inbox.comp.mail.public-inbox.meta
	nntp://news.gmane.io/gmane.mail.public-inbox.general
 note: .onion URLs require Tor: https://www.torproject.org/

code repositories for project(s) associated with this inbox:

	https://80x24.org/public-inbox.git

AGPL code for this site: git clone https://public-inbox.org/public-inbox.git