user/dev discussion of public-inbox itself
 help / color / mirror / code / Atom feed
295a8aa5ebc6952a1979cf50e610ced51bf25394 blob 1036 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
 
# Copyright (C) 2021 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>

# bytecode dispatch pipe, reads a byte, runs a sub
# byte => [ sub, @operands ]
package PublicInbox::OpPipe;
use strict;
use v5.10.1;
use parent qw(PublicInbox::DS);
use PublicInbox::Syscall qw(EPOLLIN);

sub new {
	my ($cls, $rd, $op_map, $in_loop) = @_;
	my $self = bless { sock => $rd, op_map => $op_map }, $cls;
	# 1031: F_SETPIPE_SZ, 4096: page size
	fcntl($rd, 1031, 4096) if $^O eq 'linux';
	if ($in_loop) { # iff using DS->EventLoop
		$rd->blocking(0);
		$self->SUPER::new($rd, EPOLLIN);
	}
	$self;
}

sub event_step {
	my ($self) = @_;
	my $rd = $self->{sock};
	my $byte;
	until (defined(sysread($rd, $byte, 1))) {
		return if $!{EAGAIN};
		next if $!{EINTR};
		die "read \$rd: $!";
	}
	my $op = $self->{op_map}->{$byte} or die "BUG: unknown byte `$byte'";
	if ($byte eq '') { # close on EOF
		$rd->blocking ? delete($self->{sock}) : $self->close;
	}
	my ($sub, @args) = @$op;
	$sub->(@args);
}

1;
debug log:

solving 295a8aa5 ...
found 295a8aa5 in https://80x24.org/public-inbox.git

Code repositories for project(s) associated with this inbox:

	https://80x24.org/public-inbox.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).