From: Eric Wong <e@80x24.org>
To: meta@public-inbox.org
Subject: [PATCH 07/36] lei_to_mail: start atomic and compressed mbox writing
Date: Thu, 31 Dec 2020 13:51:25 +0000 [thread overview]
Message-ID: <20201231135154.6070-8-e@80x24.org> (raw)
In-Reply-To: <20201231135154.6070-1-e@80x24.org>
We'll allow using multiple workers to write to a single
mbox (which could be compressed). This is can be done
safely with O_APPEND + syswrite for uncompressed files,
and using a lock when piping to pigz/gzip/bzip2/xz.
---
lib/PublicInbox/LeiToMail.pm | 99 ++++++++++++++++++++++++++++++++--
lib/PublicInbox/ProcessPipe.pm | 21 ++++++--
t/lei_to_mail.t | 47 ++++++++++++++++
3 files changed, 158 insertions(+), 9 deletions(-)
diff --git a/lib/PublicInbox/LeiToMail.pm b/lib/PublicInbox/LeiToMail.pm
index b0d4b664..ebb50c50 100644
--- a/lib/PublicInbox/LeiToMail.pm
+++ b/lib/PublicInbox/LeiToMail.pm
@@ -6,6 +6,12 @@ package PublicInbox::LeiToMail;
use strict;
use v5.10.1;
use PublicInbox::Eml;
+use PublicInbox::Lock;
+use PublicInbox::ProcessPipe;
+use PublicInbox::Spawn qw(which spawn);
+use Symbol qw(gensym);
+use File::Temp ();
+use IO::Handle; # ->autoflush
my %kw2char = ( # Maildir characters
draft => 'D',
@@ -45,10 +51,14 @@ sub _mbox_hdr_buf ($$$) {
$buf;
}
-sub write_in_full_atomic ($$) {
- my ($fh, $buf) = @_;
- defined(my $w = syswrite($fh, $$buf)) or die "write: $!";
- $w == length($$buf) or die "short write: $w != ".length($$buf);
+sub write_in_full ($$$) {
+ my ($fh, $buf, $atomic) = @_;
+ if ($atomic) {
+ defined(my $w = syswrite($fh, $$buf)) or die "write: $!";
+ $w == length($$buf) or die "short write: $w != ".length($$buf);
+ } else {
+ print $fh $$buf or die "print: $!";
+ }
}
sub eml2mboxrd ($;$) {
@@ -106,4 +116,85 @@ sub eml2mboxcl2 {
$buf;
}
+sub mkmaildir ($) {
+ my ($maildir) = @_;
+ for (qw(new tmp cur)) {
+ my $d = "$maildir/$_";
+ next if -d $d;
+ require File::Path;
+ if (!File::Path::mkpath($d) && !-d $d) {
+ die "failed to mkpath($d): $!\n";
+ }
+ }
+}
+
+sub git_to_mail { # git->cat_async callback
+ my ($bref, $oid, $type, $size, $arg) = @_;
+ if ($type ne 'blob') {
+ if ($type eq 'missing') {
+ warn "missing $oid\n";
+ } else {
+ warn "unexpected type=$type for $oid\n";
+ }
+ }
+ if ($size > 0) {
+ my ($write_cb, $kw) = @$arg;
+ $write_cb->($bref, $oid, $kw);
+ }
+}
+
+sub reap_compress { # dwaitpid callback
+ my ($lei, $pid) = @_;
+ my $cmd = delete $lei->{"pid.$pid"};
+ return if $? == 0;
+ $lei->fail("@$cmd failed", $? >> 8);
+}
+
+sub compress_dst {
+ my ($out, $sfx, $lei) = @_;
+ my $cmd = [];
+ if ($sfx eq 'gz') {
+ $cmd->[0] = which($lei->{env}->{GZIP} // 'pigz') //
+ which('gzip') //
+ die "pigz or gzip missing for $sfx\n";
+ # TODO: use IO::Compress::Gzip
+ push @$cmd, '-c'; # stdout
+ push @$cmd, '--rsyncable' if $lei->{opt}->{rsyncable};
+ } else {
+ die "TODO $sfx"
+ }
+ pipe(my ($r, $w)) or die "pipe: $!";
+ my $rdr = { 0 => $r, 1 => $out, 2 => $lei->{2} };
+ my $pid = spawn($cmd, $lei->{env}, $rdr);
+ $lei->{"pid.$pid"} = $cmd;
+ my $pp = gensym;
+ tie *$pp, 'PublicInbox::ProcessPipe', $pid, $w, \&reap_compress, $lei;
+ my $tmp = File::Temp->new("$sfx.lock-XXXXXX", TMPDIR => 1);
+ my $pipe_lk = ($lei->{opt}->{jobs} // 0) > 1 ? bless({
+ lock_path => $tmp->filename,
+ tmp => $tmp
+ }, 'PublicInbox::Lock') : undef;
+ ($pp, $pipe_lk);
+}
+
+sub write_cb {
+ my ($cls, $dst, $lei) = @_;
+ if ($dst =~ s!\A(mbox(?:rd|cl|cl2|o))?:!!) {
+ my $m = "eml2$1";
+ my $eml2mbox = $cls->can($m) or die "$cls->$m missing";
+ my ($out, $pipe_lk);
+ open $out, '>>', $dst or die "open $dst: $!";
+ my $atomic = !!(($lei->{opt}->{jobs} // 0) > 1);
+ if ($dst =~ /\.(gz|bz2|xz)\z/) {
+ ($out, $pipe_lk) = compress_dst($out, $1, $lei);
+ }
+ sub {
+ my ($buf, $oid, $kw) = @_;
+ $buf = $eml2mbox->(PublicInbox::Eml->new($buf), $kw);
+ my $lock = $pipe_lk->lock_for_scope if $pipe_lk;
+ write_in_full($out, $buf, $atomic);
+ }
+ }
+}
+
1;
diff --git a/lib/PublicInbox/ProcessPipe.pm b/lib/PublicInbox/ProcessPipe.pm
index 2ce7eb8f..c9234f42 100644
--- a/lib/PublicInbox/ProcessPipe.pm
+++ b/lib/PublicInbox/ProcessPipe.pm
@@ -4,28 +4,39 @@
# a tied handle for auto reaping of children tied to a pipe, see perltie(1)
package PublicInbox::ProcessPipe;
use strict;
-use warnings;
+use v5.10.1;
sub TIEHANDLE {
- my ($class, $pid, $fh) = @_;
- bless { pid => $pid, fh => $fh }, $class;
+ my ($class, $pid, $fh, $cb, $arg) = @_;
+ bless { pid => $pid, fh => $fh, cb => $cb, arg => $arg }, $class;
}
sub READ { read($_[0]->{fh}, $_[1], $_[2], $_[3] || 0) }
sub READLINE { readline($_[0]->{fh}) }
+sub WRITE {
+ use bytes qw(length);
+ syswrite($_[0]->{fh}, $_[1], $_[2] // length($_[1]), $_[3] // 0);
+}
+
+sub PRINT {
+ my $self = shift;
+ print { $self->{fh} } @_;
+}
+
sub CLOSE {
my $fh = delete($_[0]->{fh});
my $ret = defined $fh ? close($fh) : '';
- my $pid = delete $_[0]->{pid};
+ my ($pid, $cb, $arg) = delete @{$_[0]}{qw(pid cb arg)};
if (defined $pid) {
# PublicInbox::DS may not be loaded
- eval { PublicInbox::DS::dwaitpid($pid, undef, undef) };
+ eval { PublicInbox::DS::dwaitpid($pid, $cb, $arg) };
if ($@) { # ok, not in the event loop, work synchronously
waitpid($pid, 0);
$ret = '' if $?;
+ $cb->($arg, $pid) if $cb;
}
}
$ret;
diff --git a/t/lei_to_mail.t b/t/lei_to_mail.t
index 089a422e..231cf543 100644
--- a/t/lei_to_mail.t
+++ b/t/lei_to_mail.t
@@ -62,4 +62,51 @@ for my $mbox (qw(mboxrd mboxo mboxcl mboxcl2)) {
}
}
+my ($tmpdir, $for_destroy) = tmpdir();
+local $ENV{TMPDIR} = $tmpdir;
+open my $err, '>>', "$tmpdir/lei.err" or BAIL_OUT $!;
+my $lei = { 2 => $err };
+my $buf = <<'EOM';
+From: x@example.com
+Subject: x
+
+blah
+EOM
+my $fn = "$tmpdir/x.mbox";
+my $orig = do {
+ my $wcb = PublicInbox::LeiToMail->write_cb("mboxcl2:$fn", $lei);
+ is(ref $wcb, 'CODE', 'write_cb returned callback');
+ ok(-f $fn && !-s _, 'empty file created');
+ $wcb->(\(my $dup = $buf), 'deadbeef', [ qw(seen) ]);
+ undef $wcb;
+ open my $fh, '<', $fn or BAIL_OUT $!;
+ my $raw = do { local $/; <$fh> };
+ like($raw, qr/^blah\n/sm, 'wrote content');
+ unlink $fn or BAIL_OUT $!;
+
+ local $lei->{opt} = { jobs => 2 };
+ $wcb = PublicInbox::LeiToMail->write_cb("mboxcl2:$fn", $lei);
+ $wcb->(\($dup = $buf), 'deadbeef', [ qw(seen) ]);
+ undef $wcb;
+ open $fh, '<', $fn or BAIL_OUT $!;
+ is($raw, do { local $/; <$fh> }, 'jobs > 1');
+ $raw;
+};
+SKIP: {
+ use PublicInbox::Spawn qw(which);
+ my $gzip = which('gzip') or skip 'gzip not found', 1;
+ my $wcb = PublicInbox::LeiToMail->write_cb("mboxcl2:$fn.gz", $lei);
+ $wcb->(\(my $dup = $buf), 'deadbeef', [ qw(seen) ]);
+ undef $wcb;
+ my $uncompressed = xqx([$gzip, '-dc', "$fn.gz"]);
+ is($uncompressed, $orig, 'gzip works');
+
+ local $lei->{opt} = { jobs => 2 };
+ unlink "$fn.gz" or die "unlink $!";
+ $wcb = PublicInbox::LeiToMail->write_cb("mboxcl2:$fn.gz", $lei);
+ $wcb->(\(my $dupe = $buf), 'deadbeef', [ qw(seen) ]);
+ undef $wcb;
+ is(xqx([$gzip, '-dc', "$fn.gz"]), $orig);
+}
+
done_testing;
next prev parent reply other threads:[~2020-12-31 13:51 UTC|newest]
Thread overview: 37+ messages / expand[flat|nested] mbox.gz Atom feed top
2020-12-31 13:51 [PATCH 00/36] another round of lei stuff Eric Wong
2020-12-31 13:51 ` [PATCH 01/36] import: respect init.defaultBranch Eric Wong
2020-12-31 13:51 ` [PATCH 02/36] lei_store: use per-machine refname as git HEAD Eric Wong
2020-12-31 13:51 ` [PATCH 03/36] revert "lei_store: use per-machine refname as git HEAD" Eric Wong
2020-12-31 13:51 ` [PATCH 04/36] lei_to_mail: initial implementation for writing mbox formats Eric Wong
2020-12-31 13:51 ` [PATCH 05/36] sharedkv: fork()-friendly key-value store Eric Wong
2020-12-31 13:51 ` [PATCH 06/36] sharedkv: split out index_values Eric Wong
2020-12-31 13:51 ` Eric Wong [this message]
2020-12-31 13:51 ` [PATCH 08/36] mboxreader: new class for reading various mbox formats Eric Wong
2020-12-31 13:51 ` [PATCH 09/36] lei_to_mail: start --augment, dedupe, bz2 and xz Eric Wong
2020-12-31 13:51 ` [PATCH 10/36] lei: implement various deduplication strategies Eric Wong
2020-12-31 13:51 ` [PATCH 11/36] lei_to_mail: lazy-require LeiDedupe Eric Wong
2020-12-31 13:51 ` [PATCH 12/36] lei_to_mail: support for non-seekable outputs Eric Wong
2020-12-31 13:51 ` [PATCH 13/36] lei_to_mail: support Maildir, fix+test --augment Eric Wong
2020-12-31 13:51 ` [PATCH 14/36] ipc: generic IPC dispatch based on Storable Eric Wong
2020-12-31 13:51 ` [PATCH 15/36] ipc: support Sereal Eric Wong
2020-12-31 13:51 ` [PATCH 16/36] lei_store: add ->set_eml, ->add_eml can return smsg Eric Wong
2020-12-31 13:51 ` [PATCH 17/36] lei: rename "extinbox" => "external" Eric Wong
2020-12-31 13:51 ` [PATCH 18/36] mid: use defined-or with `push' for uniqueness check Eric Wong
2020-12-31 13:51 ` [PATCH 19/36] mid: hoist out mids_in sub Eric Wong
2020-12-31 13:51 ` [PATCH 20/36] lei_store: handle messages without Message-ID at all Eric Wong
2020-12-31 13:51 ` [PATCH 21/36] ipc: use shutdown(2), base atfork* callback Eric Wong
2020-12-31 13:51 ` [PATCH 22/36] lei_to_mail: unlink mboxes if not augmenting Eric Wong
2020-12-31 13:51 ` [PATCH 23/36] lei: add --mfolder as an --output alias Eric Wong
2020-12-31 13:51 ` [PATCH 24/36] spawn: move run_die here from PublicInbox::Import Eric Wong
2020-12-31 13:51 ` [PATCH 25/36] init: remove embedded UnlinkMe package Eric Wong
2020-12-31 13:51 ` [PATCH 26/36] t/run: avoid uninitialized var on incomplete test Eric Wong
2020-12-31 13:51 ` [PATCH 27/36] gcf2client: reap process on DESTROY Eric Wong
2020-12-31 13:51 ` [PATCH 28/36] lei_to_mail: open FIFOs O_WRONLY so we block Eric Wong
2020-12-31 13:51 ` [PATCH 29/36] searchidxshard: call DS->Reset at worker start Eric Wong
2020-12-31 13:51 ` [PATCH 30/36] t/ipc.t: test for references via `die' Eric Wong
2020-12-31 13:51 ` [PATCH 31/36] use PublicInbox::DS for dwaitpid Eric Wong
2020-12-31 13:51 ` [PATCH 32/36] syscall: SFD_NONBLOCK can be a constant, again Eric Wong
2020-12-31 13:51 ` [PATCH 33/36] lei: avoid Spawn package when starting daemon Eric Wong
2020-12-31 13:51 ` [PATCH 34/36] avoid calling waitpid from children in DESTROY Eric Wong
2020-12-31 13:51 ` [PATCH 35/36] ds: clobber $in_loop first at reset Eric Wong
2020-12-31 13:51 ` [PATCH 36/36] on_destroy: support PID owner guard Eric Wong
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://public-inbox.org/README
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20201231135154.6070-8-e@80x24.org \
--to=e@80x24.org \
--cc=meta@public-inbox.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://80x24.org/public-inbox.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).