user/dev discussion of public-inbox itself
 help / color / Atom feed
* [PATCH 0/2] daemon: SIGUSR2 fixes
@ 2020-03-22  8:58 Eric Wong
  2020-03-22  8:58 ` [PATCH 1/2] daemon: fix SIGUSR2 upgrade with -W0 (no workers) Eric Wong
  2020-03-22  8:58 ` [PATCH 2/2] daemon: unlink .oldbin PID file correctly Eric Wong
  0 siblings, 2 replies; 4+ messages in thread
From: Eric Wong @ 2020-03-22  8:58 UTC (permalink / raw)
  To: meta

I noticed we never had tests for SIGUSR2, so I started
writing them and fixed two bugs.

Eric Wong (2):
  daemon: fix SIGUSR2 upgrade with -W0 (no workers)
  daemon: unlink .oldbin PID file correctly

 lib/PublicInbox/Daemon.pm |   7 ++-
 t/httpd-unix.t            | 100 ++++++++++++++++++++++++++++++++++----
 2 files changed, 95 insertions(+), 12 deletions(-)

^ permalink raw reply	[flat|nested] 4+ messages in thread

* [PATCH 1/2] daemon: fix SIGUSR2 upgrade with -W0 (no workers)
  2020-03-22  8:58 [PATCH 0/2] daemon: SIGUSR2 fixes Eric Wong
@ 2020-03-22  8:58 ` Eric Wong
  2020-03-24  7:24   ` [PATCH 3/2 (squash)] t/httpd-unix: fix race in SIGUSR2 test Eric Wong
  2020-03-22  8:58 ` [PATCH 2/2] daemon: unlink .oldbin PID file correctly Eric Wong
  1 sibling, 1 reply; 4+ messages in thread
From: Eric Wong @ 2020-03-22  8:58 UTC (permalink / raw)
  To: meta

Disabling workers via `-W0' blesses the contents of the
@listeners array, so we need to ensure we call fcntl on
the GLOB ref in ->{sock}.

Add tests to ensure USR2 works regardless of whether workers
are enabled or not.
---
 lib/PublicInbox/Daemon.pm |  3 ++
 t/httpd-unix.t            | 99 +++++++++++++++++++++++++++++++++++----
 2 files changed, 92 insertions(+), 10 deletions(-)

diff --git a/lib/PublicInbox/Daemon.pm b/lib/PublicInbox/Daemon.pm
index 43ef2691..3d582e35 100644
--- a/lib/PublicInbox/Daemon.pm
+++ b/lib/PublicInbox/Daemon.pm
@@ -403,6 +403,9 @@ sub upgrade { # $_[0] = signal name or number (unused)
 		$ENV{LISTEN_FDS} = scalar @listeners;
 		$ENV{LISTEN_PID} = $$;
 		foreach my $s (@listeners) {
+			# @listeners are globs with workers, PI::L w/o workers
+			$s = $s->{sock} if ref($s) eq 'PublicInbox::Listener';
+
 			my $fl = fcntl($s, F_GETFD, 0);
 			fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 		}
diff --git a/t/httpd-unix.t b/t/httpd-unix.t
index b321c789..425ecfff 100644
--- a/t/httpd-unix.t
+++ b/t/httpd-unix.t
@@ -6,6 +6,8 @@ use warnings;
 use Test::More;
 use PublicInbox::TestCommon;
 use Errno qw(EADDRINUSE);
+use Cwd qw(abs_path);
+use Carp qw(croak);
 require_mods(qw(Plack::Util Plack::Builder HTTP::Date HTTP::Status));
 use IO::Socket::UNIX;
 my ($tmpdir, $for_destroy) = tmpdir();
@@ -79,9 +81,26 @@ check_sock($unix);
 	ok(-S $unix, 'unix socket still exists');
 }
 
+sub delay_until {
+	my $cond = shift;
+	for (1..1000) {
+		return if $cond->();
+		select undef, undef, undef, 0.012;
+	}
+	Carp::croak('condition failed');
+}
+
 SKIP: {
 	require_mods('Net::Server::Daemonize', 20);
 	my $pid_file = "$tmpdir/pid";
+	my $read_pid = sub {
+		my $f = shift;
+		open my $fh, '<', $f or die "open $f failed: $!";
+		my $pid = do { local $/; <$fh> };
+		chomp $pid;
+		$pid || 0;
+	};
+
 	for my $w (qw(-W0 -W1)) {
 		# wait for daemonization
 		$spawn_httpd->("-l$unix", '-D', '-P', $pid_file, $w);
@@ -90,18 +109,78 @@ SKIP: {
 		check_sock($unix);
 
 		ok(-f $pid_file, "$w pid file written");
-		open my $fh, '<', "$tmpdir/pid" or die "open failed: $!";
-		my $rpid = do { local $/; <$fh> };
-		chomp $rpid;
-		like($rpid, qr/\A\d+\z/s, "$w pid file looks like a pid");
-		is(kill('TERM', $rpid), 1, "signaled daemonized $w process");
-		for (1..100) {
-			kill(0, $rpid) or last;
-			select undef, undef, undef, 0.02;
-		}
-		is(kill(0, $rpid), 0, "daemonized $w process exited");
+		my $pid = $read_pid->($pid_file);
+		is(kill('TERM', $pid), 1, "signaled daemonized $w process");
+		delay_until(sub { !kill(0, $pid) });
+		is(kill(0, $pid), 0, "daemonized $w process exited");
 		ok(!-e $pid_file, "$w pid file unlinked at exit");
 	}
+
+	# try a USR2 upgrade with workers:
+	my $httpd = abs_path('blib/script/public-inbox-httpd');
+	$psgi = abs_path($psgi);
+	my $opt = { run_mode => 0 };
+
+	my @args = ("-l$unix", '-D', '-P', $pid_file, -1, $out, -2, $err);
+	$td = start_script([$httpd, @args, $psgi], undef, $opt);
+	$td->join;
+	is($?, 0, "daemonized process again");
+	check_sock($unix);
+	my $pid = $read_pid->($pid_file);
+	kill('USR2', $pid) or die "USR2 failed: $!";
+	delay_until(sub {
+		$pid != (eval { $read_pid->($pid_file) } // $pid)
+	});
+	my $new_pid = $read_pid->($pid_file);
+	isnt($new_pid, $pid, 'new child started');
+	my $old_pid = $read_pid->("$pid_file.oldbin");
+	is($old_pid, $pid, '.oldbin pid file written');
+
+	# first, back out of the upgrade
+	kill('QUIT', $new_pid) or die "kill new PID failed: $!";
+	delay_until(sub {
+		$pid == (eval { $read_pid->($pid_file) } // 0)
+	});
+	is($read_pid->($pid_file), $pid, 'old PID file restored');
+	ok(!-f "$pid_file.oldbin", '.oldbin PID file gone');
+
+	# retry USR2 upgrade
+	kill('USR2', $pid) or die "USR2 failed: $!";
+	delay_until(sub {
+		$pid != (eval { $read_pid->($pid_file) } // $pid)
+	});
+	$new_pid = $read_pid->($pid_file);
+	isnt($new_pid, $pid, 'new child started again');
+	$old_pid = $read_pid->("$pid_file.oldbin");
+	is($old_pid, $pid, '.oldbin pid file written');
+
+	# drop the old parent
+	kill('QUIT', $old_pid) or die "QUIT failed: $!";
+	delay_until(sub { !kill(0, $old_pid) });
+
+	# drop the new child
+	check_sock($unix);
+	kill('QUIT', $new_pid) or die "QUIT failed: $!";
+	delay_until(sub { !kill(0, $new_pid) });
+	ok(!-f $pid_file, 'PID file is gone');
+
+
+	# try USR2 without workers (-W0)
+	$td = start_script([$httpd, @args, '-W0', $psgi], undef, $opt);
+	$td->join;
+	is($?, 0, 'daemonized w/o workers');
+	check_sock($unix);
+	$pid = $read_pid->($pid_file);
+
+	# replace running process
+	kill('USR2', $pid) or die "USR2 failed: $!";
+	delay_until(sub { !kill(0, $pid) });
+
+	check_sock($unix);
+	$pid = $read_pid->($pid_file);
+	kill('QUIT', $pid) or die "USR2 failed: $!";
+	delay_until(sub { !kill(0, $pid) });
+	ok(!-f $pid_file, 'PID file is gone');
 }
 
 done_testing();

^ permalink raw reply	[flat|nested] 4+ messages in thread

* [PATCH 2/2] daemon: unlink .oldbin PID file correctly
  2020-03-22  8:58 [PATCH 0/2] daemon: SIGUSR2 fixes Eric Wong
  2020-03-22  8:58 ` [PATCH 1/2] daemon: fix SIGUSR2 upgrade with -W0 (no workers) Eric Wong
@ 2020-03-22  8:58 ` Eric Wong
  1 sibling, 0 replies; 4+ messages in thread
From: Eric Wong @ 2020-03-22  8:58 UTC (permalink / raw)
  To: meta

We need to track the PID file having ".oldbin" appended
to it while a SIGUSR2 upgrade is in progress and ensure
it is unlinked on SIGQUIT.
---
 lib/PublicInbox/Daemon.pm | 4 ++--
 t/httpd-unix.t            | 1 +
 2 files changed, 3 insertions(+), 2 deletions(-)

diff --git a/lib/PublicInbox/Daemon.pm b/lib/PublicInbox/Daemon.pm
index 3d582e35..4ff7cad4 100644
--- a/lib/PublicInbox/Daemon.pm
+++ b/lib/PublicInbox/Daemon.pm
@@ -247,7 +247,7 @@ sub daemonize () {
 
 	write_pid($pid_file);
 	# for ->DESTROY:
-	bless { pid => $$, pid_file => $pid_file }, __PACKAGE__;
+	bless { pid => $$, pid_file => \$pid_file }, __PACKAGE__;
 }
 
 sub worker_quit { # $_[0] = signal name or number (unused)
@@ -663,7 +663,7 @@ sub write_pid ($) {
 }
 
 sub DESTROY {
-	unlink_pid_file_safe_ish($_[0]->{pid}, $_[0]->{pid_file});
+	unlink_pid_file_safe_ish($_[0]->{pid}, ${$_[0]->{pid_file}});
 }
 
 1;
diff --git a/t/httpd-unix.t b/t/httpd-unix.t
index 425ecfff..939431f4 100644
--- a/t/httpd-unix.t
+++ b/t/httpd-unix.t
@@ -157,6 +157,7 @@ SKIP: {
 	# drop the old parent
 	kill('QUIT', $old_pid) or die "QUIT failed: $!";
 	delay_until(sub { !kill(0, $old_pid) });
+	ok(!-f "$pid_file.oldbin", '.oldbin PID file gone');
 
 	# drop the new child
 	check_sock($unix);

^ permalink raw reply	[flat|nested] 4+ messages in thread

* [PATCH 3/2 (squash)] t/httpd-unix: fix race in SIGUSR2 test
  2020-03-22  8:58 ` [PATCH 1/2] daemon: fix SIGUSR2 upgrade with -W0 (no workers) Eric Wong
@ 2020-03-24  7:24   ` Eric Wong
  0 siblings, 0 replies; 4+ messages in thread
From: Eric Wong @ 2020-03-24  7:24 UTC (permalink / raw)
  To: meta

We need to stop workers in the old process, check the socket and
ensure $new_pid is ready to receive signals before killing it.
---
 t/httpd-unix.t | 6 ++++++
 1 file changed, 6 insertions(+)

diff --git a/t/httpd-unix.t b/t/httpd-unix.t
index 939431f4..a0fe1e31 100644
--- a/t/httpd-unix.t
+++ b/t/httpd-unix.t
@@ -127,6 +127,10 @@ SKIP: {
 	is($?, 0, "daemonized process again");
 	check_sock($unix);
 	my $pid = $read_pid->($pid_file);
+
+	# stop worker to ensure check_sock below hits $new_pid
+	kill('TTOU', $pid) or die "TTOU failed: $!";
+
 	kill('USR2', $pid) or die "USR2 failed: $!";
 	delay_until(sub {
 		$pid != (eval { $read_pid->($pid_file) } // $pid)
@@ -136,6 +140,8 @@ SKIP: {
 	my $old_pid = $read_pid->("$pid_file.oldbin");
 	is($old_pid, $pid, '.oldbin pid file written');
 
+	check_sock($unix); # ensures $new_pid is ready to receive signals
+
 	# first, back out of the upgrade
 	kill('QUIT', $new_pid) or die "kill new PID failed: $!";
 	delay_until(sub {

^ permalink raw reply	[flat|nested] 4+ messages in thread

end of thread, back to index

Thread overview: 4+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2020-03-22  8:58 [PATCH 0/2] daemon: SIGUSR2 fixes Eric Wong
2020-03-22  8:58 ` [PATCH 1/2] daemon: fix SIGUSR2 upgrade with -W0 (no workers) Eric Wong
2020-03-24  7:24   ` [PATCH 3/2 (squash)] t/httpd-unix: fix race in SIGUSR2 test Eric Wong
2020-03-22  8:58 ` [PATCH 2/2] daemon: unlink .oldbin PID file correctly Eric Wong

user/dev discussion of public-inbox itself

Archives are clonable:
	git clone --mirror http://public-inbox.org/meta
	git clone --mirror http://czquwvybam4bgbro.onion/meta
	git clone --mirror http://hjrcffqmbrq6wope.onion/meta
	git clone --mirror http://ou63pmih66umazou.onion/meta

Example config snippet for mirrors

Newsgroups are available over NNTP:
	nntp://news.public-inbox.org/inbox.comp.mail.public-inbox.meta
	nntp://ou63pmih66umazou.onion/inbox.comp.mail.public-inbox.meta
	nntp://czquwvybam4bgbro.onion/inbox.comp.mail.public-inbox.meta
	nntp://hjrcffqmbrq6wope.onion/inbox.comp.mail.public-inbox.meta
	nntp://news.gmane.io/gmane.mail.public-inbox.general

 note: .onion URLs require Tor: https://www.torproject.org/

AGPL code for this site: git clone https://public-inbox.org/public-inbox.git