user/dev discussion of public-inbox itself
 help / color / mirror / Atom feed
* [PATCH] search: allow testing with current xapian.git and 1.5.x
@ 2020-08-26 22:02 Eric Wong
  0 siblings, 0 replies; only message in thread
From: Eric Wong @ 2020-08-26 22:02 UTC (permalink / raw)
  To: meta

A `PI_XAPIAN' environment variable is now exposed for testing
purposes.  We'll also deal with the removal of
`NumberValueRangeProcessor' and use `NumberRangeProcessor'
in its place, but continue favoring the old Search::Xapian
since that's all that's packaged for Debian 10.x stable.
---
 lib/PublicInbox/Search.pm | 37 +++++++++++++++++++++++++++----------
 1 file changed, 27 insertions(+), 10 deletions(-)

diff --git a/lib/PublicInbox/Search.pm b/lib/PublicInbox/Search.pm
index 01bbe73d..b739faf1 100644
--- a/lib/PublicInbox/Search.pm
+++ b/lib/PublicInbox/Search.pm
@@ -54,19 +54,33 @@ use constant {
 use PublicInbox::Smsg;
 use PublicInbox::Over;
 my $QP_FLAGS;
-our %X = map { $_ => 0 } qw(BoolWeight Database Enquire
-			NumberValueRangeProcessor QueryParser Stem);
+our %X = map { $_ => 0 } qw(BoolWeight Database Enquire QueryParser Stem);
 our $Xap; # 'Search::Xapian' or 'Xapian'
+my $NVRP; # '$Xap::'.('NumberValueRangeProcessor' or 'NumberRangeProcessor')
 my $ENQ_ASCENDING;
 
 sub load_xapian () {
 	return 1 if defined $Xap;
-	for my $x (qw(Search::Xapian Xapian)) {
+	# n.b. PI_XAPIAN is intended for development use only.  We still
+	# favor Search::Xapian since that's what's available in current
+	# Debian stable (10.x) and derived distros.
+	for my $x (($ENV{PI_XAPIAN} // 'Search::Xapian'), 'Xapian') {
 		eval "require $x";
 		next if $@;
 
 		$x->import(qw(:standard));
 		$Xap = $x;
+
+		# `version_string' was added in Xapian 1.1
+		my $xver = eval('v'.eval($x.'::version_string()')) //
+				eval('v'.eval($x.'::xapian_version_string()'));
+
+		# NumberRangeProcessor was added in Xapian 1.3.6,
+		# NumberValueRangeProcessor was removed for 1.5.0+,
+		# favor the older /Value/ variant since that's what our
+		# (currently) preferred Search::Xapian supports
+		$NVRP = $x.'::'.($x eq 'Xapian' && $xver ge v1.5 ?
+			'NumberRangeProcessor' : 'NumberValueRangeProcessor');
 		$X{$_} = $Xap.'::'.$_ for (keys %X);
 
 		# ENQ_ASCENDING doesn't seem exported by SWIG Xapian.pm,
@@ -364,15 +378,18 @@ sub qparse_new ($) {
 	$qp->set_database($xdb);
 	$qp->set_stemmer(stemmer($self));
 	$qp->set_stemming_strategy(STEM_SOME());
-	$qp->set_max_wildcard_expansion(100);
-	my $nvrp = $X{NumberValueRangeProcessor};
-	$qp->add_valuerangeprocessor($nvrp->new(YYYYMMDD, 'd:'));
-	$qp->add_valuerangeprocessor($nvrp->new(DT, 'dt:'));
+	my $cb = $qp->can('set_max_wildcard_expansion') //
+		$qp->can('set_max_expansion'); # Xapian 1.5.0+
+	$cb->($qp, 100);
+	$cb = $qp->can('add_valuerangeprocessor') //
+		$qp->can('add_rangeprocessor'); # Xapian 1.5.0+
+	$cb->($qp, $NVRP->new(YYYYMMDD, 'd:'));
+	$cb->($qp, $NVRP->new(DT, 'dt:'));
 
 	# for IMAP, undocumented for WWW and may be split off go away
-	$qp->add_valuerangeprocessor($nvrp->new(BYTES, 'bytes:'));
-	$qp->add_valuerangeprocessor($nvrp->new(TS, 'ts:'));
-	$qp->add_valuerangeprocessor($nvrp->new(UID, 'uid:'));
+	$cb->($qp, $NVRP->new(BYTES, 'bytes:'));
+	$cb->($qp, $NVRP->new(TS, 'ts:'));
+	$cb->($qp, $NVRP->new(UID, 'uid:'));
 
 	while (my ($name, $prefix) = each %bool_pfx_external) {
 		$qp->add_boolean_prefix($name, $_) foreach split(/ /, $prefix);

^ permalink raw reply	[flat|nested] only message in thread

only message in thread, other threads:[~2020-08-26 22:02 UTC | newest]

Thread overview: (only message) (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2020-08-26 22:02 [PATCH] search: allow testing with current xapian.git and 1.5.x Eric Wong

user/dev discussion of public-inbox itself

This inbox may be cloned and mirrored by anyone:

	git clone --mirror http://public-inbox.org/meta
	git clone --mirror http://czquwvybam4bgbro.onion/meta
	git clone --mirror http://hjrcffqmbrq6wope.onion/meta
	git clone --mirror http://ou63pmih66umazou.onion/meta

	# If you have public-inbox 1.1+ installed, you may
	# initialize and index your mirror using the following commands:
	public-inbox-init -V1 meta meta/ http://public-inbox.org/meta \
		meta@public-inbox.org
	public-inbox-index meta

Example config snippet for mirrors.
Newsgroups are available over NNTP:
	nntp://news.public-inbox.org/inbox.comp.mail.public-inbox.meta
	nntp://ou63pmih66umazou.onion/inbox.comp.mail.public-inbox.meta
	nntp://czquwvybam4bgbro.onion/inbox.comp.mail.public-inbox.meta
	nntp://hjrcffqmbrq6wope.onion/inbox.comp.mail.public-inbox.meta
	nntp://news.gmane.io/gmane.mail.public-inbox.general
 note: .onion URLs require Tor: https://www.torproject.org/

code repositories for the project(s) associated with this inbox:

	https://80x24.org/public-inbox.git

AGPL code for this site: git clone https://public-inbox.org/public-inbox.git