From 0f03ff48b643a3b04bc44d2e1af27bd7dafd56c1 Mon Sep 17 00:00:00 2001
From: Eric Wong <e@80x24.org>
Date: Tue, 29 Apr 2014 05:10:48 +0000
Subject: implement our own cat-file --batch wrapper

We use --git-dir=... instead of $ENV{GIT_DIR} because ENV changes
do not propagate easily with mod_perl.
---
 MANIFEST                      |  1 +
 lib/PublicInbox/Feed.pm       | 36 +++------------------
 lib/PublicInbox/GitCatFile.pm | 73 +++++++++++++++++++++++++++++++++++++++++++
 public-inbox.cgi              |  1 -
 4 files changed, 79 insertions(+), 32 deletions(-)
 create mode 100644 lib/PublicInbox/GitCatFile.pm

diff --git a/MANIFEST b/MANIFEST
index b212c76b..ecdc8b5d 100644
--- a/MANIFEST
+++ b/MANIFEST
@@ -10,6 +10,7 @@ lib/PublicInbox/MDA.pm
 lib/PublicInbox/Config.pm
 lib/PublicInbox/Feed.pm
 lib/PublicInbox/Filter.pm
+lib/PublicInbox/GitCatFile.pm
 lib/PublicInbox/Hval.pm
 lib/PublicInbox/View.pm
 public-inbox-mda
diff --git a/lib/PublicInbox/Feed.pm b/lib/PublicInbox/Feed.pm
index 87b5b2a9..ad058395 100644
--- a/lib/PublicInbox/Feed.pm
+++ b/lib/PublicInbox/Feed.pm
@@ -7,7 +7,7 @@ use Email::Address;
 use Email::MIME;
 use Date::Parse qw(strptime str2time);
 use PublicInbox::Hval;
-eval { require Git }; # this is GPLv2+, so we are OK to use it
+use PublicInbox::GitCatFile;
 use constant {
 	DATEFMT => '%Y-%m-%dT%H:%M:%SZ',
 	MAX_PER_PAGE => 25,
@@ -39,7 +39,7 @@ sub generate {
 		updated => POSIX::strftime(DATEFMT, gmtime),
 	);
 
-	my $git = try_git_pm($args->{git_dir});
+	my $git = PublicInbox::GitCatFile->new($args->{git_dir});
 	each_recent_blob($args, sub {
 		my ($add) = @_;
 		add_to_feed($feed_opts, $feed, $add, $git);
@@ -59,7 +59,7 @@ sub generate_html_index {
 	$title = PublicInbox::Hval->new_oneline($title)->as_html;
 
 	my @messages;
-	my $git = try_git_pm($args->{git_dir});
+	my $git = PublicInbox::GitCatFile->new($args->{git_dir});
 	my $last = each_recent_blob($args, sub {
 		my $mime = do_cat_mail($git, $_[0]) or return 0;
 		$mime->body_set(''); # save some memory
@@ -294,36 +294,10 @@ sub dump_html_line {
 	dump_html_line($self->next, $level, $html) if $self->next;
 }
 
-sub try_git_pm {
-	my ($dir) = @_;
-	eval { Git->repository(Directory => $dir) };
-};
-
 sub do_cat_mail {
 	my ($git, $path) = @_;
-	my $str;
-	if ($git) {
-		open my $fh, '>', \$str or
-				die "failed to setup string handle: $!\n";
-		binmode $fh;
-		my $err = '';
-		my $bytes;
-		{
-			local $SIG{__WARN__} = sub { $err .= $_[0] };
-			$bytes = $git->cat_blob("HEAD:$path", $fh);
-		}
-		close $fh or die "failed to close string handle: $!\n";
-
-		if ($bytes < 0 && $err &&
-				$err !~ /doesn't exist in the repository/) {
-			warn $err;
-		}
-		return if $bytes <= 0;
-	} else {
-		$str = `git cat-file blob HEAD:$path`;
-		return if $? != 0 || length($str) == 0;
-	}
-	Email::MIME->new($str);
+	my $str = $git->cat_file("HEAD:$path");
+	Email::MIME->new($$str);
 }
 
 1;
diff --git a/lib/PublicInbox/GitCatFile.pm b/lib/PublicInbox/GitCatFile.pm
new file mode 100644
index 00000000..bdad2b56
--- /dev/null
+++ b/lib/PublicInbox/GitCatFile.pm
@@ -0,0 +1,73 @@
+# Copyright (C) 2014, Eric Wong <normalperson@yhbt.net> and all contributors
+# License: GPLv2 or later (https://www.gnu.org/licenses/gpl-2.0.txt)
+# This is based on code in Git.pm which is GPLv2, but modified to avoid
+# dependence on environment variables for compatibility with mod_perl.
+# There are also API changes to simplify our usage and data set.
+package PublicInbox::GitCatFile;
+use strict;
+use warnings;
+use IPC::Open2 qw(open2);
+
+sub new {
+	my ($class, $git_dir) = @_;
+	bless { git_dir => $git_dir }, $class;
+}
+
+sub _cat_file_begin {
+	my ($self) = @_;
+	return if $self->{pid};
+	my ($in, $out);
+	my $pid = open2($in, $out, 'git', '--git-dir', $self->{git_dir},
+			'cat-file', '--batch');
+
+	$self->{pid} = $pid;
+	$self->{in} = $in;
+	$self->{out} = $out;
+}
+
+sub cat_file {
+	my ($self, $object) = @_;
+
+	$self->_cat_file_begin;
+	print { $self->{out} } $object, "\n" or die "write error: $!\n";
+
+	my $in = $self->{in};
+	my $head = <$in>;
+	$head =~ / missing$/ and return undef;
+	$head =~ /^[0-9a-f]{40} \S+ (\d+)$/ or
+		die "Unexpected result from git cat-file: $head\n";
+
+	my $size = $1;
+	my $bytes_left = $size;
+	my $buf;
+	my $rv = '';
+
+	while ($bytes_left) {
+		my $read = read($in, $buf, $bytes_left);
+		defined($read) or die "read pipe failed: $!\n";
+		$rv .= $buf;
+		$bytes_left -= $read;
+	}
+
+	my $read = read($in, $buf, 1);
+	defined($read) or die "read pipe failed: $!\n";
+	if ($read != 1 || $buf ne "\n") {
+		die "newline missing after blob\n";
+	}
+	\$rv;
+}
+
+sub DESTROY {
+	my ($self) = @_;
+	my $pid = $self->{pid} or return;
+	$self->{pid} = undef;
+	foreach my $f (qw(in out)) {
+		my $fh = $self->{$f};
+		defined $fh or next;
+		close $fh;
+		$self->{$f} = undef;
+	}
+	waitpid $pid, 0;
+}
+
+1;
diff --git a/public-inbox.cgi b/public-inbox.cgi
index 93147124..ffd6ec08 100755
--- a/public-inbox.cgi
+++ b/public-inbox.cgi
@@ -218,7 +218,6 @@ sub psgi_app {
 	require POSIX;
 	require XML::Atom::SimpleFeed;
 	require Plack::Request;
-	eval { require Git }; # optional
 	sub {
 		my $req = Plack::Request->new(@_);
 		main($req, $req->method);
-- 
cgit v1.2.3-24-ge0c7