user/dev discussion of public-inbox itself
 help / color / mirror / code / Atom feed
35e059b97cd956b8df20531ed98ad5ab0cb54de0 blob 3082 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
 
#!perl -w
# Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
use strict; use v5.10.1; use PublicInbox::TestCommon;
use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
use PublicInbox::Spawn qw(which);

test_lei({ daemon_only => 1 }, sub {
	my $send_cmd = PublicInbox::Spawn->can('send_cmd4') // do {
		require PublicInbox::CmdIPC4;
		PublicInbox::CmdIPC4->can('send_cmd4');
	};
	$send_cmd or BAIL_OUT 'started testing lei-daemon w/o send_cmd4!';

	my $sock = "$ENV{XDG_RUNTIME_DIR}/lei/5.seq.sock";
	my $err_log = "$ENV{XDG_RUNTIME_DIR}/lei/errors.log";
	lei_ok('daemon-pid');
	is($lei_err, '', 'no error from daemon-pid');
	like($lei_out, qr/\A[0-9]+\n\z/s, 'pid returned') or BAIL_OUT;
	chomp(my $pid = $lei_out);
	ok(kill(0, $pid), 'pid is valid');
	ok(-S $sock, 'sock created');
	is(-s $err_log, 0, 'nothing in errors.log');
	open my $efh, '>>', $err_log or BAIL_OUT $!;
	print $efh "phail\n" or BAIL_OUT $!;
	close $efh or BAIL_OUT $!;

	lei_ok('daemon-pid');
	chomp(my $pid_again = $lei_out);
	is($pid, $pid_again, 'daemon-pid idempotent');
	like($lei_err, qr/phail/, 'got mock "phail" error previous run');

	SKIP: {
		skip 'only testing open files on Linux', 1 if $^O ne 'linux';
		my $d = "/proc/$pid/fd";
		skip "no $d on Linux" unless -d $d;
		my @before = sort(glob("$d/*"));
		my $addr = pack_sockaddr_un($sock);
		open my $null, '<', '/dev/null' or BAIL_OUT "/dev/null: $!";
		my @fds = map { fileno($null) } (0..2);
		for (0..10) {
			socket(my $c, AF_UNIX, SOCK_SEQPACKET, 0) or
							BAIL_OUT "socket: $!";
			connect($c, $addr) or BAIL_OUT "connect: $!";
			$send_cmd->($c, \@fds, 'hi',  MSG_EOR);
		}
		lei_ok('daemon-pid');
		chomp($pid = $lei_out);
		is($pid, $pid_again, 'pid unchanged after failed reqs');
		my @after = sort(glob("$d/*"));
		is_deeply(\@before, \@after, 'open files unchanged') or
			diag explain([\@before, \@after]);;
	}
	lei_ok(qw(daemon-kill));
	is($lei_out, '', 'no output from daemon-kill');
	is($lei_err, '', 'no error from daemon-kill');
	for (0..100) {
		kill(0, $pid) or last;
		tick();
	}
	ok(-S $sock, 'sock still exists');
	ok(!kill(0, $pid), 'pid gone after stop');

	lei_ok(qw(daemon-pid));
	chomp(my $new_pid = $lei_out);
	ok(kill(0, $new_pid), 'new pid is running');
	ok(-S $sock, 'sock still exists');

	for my $sig (qw(-0 -CHLD)) {
		lei_ok('daemon-kill', $sig, \"handles $sig");
	}
	is($lei_out.$lei_err, '', 'no output on innocuous signals');
	lei_ok('daemon-pid');
	chomp $lei_out;
	is($lei_out, $new_pid, 'PID unchanged after -0/-CHLD');

	if ('socket inaccessible') {
		chmod 0000, $sock or BAIL_OUT "chmod 0000: $!";
		lei_ok('help', \'connect fail, one-shot fallback works');
		like($lei_err, qr/\bconnect\(/, 'connect error noted');
		like($lei_out, qr/^usage: /, 'help output works');
		chmod 0700, $sock or BAIL_OUT "chmod 0700: $!";
	}
	unlink $sock or BAIL_OUT "unlink($sock) $!";
	for (0..100) {
		kill('CHLD', $new_pid) or last;
		tick();
	}
	ok(!kill(0, $new_pid), 'daemon exits after unlink');
});

done_testing;
debug log:

solving 35e059b9 ...
found 35e059b9 in https://80x24.org/public-inbox.git

Code repositories for project(s) associated with this inbox:

	https://80x24.org/public-inbox.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).