user/dev discussion of public-inbox itself
 help / color / Atom feed
9399c272a1b25f2a66b06c4abfc535d52fe81238 blob 2344 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
 
#!/usr/bin/perl -w
# Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
# Basic tool to create a Xapian search index for a git repository
# configured for public-inbox.
# Usage with libeatmydata <https://www.flamingspork.com/projects/libeatmydata/>
# highly recommended: eatmydata public-inbox-index REPO_DIR

use strict;
use warnings;
use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
my $usage = "public-inbox-index REPO_DIR";
use PublicInbox::Admin;
PublicInbox::Admin::require_or_die('-index');

my $reindex;
my $prune;
my $jobs = undef;
my $indexlevel;
my %opts = (
	'--reindex' => \$reindex,
	'--jobs|j=i' => \$jobs,
	'--prune' => \$prune,
        'L|indexlevel=s' => \$indexlevel,
);
GetOptions(%opts) or die "bad command-line args\n$usage";
die "--jobs must be positive\n" if defined $jobs && $jobs < 0;

sub usage { print STDERR "Usage: $usage\n"; exit 1 }

# do we really care about this message?  It's annoying...
my $warn = 'public-inbox unconfigured for serving, indexing anyways...';
my @ibxs = PublicInbox::Admin::resolve_inboxes(\@ARGV, $warn);
PublicInbox::Admin::require_or_die('-index');
usage() unless @ibxs;
my $mods = {};
foreach my $ibx (@ibxs) {
	if (defined $indexlevel && !defined($ibx->{indexlevel})) {
		# XXX: users can shoot themselves in the foot, with this...
		$ibx->{indexlevel} = $indexlevel;
	}
	PublicInbox::Admin::scan_ibx_modules($mods, $ibx);
}

PublicInbox::Admin::require_or_die(keys %$mods);

require PublicInbox::SearchIdx;
index_inbox($_) for @ibxs;

sub index_inbox {
	my ($repo) = @_;
	if (ref($repo) && ($repo->{version} || 1) == 2) {
		eval { require PublicInbox::V2Writable };
		die "v2 requirements not met: $@\n" if $@;
		my $v2w = eval {
			PublicInbox::V2Writable->new($repo, {nproc=>$jobs});
		};
		if (defined $jobs) {
			if ($jobs == 0) {
				$v2w->{parallel} = 0;
			} else {
				my $n = $v2w->{partitions};
				if ($jobs != ($n + 1)) {
					warn
"Unable to respect --jobs=$jobs, inbox was created with $n partitions\n";
				}
			}
		}
		local $SIG{__WARN__} = sub {
			print STDERR $v2w->{current_info}, ': ', @_;
		};
		$v2w->index_sync({ reindex => $reindex, prune => $prune });
	} else {
		my $s = PublicInbox::SearchIdx->new($repo, 1);
		$s->index_sync({ reindex => $reindex });
	}
}
debug log:

solving 9399c27 ...
found 9399c27 in https://80x24.org/public-inbox.git

user/dev discussion of public-inbox itself

Archives are clonable:
	git clone --mirror http://public-inbox.org/meta
	git clone --mirror http://czquwvybam4bgbro.onion/meta
	git clone --mirror http://hjrcffqmbrq6wope.onion/meta
	git clone --mirror http://ou63pmih66umazou.onion/meta

Example config snippet for mirrors

Newsgroups are available over NNTP:
	nntp://news.public-inbox.org/inbox.comp.mail.public-inbox.meta
	nntp://ou63pmih66umazou.onion/inbox.comp.mail.public-inbox.meta
	nntp://czquwvybam4bgbro.onion/inbox.comp.mail.public-inbox.meta
	nntp://hjrcffqmbrq6wope.onion/inbox.comp.mail.public-inbox.meta
	nntp://news.gmane.org/gmane.mail.public-inbox.general

 note: .onion URLs require Tor: https://www.torproject.org/

AGPL code for this site: git clone https://public-inbox.org/ public-inbox