From 85c83085eeb14be7e7b9a395fa9408241ecb8244 Mon Sep 17 00:00:00 2001
From: Eric Wong <e@80x24.org>
Date: Mon, 25 Apr 2016 05:12:43 +0000
Subject: split out NNTPD and HTTPD* modules

Hopefully this modularizes things a little and allows us
to work on a combined super server to save RAM.
---
 lib/PublicInbox/NNTPD.pm | 59 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 lib/PublicInbox/NNTPD.pm

(limited to 'lib/PublicInbox/NNTPD.pm')

diff --git a/lib/PublicInbox/NNTPD.pm b/lib/PublicInbox/NNTPD.pm
new file mode 100644
index 00000000..85109ea7
--- /dev/null
+++ b/lib/PublicInbox/NNTPD.pm
@@ -0,0 +1,59 @@
+# Copyright (C) 2016 all contributors <meta@public-inbox.org>
+# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
+
+# represents an NNTPD (currently a singleton),
+# see script/public-inbox-nntpd for how it is used
+package PublicInbox::NNTPD;
+use strict;
+use warnings;
+require PublicInbox::NewsGroup;
+require PublicInbox::Config;
+
+sub new {
+	my ($class) = @_;
+	bless {
+		groups => {},
+		err => \*STDERR,
+		out => \*STDOUT,
+		grouplist => [],
+	}, $class;
+}
+
+sub refresh_groups () {
+	my ($self) = @_;
+	my $pi_config = PublicInbox::Config->new;
+	my $new = {};
+	my @list;
+	foreach my $k (keys %$pi_config) {
+		$k =~ /\Apublicinbox\.([^\.]+)\.mainrepo\z/ or next;
+		my $g = $1;
+		my $git_dir = $pi_config->{$k};
+		my $addr = $pi_config->{"publicinbox.$g.address"};
+		my $ngname = $pi_config->{"publicinbox.$g.newsgroup"};
+		if (defined $ngname) {
+			next if ($ngname eq ''); # disabled
+			$g = $ngname;
+		}
+		my $ng = PublicInbox::NewsGroup->new($g, $git_dir, $addr);
+		my $old_ng = $self->{groups}->{$g};
+
+		# Reuse the old one if possible since it can hold
+		# references to valid mm and gcf objects
+		if ($old_ng) {
+			$old_ng->update($ng);
+			$ng = $old_ng;
+		}
+
+		# Only valid if msgmap and search works
+		if ($ng->usable) {
+			$new->{$g} = $ng;
+			push @list, $ng;
+		}
+	}
+	@list =	sort { $a->{name} cmp $b->{name} } @list;
+	$self->{grouplist} = \@list;
+	# this will destroy old groups that got deleted
+	%{$self->{groups}} = %$new;
+}
+
+1;
-- 
cgit v1.2.3-24-ge0c7