user/dev discussion of public-inbox itself
 help / color / mirror / code / Atom feed
3ce08a6a42ab74b19d6d045bb0650311fa3ebad1 blob 1574 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
 
#!perl -w
# Copyright (C) 2016-2021 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
use strict;
use v5.10.1;
use PublicInbox::TestCommon;
use PublicInbox::Eml;
require_mods(qw(DBD::SQLite Search::Xapian));
use_ok 'PublicInbox::Msgmap';
use_ok 'PublicInbox::SearchIdx';
my ($tmpdir, $for_destroy) = tmpdir();
my $git_dir = "$tmpdir/a.git";
my $alt_file = "$tmpdir/another-nntp.sqlite3";
my $altid = [ "serial:gmane:file=$alt_file" ];
my $ibx;

{
	my $mm = PublicInbox::Msgmap->new_file($alt_file, 2);
	is($mm->mid_set(1234, 'a@example.com'), 1, 'mid_set once OK');
	ok(0 == $mm->mid_set(1234, 'a@example.com'), 'mid_set not idempotent');
	ok(0 == $mm->mid_set(1, 'a@example.com'), 'mid_set fails with dup MID');
}

{
	$ibx = create_inbox 'testbox', tmpdir => $git_dir, sub {
		my ($im) = @_;
		$im->add(PublicInbox::Eml->new(<<'EOF'));
From: a@example.com
To: b@example.com
Subject: boo!
Message-ID: <a@example.com>

hello world gmane:666
EOF
	};
	$ibx->{altid} = $altid;
	PublicInbox::SearchIdx->new($ibx, 1)->index_sync;
}

{
	my $mset = $ibx->search->mset("gmane:1234");
	my $msgs = $ibx->search->mset_to_smsg($ibx, $mset);
	$msgs = [ map { $_->{mid} } @$msgs ];
	is_deeply($msgs, ['a@example.com'], 'got one match');

	$mset = $ibx->search->mset('gmane:666');
	is($mset->size, 0, 'body did NOT match');
};

{
	my $mm = PublicInbox::Msgmap->new_file($alt_file, 2);
	my ($min, $max) = $mm->minmax;
	my $num = $mm->mid_insert('b@example.com');
	ok($num > $max, 'auto-increment goes beyond mid_set');
}
done_testing;
debug log:

solving 3ce08a6a ...
found 3ce08a6a in https://80x24.org/public-inbox.git

Code repositories for project(s) associated with this inbox:

	https://80x24.org/public-inbox.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).