From 8add30044d04c1feccc00a3c5b8f9a0f75c64bf5 Mon Sep 17 00:00:00 2001
From: Eric Wong <e@80x24.org>
Date: Fri, 11 Apr 2014 20:46:12 +0000
Subject: add spam/ham learning wrapper script

This is essential for integrating into my inotify-based
spam training setup.
---
 public-inbox-learn | 78 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 78 insertions(+)
 create mode 100755 public-inbox-learn

(limited to 'public-inbox-learn')

diff --git a/public-inbox-learn b/public-inbox-learn
new file mode 100755
index 00000000..d770f0f7
--- /dev/null
+++ b/public-inbox-learn
@@ -0,0 +1,78 @@
+#!/usr/bin/perl -w
+# Copyright (C) 2014, Eric Wong <normalperson@yhbt.net> and all contributors
+# License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
+my $usage = "$0 (spam|ham) < /path/to/message";
+use strict;
+use warnings;
+use PublicInbox::Config;
+use Email::Simple;
+use Email::Address;
+use IPC::Run qw/run/;
+my $train = shift or die "usage: $usage\n";
+if ($train !~ /\A(?:ham|spam)\z/) {
+	die "`$train' not recognized.\nusage: $usage\n";
+}
+
+my $pi_config = PublicInbox::Config->new;
+my $simple;
+{
+	local $/;
+	$simple = Email::Simple->new(<>);
+}
+
+# get all recipients
+my %dests;
+foreach my $h (qw(Cc To)) {
+	foreach my $recipient (Email::Address->parse($simple->header($h))) {
+		$dests{lc($recipient->address)} = 1;
+	}
+}
+
+my $in = $simple->as_string;
+$simple->body_set("");
+
+my $err = 0;
+my @output = qw(> /dev/null > /dev/null);
+
+# n.b. message may be cross-posted to multiple public-inboxes
+foreach my $recipient (keys %dests) {
+	my $dst = $pi_config->lookup($recipient) or next;
+	my $git_dir = $dst->{mainrepo} or next;
+	my ($out, $err) = ("", "");
+
+	# We do not touch GIT_COMMITTER_* env here so we can track
+	# who trained the message.
+	# We will not touch GIT_AUTHOR_* when learning spam messages, either
+	if ($train eq "spam") {
+		# This needs to be idempotent, as my inotify trainer
+		# may train for each cross-posted message, and this
+		# script already learns for every list in
+		# ~/.public-inbox/config
+		if (!run(["ssoma-rm", $git_dir], \$in, \$out, \$err)) {
+			if ($err !~ /^git cat-file .+ failed: 32768$/) {
+				$err = 1;
+			}
+		}
+	} else { # $train eq "ham"
+		my $from = $simple->header("From");
+		my @from = Email::Address->parse($from);
+		my $name = $from[0]->name;
+		defined $name or $name = "";
+		my $email = $from[0]->address;
+		defined $email or $email = "";
+		local $ENV{GIT_AUTHOR_NAME} = $name;
+		local $ENV{GIT_AUTHOR_EMAIL} = $email;
+		local $ENV{GIT_AUTHOR_DATE} = $simple->header("Date");
+
+		# Ham messages are trained when they're marked into
+		# a SEEN state, so this is idempotent
+		run([qw(ssoma-mda -1), $git_dir], \$in, \$out, \$err);
+		if ($err !~ /CONFLICT/) {
+			$err = 1;
+		}
+	}
+	if (!run([qw(spamc -L), $train], \$in, @output)) {
+		$err = 1;
+	}
+}
+exit $err;
-- 
cgit v1.2.3-24-ge0c7